lib/ZOOM/IRSpy.pm

   1
   2 package ZOOM::IRSpy;
   3
   4 use 5.008;
   5 use strict;
   6 use warnings;
   7
   8 use Data::Dumper;               # For debugging only
   9 use File::Basename;
  10 use XML::LibXSLT;
  11 use XML::LibXML;
  12 use XML::LibXML::XPathContext;
  13 use ZOOM;
  14 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  15 use ZOOM::IRSpy::Node;
  16 use ZOOM::IRSpy::Connection;
  17 use ZOOM::IRSpy::Stats;
  18 use ZOOM::IRSpy::Utils qw(cql_target render_record
  19                           irspy_xpath_context irspy_make_identifier
  20                           irspy_record2identifier calc_reliability_stats
  21                           modify_xml_document);
  22
  23 our @ISA = qw();
  24 our $VERSION = '1.02';
  25 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  26 our $debug = 0;
  27 our $xslt_max_depth = 250;
  28 our $max_timeout_errors = 3;
  29
  30
  31 # Enumeration for callback functions to return
  32 package ZOOM::IRSpy::Status;
  33 sub OK { 29 }                   # No problems, task is still progressing
  34 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  35 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  36 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  37 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  38 package ZOOM::IRSpy;
  39
  40
  41 =head1 NAME
  42
  43 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  44
  45 =head1 SYNOPSIS
  46
  47  use ZOOM::IRSpy;
  48  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  49  $spy->targets(@targets);
  50  $spy->initialise("Main");
  51  $res = $spy->check();
  52
  53 =head1 DESCRIPTION
  54
  55 This module exists to implement the IRspy program, which discovers,
  56 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  57 protocols.  It is a successor to the ZSpy program.
  58
  59 =cut
  60
  61 BEGIN {
  62     ZOOM::Log::mask_str("irspy");
  63     ZOOM::Log::mask_str("irspy_debug");
  64     ZOOM::Log::mask_str("irspy_event");
  65     ZOOM::Log::mask_str("irspy_unhandled");
  66     ZOOM::Log::mask_str("irspy_test");
  67     ZOOM::Log::mask_str("irspy_task");
  68 }
  69
  70 sub new {
  71     my $class = shift();
  72     my($dbname, $user, $password, $activeSetSize) = @_;
  73
  74
  75     my @options;
  76     push @options, (user => $user, password => $password)
  77         if defined $user;
  78
  79     my $conn = new ZOOM::Connection($dbname, 0, @options)
  80         or die "$0: can't connection to IRSpy database 'dbname'";
  81
  82     my $xslt = new XML::LibXSLT;
  83
  84     # raise the maximum number of nested template calls and variables/params (default 250)
  85     warn "raise the maximum number of nested template calls: $xslt_max_depth\n" if $debug;
  86     $xslt->max_depth($xslt_max_depth);
  87
  88     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  89                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  90
  91     my $libxml = new XML::LibXML;
  92     warn "use irspy_to_zeerex_xsl xslt sheet: $irspy_to_zeerex_xsl\n" if $debug;
  93     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  94     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  95
  96     my $this = bless {
  97         conn => $conn,
  98         query => "cql.allRecords=1", # unless overridden
  99         modn => undef,          # Filled in by restrict_modulo()
 100         modi => undef,          # Filled in by restrict_modulo()
 101         targets => undef,       # Filled in later if targets() is
 102                                 # called; used only to keep state from
 103                                 # targets() until initialise() is
 104                                 # called.
 105         connections => undef,   # Filled in by initialise()
 106         queue => undef,         # Filled in by initialise()
 107         libxml => $libxml,
 108         irspy_to_zeerex_style => $irspy_to_zeerex_style,
 109         test => undef,          # Filled in by initialise()
 110         timeout => undef,       # Filled in by initialise()
 111         tests => undef,         # Tree of tests to be executed
 112         activeSetSize => defined $activeSetSize ? $activeSetSize : 10,
 113         rules => [],            # Can be filled by apply_rules()
 114         vars => {},             # Will contain name, id, version, etc.
 115                                 # May be written into by tests (mostly
 116                                 # Ping, which gets the Init response)
 117                                 # and read by tests for rules.
 118     }, $class;
 119     $this->log("irspy", "starting up with database '$dbname'");
 120
 121     return $this;
 122 }
 123
 124 # Read from and write to the set of vars
 125 sub var {
 126     my $this = shift();
 127     my($key, $newval) = @_;
 128
 129     if (defined $newval) {
 130         $this->{vars}->{$key} = $newval;
 131         #warn "$this: set '$key'='$newval'";
 132     } else {
 133         my $oldval = $this->{vars}->{$key};
 134         $oldval = "" if !defined $oldval;
 135         #warn "$this: got '$key'='$oldval'";
 136         return $oldval;
 137     }
 138 }
 139
 140 # wrapper to read the IRSpy database name from environment variable / apache config
 141 sub connect_to_registry {
 142     my %args = @_;
 143
 144     # XXX: we could also handle her: user, password, elementSetName
 145
 146     my $database = $ENV{IRSpyDbName} || "localhost:8018/IR-Explain---1";
 147
 148     return $database;
 149 }
 150
 151 sub log {
 152     my $this = shift();
 153     ZOOM::Log::log(@_);
 154 }
 155
 156
 157 sub find_targets {
 158     my $this = shift();
 159     my($query) = @_;
 160
 161     $this->{query} = $query;
 162 }
 163
 164
 165 # Explicitly nominate a set of targets to check, overriding the
 166 # default which is to re-check everything in the database.  Each
 167 # target already in the database results in the existing record being
 168 # updated; each new target causes a new record to be added.
 169 #
 170 sub targets {
 171     my $this = shift();
 172     my(@targets) = @_;
 173
 174     $this->log("irspy", "setting explicit list of targets ",
 175                join(", ", map { "'$_'" } @targets));
 176     my @qlist;
 177     foreach my $target (@targets) {
 178         my($protocol, $host, $port, $db, $newtarget) =
 179             _parse_target_string($target);
 180         if ($newtarget ne $target) {
 181             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 182             $target = $newtarget; # This is written through the ref
 183         }
 184         push @qlist, cql_target($protocol, $host, $port, $db);
 185     }
 186
 187     $this->{targets} = \@targets;
 188     $this->{query} = join(" or ", @qlist);
 189 }
 190
 191
 192 # Also used by ZOOM::IRSpy::Record
 193 sub _parse_target_string {
 194     my($target) = @_;
 195
 196     my($protocol, $host, $port, $db) = ($target =~ /(.*?):(.*?):(.*?)\/(.*)/);
 197     if (!defined $host) {
 198         $port = 210;
 199         ($protocol, $host, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 200         $target = irspy_make_identifier($protocol, $host, $port, $db);
 201     }
 202     die "$0: invalid target string '$target'"
 203         if !defined $host;
 204
 205     return ($protocol, $host, $port, $db, $target);
 206 }
 207
 208
 209 sub restrict_modulo {
 210     my $this = shift();
 211     my($n, $i) = @_;
 212
 213     $this->{modn} = $n;
 214     $this->{modi} = $i;
 215 }
 216
 217
 218 sub apply_rules {
 219     my $this = shift();
 220     my($fileName) = @_;
 221
 222     my $f = new IO::File("<$fileName")
 223         or die "$0: can't open rules file '$fileName': $!";
 224
 225     while (my $line = <$f>) {
 226         chomp $line;
 227         $line =~ s/#.*//;
 228         $line =~ s/\s+$//;
 229         next if !$line;
 230         my(@fields) = split /\s+/, $line;
 231         my($name, $op, $val, $rule, @params) = @fields;
 232         #warn "parsed name='$name', op='$op', val='$val', rule='$rule', params='@params'\n";
 233         push @{ $this->{rules} }, [ @fields ];
 234     }
 235     $f->close();
 236 }
 237
 238 # Records must be fetched for all records satisfying $this->{query} If
 239 # $this->{targets} is already set (i.e. a specific list of targets to
 240 # check was specified by a call to targets()), then new, empty records
 241 # will be made for any targets that are not already in the database.
 242 #
 243 sub initialise {
 244     my $this = shift();
 245     my($tname) = @_;
 246
 247     $tname = "Main" if !defined $tname;
 248     $this->{test} = $tname;
 249     $this->{tree} = $this->_gather_tests($tname)
 250         or die "No tests defined for '$tname'";
 251     $this->{tree}->resolve();
 252     #$this->{tree}->print(0);
 253
 254     $this->{timeout} = "ZOOM::IRSpy::Test::$tname"->timeout();
 255
 256     my @targets;
 257     my $targets = $this->{targets};
 258     if (defined $targets) {
 259         @targets = @$targets;
 260         delete $this->{targets};
 261     } else {
 262         my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 263         $this->log("irspy", "'", $this->{query}, "' found ",
 264                    $rs->size(), " target records");
 265         delete $this->{query};
 266
 267         foreach my $i (1 .. $rs->size()) {
 268             push @targets, render_record($rs, $i-1, "id");
 269         }
 270     }
 271
 272     my $n = $this->{activeSetSize};
 273     $n = @targets if $n == 0 || $n > @targets;
 274
 275     $this->{queue} = \@targets;
 276     $this->{connections} = [];
 277     while (@{ $this->{connections} } < $n) {
 278         my $conn = $this->_next_connection();
 279         last if !defined $conn;
 280         push @{ $this->{connections} }, $conn;
 281     }
 282 }
 283
 284
 285 sub _next_connection {
 286     my $this = shift();
 287
 288     my $target;
 289     my $n = $this->{modn};
 290     my $i = $this->{modi};
 291     if (!defined $n) {
 292         $target = shift @{ $this->{queue} };
 293         return undef if !defined $target;
 294     } else {
 295         while (1) {
 296             $target = shift @{ $this->{queue} };
 297             return undef if !defined $target;
 298             my $h = _hash($target);
 299             my $hmodn = $h % $n;
 300             last if $hmodn == $i;
 301             #$this->log("irspy", "'$target' hash $h % $n = $hmodn != $i");
 302         }
 303     }
 304
 305     die "oops -- target is undefined" if !defined $target;
 306     return create ZOOM::IRSpy::Connection($this, $target, async => 1,
 307                                           timeout => $this->{timeout});
 308 }
 309
 310
 311 sub _hash {
 312     my($target) = @_;
 313
 314     my $n = 0;
 315     foreach my $s (split //, $target) {
 316         $n += ord($s);
 317     }
 318
 319     return $n;
 320 }
 321
 322
 323 sub _irspy_to_zeerex {
 324     my $this = shift();
 325     my($conn) = @_;
 326
 327     my $save_xml = $ENV{IRSPY_SAVE_XML};
 328     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 329
 330     if ($save_xml) {
 331         unlink('/tmp/irspy_orig.xml');
 332         open FH, '>/tmp/irspy_orig.xml'
 333             or die "can't write irspy_orig.xml: $!";
 334         print FH $irspy_doc->toString();
 335         close FH;
 336     }
 337     my %params = ();
 338     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 339     if ($save_xml) {
 340         unlink('/tmp/irspy_transformed.xml');
 341         open FH, '>/tmp/irspy_transformed.xml'
 342             or die "can't write irspy_transformed.xml: $!";
 343         print FH $result->toString();
 344         close FH;
 345     }
 346
 347     return $result->documentElement();
 348 }
 349
 350
 351 sub _rewrite_irspy_record {
 352     my $this = shift();
 353     my($conn) = @_;
 354
 355     $conn->log("irspy", "rewriting XML record");
 356     my $rec = $this->_irspy_to_zeerex($conn);
 357
 358     # Since IRSpy can run for a long time between writes back to the
 359     # database, it's quite possible for the server to have closed the
 360     # connection as idle.  So re-establish it if necessary.
 361     $this->{conn}->connect($conn->option("host"));
 362
 363     _rewrite_zeerex_record($this->{conn}, $rec);
 364     $conn->log("irspy", "rewrote XML record");
 365 }
 366
 367
 368 my $_reliabilityField = {
 369     reliability => [ reliability => 0,
 370                       "Calculated reliability of server",
 371                       "e:serverInfo/e:reliability" ],
 372 };
 373
 374 sub _rewrite_zeerex_record {
 375     my($conn, $rec, $oldid) = @_;
 376
 377     # Add reliability score
 378     my $xc = irspy_xpath_context($rec);
 379     my($nok, $nall, $percent) = calc_reliability_stats($xc);
 380     modify_xml_document($xc, $_reliabilityField, { reliability => $percent });
 381
 382     my $p = $conn->package();
 383     $p->option(action => "specialUpdate");
 384     my $xml = $rec->toString();
 385     $p->option(record => $xml);
 386     $p->send("update");
 387     $p->destroy();
 388
 389     # This is the expression in the ID-making stylesheet
 390     # ../../zebra/zeerex2id.xsl
 391     my $id = irspy_record2identifier($xc);
 392     if (defined $oldid && $id ne $oldid) {
 393         warn "IDs differ (old='$oldid' new='$id')";
 394         _delete_record($conn, $oldid);
 395     }
 396
 397     $p = $conn->package();
 398     $p->send("commit");
 399     $p->destroy();
 400     if (0) {
 401         $xml =~ s/&/&amp/g;
 402         $xml =~ s/</&lt;/g;
 403         $xml =~ s/>/&gt;/g;
 404         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 405     }
 406 }
 407
 408
 409 sub _delete_record {
 410     my($conn, $id) = @_;
 411
 412     # We can't delete records using recordIdOpaque, since character
 413     # sets are handled differently here in extended services from how
 414     # they are used in the Alvis filter's record-parsing, and so
 415     # non-ASCII characters come out differently in the two contexts.
 416     # Instead, we must send a record whose contents indicate the ID of
 417     # that which we wish to delete.  There are two ways, both
 418     # unsatisfactory: we could either fetch the actual record them
 419     # resubmit it in the deletion request (which wastes a search and a
 420     # fetch) or we could build a record by hand from the parsed-out
 421     # components (which is error-prone and which I am not 100% certain
 422     # will work since the other contents of the record will be
 423     # different).  The former evil seems to be the lesser.
 424
 425     warn "$conn deleting record '$id'";
 426
 427     my $rs = $conn->search(new ZOOM::Query::CQL(cql_target($id)));
 428     die "no such ID '$id'" if $rs->size() == 0;
 429     my $rec = $rs->record(0);
 430     my $xml = $rec->render();
 431
 432     my $p = $conn->package();
 433     $p->option(action => "recordDelete");
 434     $p->option(record => $xml);
 435     $p->send("update");
 436     $p->destroy();
 437
 438     $p = $conn->package();
 439     $p->send("commit");
 440     $p->destroy();
 441 }
 442
 443
 444 # The approach: gather declarative information about test hierarchy,
 445 # then go into a loop.  In the loop, we ensure that each connection is
 446 # running a test, and within that test a task, until its list of tests
 447 # is exhausted.  No individual test ever calls wait(): tests just queue
 448 # up tasks and return immediately.  When the tasks are run (one at a
 449 # time on each connection) they generate events, and it is these that
 450 # are harvested by ZOOM::event().  Since each connection knows what
 451 # task it is running, it can invoke the appropriate callbacks.
 452 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 453 # loop how to continue.
 454 #
 455 # Invariants:
 456 #       While a connection is running a task, its current_task()
 457 #       points at the task structure.  When it finishes its task,
 458 #       next_task() is pointed at the next task to execute (if there
 459 #       is one), and its current_task() is set to zero.  When the next
 460 #       task is executed, the connection's next_task() is set to zero
 461 #       and its current_task() pointed to the task structure.
 462 #       current_task() and next_task() are both zero only when there
 463 #       are no more queued tasks, which is when a new test is
 464 #       started.
 465 #
 466 #       Each connection's current test is stored in its
 467 #       "current_test_address" option.  The next test to execute is
 468 #       calculated by walking the declarative tree of tests.  This
 469 #       option begins empty; the "next test" after this is of course
 470 #       the root test.
 471 #
 472 sub check {
 473     my $this = shift();
 474
 475     my $topname = $this->{tree}->name();
 476     my $timeout = $this->{timeout};
 477     $this->log("irspy", "beginnning with test '$topname' (timeout $timeout)");
 478
 479     my $nskipped = 0;
 480     my @conn = @{ $this->{connections} };
 481
 482     my $nruns = 0;
 483   ROUND_AND_ROUND_WE_GO:
 484     while (1) {
 485         my @copy_conn = @conn;  # avoid alias problems after splice()
 486         my $nconn = scalar(@copy_conn);
 487
 488         foreach my $i0 (0 .. $#copy_conn) {
 489             my $conn = $copy_conn[$i0];
 490             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 491             next if !defined $conn;
 492
 493             if (!$conn->current_task()) {
 494                 if (!$conn->next_task()) {
 495                     # Out of tasks: we need a new test
 496                   NEXT_TEST:
 497                     my $address = $conn->option("current_test_address");
 498                     my $nextaddr;
 499                     if (!defined $address) {
 500                         $nextaddr = "";
 501                     } else {
 502                         $conn->log("irspy_test",
 503                                    "checking for next test after '$address'");
 504                         $nextaddr = $this->_next_test($address);
 505                     }
 506
 507                     if (ZOOM::IRSpy::Test::zoom_error_timeout_check($conn)) {
 508                         $conn->log("irspy", "Got to many timeouts, stop testing");
 509                         undef $nextaddr;
 510                     }
 511
 512                     if (!defined $nextaddr) {
 513                         $conn->log("irspy", "has no more tests: removing");
 514                         $this->_rewrite_irspy_record($conn);
 515                         $conn->option(rewrote_record => 1);
 516                         my $newconn = $this->_next_connection();
 517                         if (!defined $newconn) {
 518                             # Do not destroy: needed for later sanity checks
 519                             splice @conn, $i0, 1;
 520                         } else {
 521                             $conn->destroy();
 522                             $conn[$i0] = $newconn;
 523                             $conn[$i0]->option(current_test_address => "");
 524                             $conn[$i0]->log("irspy", "entering active pool - ",
 525                                             scalar(@{ $this->{queue} }),
 526                                             " targets remain in queue");
 527                         }
 528                         next;
 529                     }
 530
 531                     my $node = $this->{tree}->select($nextaddr)
 532                         or die "invalid nextaddr '$nextaddr'";
 533                     $conn->option(current_test_address => $nextaddr);
 534                     my $tname = $node->name();
 535                     if ($this->should_skip_test($tname)) {
 536                         warn "skipping test '$tname' due to rule";
 537                         goto NEXT_TEST;
 538                     }
 539
 540                     $conn->log("irspy_test",
 541                                "starting test '$nextaddr' = $tname");
 542                     my $tasks = $conn->tasks();
 543                     my $oldcount = @$tasks;
 544                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 545                     $tasks = $conn->tasks();
 546                     if (@$tasks > $oldcount) {
 547                         # Prepare to start the first of the newly added tasks
 548                         $conn->next_task($tasks->[$oldcount]);
 549                     } else {
 550                         $conn->log("irspy_task",
 551                                    "no tasks added by new test $tname");
 552                         goto NEXT_TEST;
 553                     }
 554                 }
 555
 556                 my $task = $conn->next_task();
 557                 die "no next task queued for $conn" if !defined $task;
 558
 559                 # do not run the next task if we got too many timeouts
 560                 if (ZOOM::IRSpy::Test::zoom_error_timeout_check($conn)) {
 561                     $conn->log("irspy_task", "Got too many timeouts for this target, do not start a new task");
 562                     next;
 563                 }
 564
 565                 $conn->log("irspy_task", "preparing task $task");
 566                 $conn->next_task(0);
 567                 $conn->current_task($task);
 568                 $task->run();
 569             }
 570         }
 571
 572       NEXT_EVENT:
 573         my $i0 = ZOOM::event(\@conn);
 574         $this->log("irspy_event",
 575                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 576         if ($i0 < 1) {
 577             my %messages = (
 578                             0 => "no events remain",
 579                             -1 => "ZOOM::event() argument not a reference",
 580                             -2 => "ZOOM::event() reference not an array",
 581                             -3 => "no connections remain",
 582                             -4 => "too many connections for ZOOM::event()",
 583                             );
 584             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 585             $this->log("irspy", $message);
 586             last;
 587         }
 588
 589         my $conn = $conn[$i0-1];
 590         my $ev = $conn->last_event();
 591         my $evstr = ZOOM::event_str($ev);
 592         $conn->log("irspy_event", "event $ev ($evstr)");
 593         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 594
 595         my $task = $conn->current_task();
 596         die "$conn has no current task for event $ev ($evstr)" if !$task;
 597
 598         my $res;
 599         eval { $conn->check() };
 600         if ($@ && ref $@ && $@->isa("ZOOM::Exception")) {
 601             my $sub = $task->{cb}->{exception};
 602             die $@ if !defined $sub;
 603             $res = &$sub($conn, $task, $task->udata(), $@);
 604         } elsif ($@) {
 605             die "Unexpected non-ZOOM exception: " . ref($@) . " ($@)";
 606         } else {
 607             my $sub = $task->{cb}->{$ev};
 608             if (!defined $sub) {
 609                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 610                 next;
 611             }
 612
 613             $res = &$sub($conn, $task, $task->udata(), $ev);
 614         }
 615
 616         if ($res == ZOOM::IRSpy::Status::OK) {
 617             # Nothing to do -- life continues
 618
 619         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 620             my $task = $conn->current_task();
 621             die "no task for TASK_DONE on $conn" if !$task;
 622             die "next task already defined for $conn" if $conn->next_task();
 623             $conn->log("irspy_task", "completed task $task");
 624             $conn->next_task($task->{next});
 625             $conn->current_task(0);
 626
 627         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 628                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 629             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 630             $conn->log("irspy_task", "test ended during task $task ($x)");
 631             $conn->log("irspy_test", "test completed ($x)");
 632             $conn->current_task(0);
 633             $conn->next_task(0);
 634             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 635                 my $address = $conn->option('current_test_address');
 636                 $conn->log("irspy", "top-level test failed!")
 637                     if $address eq "";
 638                 my $node = $this->{tree}->select($address);
 639                 my $skipcount = 0;
 640                 while (defined $node->next() &&
 641                        length($node->next()->address()) >= length($address)) {
 642                     $conn->log("irspy_debug", "skipping from '",
 643                                $node->address(), "' to '",
 644                                $node->next()->address(), "'");
 645                     $node = $node->next();
 646                     $skipcount++;
 647                 }
 648
 649                 $conn->option(current_test_address => $node->address());
 650                 $conn->log("irspy_test", "skipped $skipcount tests");
 651                 $nskipped += $skipcount;
 652             }
 653
 654         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 655             $conn->log("irspy_test", "test skipped during task $task");
 656             $conn->current_task(0);
 657             $conn->next_task(0);
 658             $nskipped++;
 659
 660         } else {
 661             die "unknown callback return-value '$res'";
 662         }
 663     }
 664
 665     $this->log("irspy", "exiting main loop");
 666
 667     # Sanity checks: none of the following should ever happen
 668     my $finished = 1;
 669     $this->log("irspy", "performing end-of-run sanity-checks");
 670     foreach my $conn (@conn) {
 671         my $test = $conn->option("current_test_address");
 672         my $next = $this->_next_test($test);
 673         if (defined $next) {
 674             $this->log("irspy",
 675                        "$conn (in test '$test') has queued test '$next'");
 676             $finished = 0;
 677         }
 678         if (my $task = $conn->current_task()) {
 679             $this->log("irspy", "$conn still has an active task $task");
 680             $finished = 0;
 681         }
 682         if (my $task = $conn->next_task()) {
 683             $this->log("irspy", "$conn still has a queued task $task");
 684             $finished = 0;
 685         }
 686         if (!$conn->is_idle()) {
 687             $this->log("irspy",
 688                        "$conn still has ZOOM-C level tasks queued: see below");
 689             $finished = 0;
 690         }
 691         my $ev = $conn->peek_event();
 692         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 693             my $evstr = ZOOM::event_str($ev);
 694             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 695             $finished = 0;
 696         }
 697         if (!$conn->option("rewrote_record")) {
 698             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 699             $finished = 0;
 700         }
 701     }
 702
 703     # This really shouldn't be necessary, and in practice it rarely
 704     # helps, but it's belt and braces.  (For now, we don't do this
 705     # hence the zero in the $nruns check).
 706     if (!$finished) {
 707         if (++$nruns < 0) {
 708             $this->log("irspy", "back into main loop, ${nruns}th time");
 709             goto ROUND_AND_ROUND_WE_GO;
 710         } else {
 711             $this->log("irspy", "bailing after $nruns main-loop runs");
 712         }
 713     }
 714
 715     # This shouldn't happen emit anything either:
 716     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 717         my $conn = $conn[$i1-1];
 718         my $ev = $conn->last_event();
 719         my $evstr = ZOOM::event_str($ev);
 720         $this->log("irspy",
 721                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 722             if $ev != ZOOM::Event::ZEND;
 723     }
 724
 725     return $nskipped;
 726 }
 727
 728
 729 ### This could of course call a much more general looping evaluator
 730 sub should_skip_test {
 731     my $this = shift();
 732     my($tname) = @_;
 733
 734     foreach my $rule (@{ $this->{rules} }) {
 735         my($name, $op, $val, $rule, @params) = @$rule;
 736         #warn "using name='$name', op='$op', val='$val', rule='$rule', params='@params'\n";
 737         if ($op eq "~" &&
 738             $rule eq "skip" &&
 739             $params[0] eq $tname) {
 740             my $re = $val;
 741             $re =~ s/^\/(.*)\/$/$1/;
 742             if ($this->var($name) =~ $re) {
 743                 #warn "$name '", $this->var($name), "' matches /$re/ -- skipping '$tname'";
 744                 return 1;
 745             }
 746         }
 747     }
 748
 749     return 0;
 750 }
 751
 752
 753 # Exactly equivalent to ZOOM::event() except that it is tolerant to
 754 # undefined values in the array being passed in.
 755 #
 756 sub __UNUSED_tolerant_ZOOM_event {
 757     my($connref) = @_;
 758
 759     my(@conn, @map);
 760     foreach my $i (0 .. @$connref-1) {
 761         my $conn = $connref->[$i];
 762         if (defined $conn) {
 763             push @conn, $conn;
 764             push @map, $i;
 765         }
 766     }
 767
 768     my $res = ZOOM::event(\@conn);
 769     return $res if $res <= 0;
 770     my $res2 = $map[$res-1] + 1;
 771     print STDERR "*** tolerant_ZOOM_event() returns $res->$res2\n";
 772     return $res2;
 773 }
 774
 775
 776 sub _gather_tests {
 777     my $this = shift();
 778     my($tname, @ancestors) = @_;
 779
 780     die("$0: test-hierarchy loop detected: " .
 781         join(" -> ", @ancestors, $tname))
 782         if grep { $_ eq $tname } @ancestors;
 783
 784     my $slashSeperatedTname = $tname;
 785     $slashSeperatedTname =~ s/::/\//g;
 786     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 787
 788     eval {
 789         require $fullName;
 790     }; if ($@) {
 791         $this->log("irspy", "couldn't require '$fullName': $@");
 792         $this->log("warn", "can't load test '$tname': skipping",
 793                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 794         return undef;
 795     }
 796
 797     $this->log("irspy", "adding test '$tname'");
 798     my @subnodes;
 799     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 800         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 801         push @subnodes, $subtest if defined $subtest;
 802     }
 803
 804     return new ZOOM::IRSpy::Node($tname, @subnodes);
 805 }
 806
 807
 808 # These next three should arguably be Node methods
 809 sub _next_test {
 810     my $this = shift();
 811     my($address, $omit_child) = @_;
 812
 813     # Try first child
 814     if (!$omit_child) {
 815         my $maybe = $address eq "" ? "0" : "$address:0";
 816         return $maybe if $this->{tree}->select($maybe);
 817     }
 818
 819     # The top-level node has no successor or parent
 820     return undef if $address eq "";
 821
 822     # Try next sibling child
 823     # The use of a regexp in split() is to avoid confusing Emacs's
 824     # Perl mode; the third colon is to avoid looking like a POSIX
 825     # named character class ... *sigh*
 826     my @components = split /[:::]/, $address;
 827     my $last = pop @components;
 828     my $maybe = join(":", @components, $last+1);
 829     return $maybe if $this->{tree}->select($maybe);
 830
 831     # This node is exhausted: try the parent's successor
 832     return $this->_next_test(join(":", @components), 1)
 833 }
 834
 835
 836 sub _last_sibling_test {
 837     die "_last_sibling_test() called -- I thought that never happened?";
 838     my $this = shift();
 839     my($address) = @_;
 840
 841     return undef
 842         if !defined $this->_next_sibling_test($address);
 843
 844     my $nskipped = 0;
 845     while (1) {
 846         my $maybe = $this->_next_sibling_test($address);
 847         last if !defined $maybe;
 848         $nskipped++;
 849         $address = $maybe;
 850         $this->log("irspy", "skipping $nskipped tests to '$address'");
 851     }
 852
 853     return ($address, $nskipped);
 854 }
 855
 856
 857 sub _next_sibling_test {
 858     die "_next_sibling_test() called -- I thought that never happened?";
 859     my $this = shift();
 860     my($address) = @_;
 861
 862     my @components = split /[:::]/, $address;
 863     my $last = pop @components;
 864     my $maybe = join(":", @components, $last+1);
 865     return $maybe if $this->{tree}->select($maybe);
 866     return undef;
 867 }
 868
 869
 870 =head1 SEE ALSO
 871
 872 ZOOM::IRSpy::Record,
 873 ZOOM::IRSpy::Web,
 874 ZOOM::IRSpy::Test,
 875 ZOOM::IRSpy::Maintenance.
 876
 877 The ZOOM-Perl module,
 878 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 879
 880 The Zebra Database,
 881 http://indexdata.com/zebra/
 882
 883 =head1 AUTHOR
 884
 885 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 886
 887 =head1 COPYRIGHT AND LICENSE
 888
 889 Copyright (C) 2006 by Index Data ApS.
 890
 891 This library is free software; you can redistribute it and/or modify
 892 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 893 at your option, any later version of Perl 5 you may have available.
 894
 895 =cut
 896
 897
 898 1;