lib/ZOOM.pm

   1 # $Id: ZOOM.pm,v 1.44 2007-01-16 11:17:28 mike Exp $
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::Z3950::ZOOM;
   7
   8
   9 package ZOOM;
  10
  11 # Member naming convention: hash-element names which begin with an
  12 # underscore represent underlying ZOOM-C object descriptors; those
  13 # which lack them represent Perl's ZOOM objects.  (The same convention
  14 # is used in naming local variables where appropriate.)
  15 #
  16 # So, for example, the ZOOM::Connection class has an {_conn} element,
  17 # which is a pointer to the ZOOM-C Connection object; but the
  18 # ZOOM::ResultSet class has a {conn} element, which is a reference to
  19 # the Perl-level Connection object by which it was created.  (It may
  20 # be that we find we have no need for these references, but for now
  21 # they are retained.)
  22 #
  23 # To get at the underlying ZOOM-C connection object of a result-set
  24 # (if you ever needed to do such a thing, which you probably don't)
  25 # you'd use $rs->{conn}->_conn().
  26
  27 # ----------------------------------------------------------------------------
  28
  29 # The "Error" package contains constants returned as error-codes.
  30 package ZOOM::Error;
  31 sub NONE { Net::Z3950::ZOOM::ERROR_NONE }
  32 sub CONNECT { Net::Z3950::ZOOM::ERROR_CONNECT }
  33 sub MEMORY { Net::Z3950::ZOOM::ERROR_MEMORY }
  34 sub ENCODE { Net::Z3950::ZOOM::ERROR_ENCODE }
  35 sub DECODE { Net::Z3950::ZOOM::ERROR_DECODE }
  36 sub CONNECTION_LOST { Net::Z3950::ZOOM::ERROR_CONNECTION_LOST }
  37 sub ZINIT { Net::Z3950::ZOOM::ERROR_INIT }
  38 sub INTERNAL { Net::Z3950::ZOOM::ERROR_INTERNAL }
  39 sub TIMEOUT { Net::Z3950::ZOOM::ERROR_TIMEOUT }
  40 sub UNSUPPORTED_PROTOCOL { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_PROTOCOL }
  41 sub UNSUPPORTED_QUERY { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_QUERY }
  42 sub INVALID_QUERY { Net::Z3950::ZOOM::ERROR_INVALID_QUERY }
  43 sub CQL_PARSE { Net::Z3950::ZOOM::ERROR_CQL_PARSE }
  44 sub CQL_TRANSFORM { Net::Z3950::ZOOM::ERROR_CQL_TRANSFORM }
  45 sub CCL_CONFIG { Net::Z3950::ZOOM::ERROR_CCL_CONFIG }
  46 sub CCL_PARSE { Net::Z3950::ZOOM::ERROR_CCL_PARSE }
  47 # The following are added specifically for this OO interface
  48 sub CREATE_QUERY { 20001 }
  49 sub QUERY_CQL { 20002 }
  50 sub QUERY_PQF { 20003 }
  51 sub SORTBY { 20004 }
  52 sub CLONE { 20005 }
  53 sub PACKAGE { 20006 }
  54 sub SCANTERM { 20007 }
  55 sub LOGLEVEL { 20008 }
  56
  57 # Separate space for CCL errors.  Great.
  58 package ZOOM::CCL::Error;
  59 sub OK { Net::Z3950::ZOOM::CCL_ERR_OK }
  60 sub TERM_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_TERM_EXPECTED }
  61 sub RP_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_RP_EXPECTED }
  62 sub SETNAME_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_SETNAME_EXPECTED }
  63 sub OP_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_OP_EXPECTED }
  64 sub BAD_RP { Net::Z3950::ZOOM::CCL_ERR_BAD_RP }
  65 sub UNKNOWN_QUAL { Net::Z3950::ZOOM::CCL_ERR_UNKNOWN_QUAL }
  66 sub DOUBLE_QUAL { Net::Z3950::ZOOM::CCL_ERR_DOUBLE_QUAL }
  67 sub EQ_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_EQ_EXPECTED }
  68 sub BAD_RELATION { Net::Z3950::ZOOM::CCL_ERR_BAD_RELATION }
  69 sub TRUNC_NOT_LEFT { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_LEFT }
  70 sub TRUNC_NOT_BOTH { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_BOTH }
  71 sub TRUNC_NOT_RIGHT { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_RIGHT }
  72
  73 # The "Event" package contains constants returned by last_event()
  74 package ZOOM::Event;
  75 sub NONE { Net::Z3950::ZOOM::EVENT_NONE }
  76 sub CONNECT { Net::Z3950::ZOOM::EVENT_CONNECT }
  77 sub SEND_DATA { Net::Z3950::ZOOM::EVENT_SEND_DATA }
  78 sub RECV_DATA { Net::Z3950::ZOOM::EVENT_RECV_DATA }
  79 sub TIMEOUT { Net::Z3950::ZOOM::EVENT_TIMEOUT }
  80 sub UNKNOWN { Net::Z3950::ZOOM::EVENT_UNKNOWN }
  81 sub SEND_APDU { Net::Z3950::ZOOM::EVENT_SEND_APDU }
  82 sub RECV_APDU { Net::Z3950::ZOOM::EVENT_RECV_APDU }
  83 sub RECV_RECORD { Net::Z3950::ZOOM::EVENT_RECV_RECORD }
  84 sub RECV_SEARCH { Net::Z3950::ZOOM::EVENT_RECV_SEARCH }
  85 sub ZEND { Net::Z3950::ZOOM::EVENT_END }
  86
  87 # ----------------------------------------------------------------------------
  88
  89 package ZOOM;
  90
  91 sub diag_str {
  92     my($code) = @_;
  93
  94     # Special cases for error specific to the OO layer
  95     if ($code == ZOOM::Error::CREATE_QUERY) {
  96         return "can't create query object";
  97     } elsif ($code == ZOOM::Error::QUERY_CQL) {
  98         return "can't set CQL query";
  99     } elsif ($code == ZOOM::Error::QUERY_PQF) {
 100         return "can't set prefix query";
 101     } elsif ($code == ZOOM::Error::SORTBY) {
 102         return "can't set sort-specification";
 103     } elsif ($code == ZOOM::Error::CLONE) {
 104         return "can't clone record";
 105     } elsif ($code == ZOOM::Error::PACKAGE) {
 106         return "can't create package";
 107     } elsif ($code == ZOOM::Error::SCANTERM) {
 108         return "can't retrieve term from scan-set";
 109     } elsif ($code == ZOOM::Error::LOGLEVEL) {
 110         return "unregistered log-level";
 111     }
 112
 113     return Net::Z3950::ZOOM::diag_str($code);
 114 }
 115
 116 sub event_str {
 117     return Net::Z3950::ZOOM::event_str(@_);
 118 }
 119
 120 sub event {
 121     my($connsref) = @_;
 122
 123     my @_connsref = map { $_->_conn() } @$connsref;
 124     return Net::Z3950::ZOOM::event(\@_connsref);
 125 }
 126
 127 sub _oops {
 128     my($code, $addinfo, $diagset) = @_;
 129
 130     die new ZOOM::Exception($code, undef, $addinfo, $diagset);
 131 }
 132
 133 # ----------------------------------------------------------------------------
 134
 135 package ZOOM::Exception;
 136
 137 sub new {
 138     my $class = shift();
 139     my($code, $message, $addinfo, $diagset) = @_;
 140
 141     $diagset ||= "ZOOM";
 142     if (uc($diagset) eq "ZOOM" || uc($diagset) eq "BIB-1") {
 143         $message ||= ZOOM::diag_str($code);
 144     } else {
 145         # Should fill in messages for other diagsets, too.
 146     }
 147
 148     return bless {
 149         code => $code,
 150         message => $message,
 151         addinfo => $addinfo,
 152         diagset => $diagset,
 153     }, $class;
 154 }
 155
 156 sub code {
 157     my $this = shift();
 158     return $this->{code};
 159 }
 160
 161 sub message {
 162     my $this = shift();
 163     return $this->{message};
 164 }
 165
 166 sub addinfo {
 167     my $this = shift();
 168     return $this->{addinfo};
 169 }
 170
 171 sub diagset {
 172     my $this = shift();
 173     return $this->{diagset};
 174 }
 175
 176 sub render {
 177     my $this = shift();
 178     my $res = "ZOOM error " . $this->code() . ' "' . $this->message() . '"';
 179     $res .= ' (addinfo: "' . $this->addinfo() . '")' if $this->addinfo();
 180     $res .= " from diag-set '" . $this->diagset() . "'" if $this->diagset();
 181     return $res;
 182 }
 183
 184 # This means that untrapped exceptions render nicely.
 185 use overload '""' => \&render;
 186
 187 # ----------------------------------------------------------------------------
 188
 189 package ZOOM::Options;
 190
 191 sub new {
 192     my $class = shift();
 193     my($p1, $p2) = @_;
 194
 195     my $opts;
 196     if (@_ == 0) {
 197         $opts = Net::Z3950::ZOOM::options_create();
 198     } elsif (@_ == 1) {
 199         $opts = Net::Z3950::ZOOM::options_create_with_parent($p1->_opts());
 200     } elsif (@_ == 2) {
 201         $opts = Net::Z3950::ZOOM::options_create_with_parent2($p1->_opts(),
 202                                                               $p2->_opts());
 203     } else {
 204         die "can't make $class object with more than 2 parents";
 205     }
 206
 207     return bless {
 208         _opts => $opts,
 209     }, $class;
 210 }
 211
 212 # PRIVATE to this class and ZOOM::Connection::create() and
 213 # ZOOM::Connection::package()
 214 #
 215 sub _opts {
 216     my $this = shift();
 217
 218     my $_opts = $this->{_opts};
 219     die "{_opts} undefined: has this Options block been destroy()ed?"
 220         if !defined $_opts;
 221
 222     return $_opts;
 223 }
 224
 225 sub option {
 226     my $this = shift();
 227     my($key, $value) = @_;
 228
 229     my $oldval = Net::Z3950::ZOOM::options_get($this->_opts(), $key);
 230     Net::Z3950::ZOOM::options_set($this->_opts(), $key, $value)
 231         if defined $value;
 232
 233     return $oldval;
 234 }
 235
 236 sub option_binary {
 237     my $this = shift();
 238     my($key, $value) = @_;
 239
 240     my $dummylen = 0;
 241     my $oldval = Net::Z3950::ZOOM::options_getl($this->_opts(),
 242                                                 $key, $dummylen);
 243     Net::Z3950::ZOOM::options_setl($this->_opts(), $key,
 244                                    $value, length($value))
 245         if defined $value;
 246
 247     return $oldval;
 248 }
 249
 250 # This is a bit stupid, since the scalar values that Perl returns from
 251 # option() can be used as a boolean; but it's just possible that some
 252 # applications will rely on ZOOM_options_get_bool()'s idiosyncratic
 253 # interpretation of what constitutes truth.
 254 #
 255 sub bool {
 256     my $this = shift();
 257     my($key, $default) = @_;
 258
 259     return Net::Z3950::ZOOM::options_get_bool($this->_opts(), $key, $default);
 260 }
 261
 262 # .. and the next two are even more stupid
 263 sub int {
 264     my $this = shift();
 265     my($key, $default) = @_;
 266
 267     return Net::Z3950::ZOOM::options_get_int($this->_opts(), $key, $default);
 268 }
 269
 270 sub set_int {
 271     my $this = shift();
 272     my($key, $value) = @_;
 273
 274     Net::Z3950::ZOOM::options_set_int($this->_opts(), $key, $value);
 275 }
 276
 277 #   ### Feel guilty.  Feel very, very guilty.  I've not been able to
 278 #       get the callback memory-management right in "ZOOM.xs", with
 279 #       the result that the values of $function and $udata passed into
 280 #       this function, which are on the stack, have sometimes been
 281 #       freed by the time they're used by __ZOOM_option_callback(),
 282 #       with hilarious results.  To avoid this, I copy the values into
 283 #       module-scoped globals, and pass _those_ into the extension
 284 #       function.  To avoid overwriting those globals by subsequent
 285 #       calls, I keep all the old ones, pushed onto the @_function and
 286 #       @_udata arrays, which means that THIS FUNCTION LEAKS MEMORY
 287 #       LIKE IT'S GOING OUT OF FASHION.  Not nice.  One day, I should
 288 #       fix this, but for now there's more important fish to fry.
 289 #
 290 my(@_function, @_udata);
 291 sub set_callback {
 292     my $o1 = shift();
 293     my($function, $udata) = @_;
 294
 295     push @_function, $function;
 296     push @_udata, $udata;
 297     Net::Z3950::ZOOM::options_set_callback($o1->_opts(),
 298                                            $_function[-1], $_udata[-1]);
 299 }
 300
 301 sub destroy {
 302     my $this = shift();
 303
 304     Net::Z3950::ZOOM::options_destroy($this->_opts());
 305     $this->{_opts} = undef;
 306 }
 307
 308
 309 # ----------------------------------------------------------------------------
 310
 311 package ZOOM::Connection;
 312
 313 sub new {
 314     my $class = shift();
 315     my($host, $port, @options) = @_;
 316
 317     my $conn = $class->create(@options);
 318     $conn->{host} = $host;
 319     $conn->{port} = $port;
 320
 321     Net::Z3950::ZOOM::connection_connect($conn->_conn(), $host, $port || 0);
 322     $conn->_check();
 323
 324     return $conn;
 325 }
 326
 327 # PRIVATE to this class, to ZOOM::event() and to ZOOM::Query::CQL2RPN::new()
 328 sub _conn {
 329     my $this = shift();
 330
 331     my $_conn = $this->{_conn};
 332     die "{_conn} undefined: has this Connection been destroy()ed?"
 333         if !defined $_conn;
 334
 335     return $_conn;
 336 }
 337
 338 sub _check {
 339     my $this = shift();
 340
 341     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "x", "x", "x");
 342     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 343                                                     $addinfo, $diagset);
 344     die new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset)
 345         if $errcode;
 346 }
 347
 348 sub create {
 349     my $class = shift();
 350     my(@options) = @_;
 351
 352     my $_opts;
 353     if (@_ == 1) {
 354         $_opts = $_[0]->_opts();
 355     } else {
 356         $_opts = Net::Z3950::ZOOM::options_create();
 357         while (@options >= 2) {
 358             my $key = shift(@options);
 359             my $val = shift(@options);
 360             Net::Z3950::ZOOM::options_set($_opts, $key, $val);
 361         }
 362
 363         die "Odd number of options specified"
 364             if @options;
 365     }
 366
 367     my $_conn = Net::Z3950::ZOOM::connection_create($_opts);
 368     my $conn = bless {
 369         host => undef,
 370         port => undef,
 371         _conn => $_conn,
 372     }, $class;
 373     return $conn;
 374 }
 375
 376 sub error_x {
 377     my $this = shift();
 378
 379     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 380     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 381                                                     $addinfo, $diagset);
 382     return wantarray() ? ($errcode, $errmsg, $addinfo, $diagset) : $errcode;
 383 }
 384
 385 sub errcode {
 386     my $this = shift();
 387     return Net::Z3950::ZOOM::connection_errcode($this->_conn());
 388 }
 389
 390 sub errmsg {
 391     my $this = shift();
 392     return Net::Z3950::ZOOM::connection_errmsg($this->_conn());
 393 }
 394
 395 sub addinfo {
 396     my $this = shift();
 397     return Net::Z3950::ZOOM::connection_addinfo($this->_conn());
 398 }
 399
 400 sub diagset {
 401     my $this = shift();
 402     return Net::Z3950::ZOOM::connection_diagset($this->_conn());
 403 }
 404
 405 sub connect {
 406     my $this = shift();
 407     my($host, $port) = @_;
 408
 409     $port = 0 if !defined $port;
 410     Net::Z3950::ZOOM::connection_connect($this->_conn(), $host, $port);
 411     $this->_check();
 412     # No return value
 413 }
 414
 415 sub option {
 416     my $this = shift();
 417     my($key, $value) = @_;
 418
 419     my $oldval = Net::Z3950::ZOOM::connection_option_get($this->_conn(), $key);
 420     Net::Z3950::ZOOM::connection_option_set($this->_conn(), $key, $value)
 421         if defined $value;
 422
 423     return $oldval;
 424 }
 425
 426 sub option_binary {
 427     my $this = shift();
 428     my($key, $value) = @_;
 429
 430     my $dummylen = 0;
 431     my $oldval = Net::Z3950::ZOOM::connection_option_getl($this->_conn(),
 432                                                           $key, $dummylen);
 433     Net::Z3950::ZOOM::connection_option_setl($this->_conn(), $key,
 434                                              $value, length($value))
 435         if defined $value;
 436
 437     return $oldval;
 438 }
 439
 440 sub search {
 441     my $this = shift();
 442     my($query) = @_;
 443
 444     my $_rs = Net::Z3950::ZOOM::connection_search($this->_conn(),
 445                                                   $query->_query());
 446     $this->_check();
 447     return _new ZOOM::ResultSet($this, $query, $_rs);
 448 }
 449
 450 sub search_pqf {
 451     my $this = shift();
 452     my($pqf) = @_;
 453
 454     my $_rs = Net::Z3950::ZOOM::connection_search_pqf($this->_conn(), $pqf);
 455     $this->_check();
 456     return _new ZOOM::ResultSet($this, $pqf, $_rs);
 457 }
 458
 459 sub scan_pqf {
 460     my $this = shift();
 461     my($startterm) = @_;
 462
 463     my $_ss = Net::Z3950::ZOOM::connection_scan($this->_conn(), $startterm);
 464     $this->_check();
 465     return _new ZOOM::ScanSet($this, $startterm, $_ss);
 466 }
 467
 468 sub scan {
 469     my $this = shift();
 470     my($query) = @_;
 471
 472     my $_ss = Net::Z3950::ZOOM::connection_scan1($this->_conn(),
 473                                                  $query->_query());
 474     $this->_check();
 475     return _new ZOOM::ScanSet($this, $query, $_ss);
 476 }
 477
 478 sub package {
 479     my $this = shift();
 480     my($options) = @_;
 481
 482     my $_o = defined $options ? $options->_opts() :
 483         Net::Z3950::ZOOM::options_create();
 484     my $_p = Net::Z3950::ZOOM::connection_package($this->_conn(), $_o)
 485         or ZOOM::_oops(ZOOM::Error::PACKAGE);
 486
 487     return _new ZOOM::Package($this, $options, $_p);
 488 }
 489
 490 sub last_event {
 491     my $this = shift();
 492
 493     return Net::Z3950::ZOOM::connection_last_event($this->_conn());
 494 }
 495
 496 sub is_idle {
 497     my $this = shift();
 498
 499     return Net::Z3950::ZOOM::connection_is_idle($this->_conn());
 500 }
 501
 502 sub peek_event {
 503     my $this = shift();
 504
 505     return Net::Z3950::ZOOM::connection_peek_event($this->_conn());
 506 }
 507
 508 sub destroy {
 509     my $this = shift();
 510
 511     Net::Z3950::ZOOM::connection_destroy($this->_conn());
 512     $this->{_conn} = undef;
 513 }
 514
 515
 516 # ----------------------------------------------------------------------------
 517
 518 package ZOOM::Query;
 519
 520 sub new {
 521     my $class = shift();
 522     die "You can't create $class objects: it's a virtual base class";
 523 }
 524
 525 # PRIVATE to this class and ZOOM::Connection::search()
 526 sub _query {
 527     my $this = shift();
 528
 529     my $_query = $this->{_query};
 530     die "{_query} undefined: has this Query been destroy()ed?"
 531         if !defined $_query;
 532
 533     return $_query;
 534 }
 535
 536 sub sortby {
 537     my $this = shift();
 538     my($sortby) = @_;
 539
 540     Net::Z3950::ZOOM::query_sortby($this->_query(), $sortby) == 0
 541         or ZOOM::_oops(ZOOM::Error::SORTBY, $sortby);
 542 }
 543
 544 sub destroy {
 545     my $this = shift();
 546
 547     Net::Z3950::ZOOM::query_destroy($this->_query());
 548     $this->{_query} = undef;
 549 }
 550
 551
 552 package ZOOM::Query::CQL;
 553 our @ISA = qw(ZOOM::Query);
 554
 555 sub new {
 556     my $class = shift();
 557     my($string) = @_;
 558
 559     my $q = Net::Z3950::ZOOM::query_create()
 560         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 561     Net::Z3950::ZOOM::query_cql($q, $string) == 0
 562         or ZOOM::_oops(ZOOM::Error::QUERY_CQL, $string);
 563
 564     return bless {
 565         _query => $q,
 566     }, $class;
 567 }
 568
 569
 570 package ZOOM::Query::CQL2RPN;
 571 our @ISA = qw(ZOOM::Query);
 572
 573 sub new {
 574     my $class = shift();
 575     my($string, $conn) = @_;
 576
 577     my $q = Net::Z3950::ZOOM::query_create()
 578         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 579     # check() throws the exception we want; but we only want it on failure!
 580     Net::Z3950::ZOOM::query_cql2rpn($q, $string, $conn->_conn()) == 0
 581         or $conn->_check();
 582
 583     return bless {
 584         _query => $q,
 585     }, $class;
 586 }
 587
 588
 589 # We have to work around the retarded ZOOM_query_ccl2rpn() API
 590 package ZOOM::Query::CCL2RPN;
 591 our @ISA = qw(ZOOM::Query);
 592
 593 sub new {
 594     my $class = shift();
 595     my($string, $conn) = @_;
 596
 597     my $q = Net::Z3950::ZOOM::query_create()
 598         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 599
 600     my $config = $conn->option("cclqual");
 601     if (!defined $config) {
 602         my $cclfile = $conn->option("cclfile")
 603             or ZOOM::_oops(ZOOM::Error::CCL_CONFIG,
 604                            "no 'cclqual' or 'cclfile' specified");
 605         my $fh = new IO::File("<$cclfile")
 606             or ZOOM::_oops(ZOOM::Error::CCL_CONFIG,
 607                            "can't open cclfile '$cclfile': $!");
 608         $config = join("", <$fh>);
 609         $fh->close();
 610     }
 611
 612     my($ccl_errcode, $ccl_errstr, $ccl_errpos) = (0, "", 0);
 613     if (Net::Z3950::ZOOM::query_ccl2rpn($q, $string, $config,
 614                                         $ccl_errcode, $ccl_errstr,
 615                                         $ccl_errpos) < 0) {
 616         # We have no use for $ccl_errcode or $ccl_errpos
 617         ZOOM::_oops(ZOOM::Error::CCL_PARSE, $ccl_errstr);
 618     }
 619
 620     return bless {
 621         _query => $q,
 622     }, $class;
 623 }
 624
 625
 626 package ZOOM::Query::PQF;
 627 our @ISA = qw(ZOOM::Query);
 628
 629 sub new {
 630     my $class = shift();
 631     my($string) = @_;
 632
 633     my $q = Net::Z3950::ZOOM::query_create()
 634         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 635     Net::Z3950::ZOOM::query_prefix($q, $string) == 0
 636         or ZOOM::_oops(ZOOM::Error::QUERY_PQF, $string);
 637
 638     return bless {
 639         _query => $q,
 640     }, $class;
 641 }
 642
 643
 644 # ----------------------------------------------------------------------------
 645
 646 package ZOOM::ResultSet;
 647
 648 sub new {
 649     my $class = shift();
 650     die "You can't create $class objects directly";
 651 }
 652
 653 # PRIVATE to ZOOM::Connection::search() and ZOOM::Connection::search_pqf()
 654 sub _new {
 655     my $class = shift();
 656     my($conn, $query, $_rs) = @_;
 657
 658     return bless {
 659         conn => $conn,
 660         query => $query,        # This is not currently used, which is
 661                                 # just as well since it could be
 662                                 # either a string (when the RS is
 663                                 # created with search_pqf()) or a
 664                                 # ZOOM::Query object (when it's
 665                                 # created with search())
 666         _rs => $_rs,
 667     }, $class;
 668 }
 669
 670 # PRIVATE to this class
 671 sub _rs {
 672     my $this = shift();
 673
 674     my $_rs = $this->{_rs};
 675     die "{_rs} undefined: has this ResultSet been destroy()ed?"
 676         if !defined $_rs;
 677
 678     return $_rs;
 679 }
 680
 681 sub option {
 682     my $this = shift();
 683     my($key, $value) = @_;
 684
 685     my $oldval = Net::Z3950::ZOOM::resultset_option_get($this->_rs(), $key);
 686     Net::Z3950::ZOOM::resultset_option_set($this->_rs(), $key, $value)
 687         if defined $value;
 688
 689     return $oldval;
 690 }
 691
 692 sub size {
 693     my $this = shift();
 694
 695     return Net::Z3950::ZOOM::resultset_size($this->_rs());
 696 }
 697
 698 sub record {
 699     my $this = shift();
 700     my($which) = @_;
 701
 702     my $_rec = Net::Z3950::ZOOM::resultset_record($this->_rs(), $which);
 703     $this->{conn}->_check();
 704
 705     # Even if no error has occurred, I think record() might
 706     # legitimately return undef if we're running in asynchronous mode
 707     # and the record just hasn't been retrieved yet.  This goes double
 708     # for record_immediate().
 709     return undef if !defined $_rec;
 710
 711     # For some reason, I have to use the explicit "->" syntax in order
 712     # to invoke the ZOOM::Record constructor here, even though I don't
 713     # have to do the same for _new ZOOM::ResultSet above.  Weird.
 714     return ZOOM::Record->_new($this, $which, $_rec);
 715 }
 716
 717 sub record_immediate {
 718     my $this = shift();
 719     my($which) = @_;
 720
 721     my $_rec = Net::Z3950::ZOOM::resultset_record_immediate($this->_rs(),
 722                                                             $which);
 723     $this->{conn}->_check();
 724     # The record might legitimately not be there yet
 725     return undef if !defined $_rec;
 726
 727     return ZOOM::Record->_new($this, $which, $_rec);
 728 }
 729
 730 sub cache_reset {
 731     my $this = shift();
 732
 733     Net::Z3950::ZOOM::resultset_cache_reset($this->_rs());
 734 }
 735
 736 sub records {
 737     my $this = shift();
 738     my($start, $count, $return_records) = @_;
 739
 740     # If the request is out of range, ZOOM-C will currently (as of YAZ
 741     # 2.1.38) no-op: it understandably refuses to build and send a
 742     # known-bad APDU, but it doesn't set a diagnostic as it ought.  So
 743     # for now, we do it here.  It would be more polite to stash the
 744     # error-code in the ZOOM-C connection object for subsequent
 745     # discovery (which is what ZOOM-C will presumably do itself when
 746     # it's fixed) but since there is no API that allows us to do that,
 747     # we just have to throw the exception right now.  That's probably
 748     # OK for synchronous applications, but not really for
 749     # multiplexers.
 750     my $size = $this->size();
 751     if ($start + $count-1 >= $size) {
 752         # BIB-1 diagnostic 13 is "Present request out-of-range"
 753         ZOOM::_oops(13, undef, "BIB-1");
 754     }
 755
 756     my $raw = Net::Z3950::ZOOM::resultset_records($this->_rs(), $start, $count,
 757                                                   $return_records);
 758     # By design, $raw may be undefined (if $return_records is true)
 759     return undef if !defined $raw;
 760
 761     # We need to package up the returned records in ZOOM::Record objects
 762     my @res = ();
 763     for my $i (0 .. @$raw-1) {
 764         my $_rec = $raw->[$i];
 765         if (!defined $_rec) {
 766             push @res, undef;
 767         } else {
 768             push @res, ZOOM::Record->_new($this, $start+$i, $_rec);
 769         }
 770     }
 771
 772     return \@res;
 773 }
 774
 775 sub sort {
 776     my $this = shift();
 777     my($sort_type, $sort_spec) = @_;
 778
 779     return Net::Z3950::ZOOM::resultset_sort1($this->_rs(),
 780                                              $sort_type, $sort_spec);
 781 }
 782
 783 sub destroy {
 784     my $this = shift();
 785
 786     Net::Z3950::ZOOM::resultset_destroy($this->_rs());
 787     $this->{_rs} = undef;
 788 }
 789
 790
 791 # ----------------------------------------------------------------------------
 792
 793 package ZOOM::Record;
 794
 795 sub new {
 796     my $class = shift();
 797     die "You can't create $class objects directly";
 798 }
 799
 800 # PRIVATE to ZOOM::ResultSet::record(),
 801 # ZOOM::ResultSet::record_immediate(), ZOOM::ResultSet::records() and
 802 # ZOOM::Record::clone()
 803 #
 804 sub _new {
 805     my $class = shift();
 806     my($rs, $which, $_rec) = @_;
 807
 808     return bless {
 809         rs => $rs,
 810         which => $which,
 811         _rec => $_rec,
 812     }, $class;
 813 }
 814
 815 # PRIVATE to this class
 816 sub _rec {
 817     my $this = shift();
 818
 819     my $_rec = $this->{_rec};
 820     die "{_rec} undefined: has this Record been destroy()ed?"
 821         if !defined $_rec;
 822
 823     return $_rec;
 824 }
 825
 826 sub error {
 827     my $this = shift();
 828
 829     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 830     $errcode = Net::Z3950::ZOOM::record_error($this->_rec(), $errmsg,
 831                                               $addinfo, $diagset);
 832
 833     return wantarray() ? ($errcode, $errmsg, $addinfo, $diagset) : $errcode;
 834 }
 835
 836 sub exception {
 837     my $this = shift();
 838
 839     my($errcode, $errmsg, $addinfo, $diagset) = $this->error();
 840     return undef if $errcode == 0;
 841     return new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset);
 842 }
 843
 844
 845 sub render {
 846     my $this = shift();
 847
 848     return $this->get("render", @_);
 849 }
 850
 851 sub raw {
 852     my $this = shift();
 853
 854     return $this->get("raw", @_);
 855 }
 856
 857 sub get {
 858     my $this = shift();
 859     my($type, $args) = @_;
 860
 861     $type = "$type;$args" if defined $args;
 862     my $len = 0;
 863     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), $type, $len);
 864     # I don't think we need '$len' at all.  ### Probably the Perl-to-C
 865     # glue code should use the value of `len' as well as the opaque
 866     # data-pointer returned, to ensure that the SV contains all of the
 867     # returned data and does not stop at the first NUL character in
 868     # binary data.  Carefully check the ZOOM_record_get() documentation.
 869     return $string;
 870 }
 871
 872 sub clone {
 873     my $this = shift();
 874
 875     my $raw = Net::Z3950::ZOOM::record_clone($this->_rec())
 876         or ZOOM::_oops(ZOOM::Error::CLONE);
 877
 878     # Arg 1 (rs) is undefined as the new record doesn't belong to an RS
 879     return _new ZOOM::Record(undef, undef, $raw);
 880 }
 881
 882 sub destroy {
 883     my $this = shift();
 884
 885     Net::Z3950::ZOOM::record_destroy($this->_rec());
 886     $this->{_rec} = undef;
 887 }
 888
 889
 890 # ----------------------------------------------------------------------------
 891
 892 package ZOOM::ScanSet;
 893
 894 sub new {
 895     my $class = shift();
 896     die "You can't create $class objects directly";
 897 }
 898
 899 # PRIVATE to ZOOM::Connection::scan(),
 900 sub _new {
 901     my $class = shift();
 902     my($conn, $startterm, $_ss) = @_;
 903
 904     return bless {
 905         conn => $conn,
 906         startterm => $startterm,# This is not currently used, which is
 907                                 # just as well since it could be
 908                                 # either a string (when the SS is
 909                                 # created with scan()) or a
 910                                 # ZOOM::Query object (when it's
 911                                 # created with scan1())
 912         _ss => $_ss,
 913     }, $class;
 914 }
 915
 916 # PRIVATE to this class
 917 sub _ss {
 918     my $this = shift();
 919
 920     my $_ss = $this->{_ss};
 921     die "{_ss} undefined: has this ScanSet been destroy()ed?"
 922         if !defined $_ss;
 923
 924     return $_ss;
 925 }
 926
 927 sub option {
 928     my $this = shift();
 929     my($key, $value) = @_;
 930
 931     my $oldval = Net::Z3950::ZOOM::scanset_option_get($this->_ss(), $key);
 932     Net::Z3950::ZOOM::scanset_option_set($this->_ss(), $key, $value)
 933         if defined $value;
 934
 935     return $oldval;
 936 }
 937
 938 sub size {
 939     my $this = shift();
 940
 941     return Net::Z3950::ZOOM::scanset_size($this->_ss());
 942 }
 943
 944 sub term {
 945     my $this = shift();
 946     my($which) = @_;
 947
 948     my($occ, $len) = (0, 0);
 949     my $term = Net::Z3950::ZOOM::scanset_term($this->_ss(), $which,
 950                                               $occ, $len)
 951         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 952
 953     die "length of term '$term' differs from returned len=$len"
 954         if length($term) != $len;
 955
 956     return ($term, $occ);
 957 }
 958
 959 sub display_term {
 960     my $this = shift();
 961     my($which) = @_;
 962
 963     my($occ, $len) = (0, 0);
 964     my $term = Net::Z3950::ZOOM::scanset_display_term($this->_ss(), $which,
 965                                                       $occ, $len)
 966         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 967
 968     die "length of display term '$term' differs from returned len=$len"
 969         if length($term) != $len;
 970
 971     return ($term, $occ);
 972 }
 973
 974 sub destroy {
 975     my $this = shift();
 976
 977     Net::Z3950::ZOOM::scanset_destroy($this->_ss());
 978     $this->{_ss} = undef;
 979 }
 980
 981
 982 # ----------------------------------------------------------------------------
 983
 984 package ZOOM::Package;
 985
 986 sub new {
 987     my $class = shift();
 988     die "You can't create $class objects directly";
 989 }
 990
 991 # PRIVATE to ZOOM::Connection::package(),
 992 sub _new {
 993     my $class = shift();
 994     my($conn, $options, $_p) = @_;
 995
 996     return bless {
 997         conn => $conn,
 998         options => $options,
 999         _p => $_p,
1000     }, $class;
1001 }
1002
1003 # PRIVATE to this class
1004 sub _p {
1005     my $this = shift();
1006
1007     my $_p = $this->{_p};
1008     die "{_p} undefined: has this Package been destroy()ed?"
1009         if !defined $_p;
1010
1011     return $_p;
1012 }
1013
1014 sub option {
1015     my $this = shift();
1016     my($key, $value) = @_;
1017
1018     my $oldval = Net::Z3950::ZOOM::package_option_get($this->_p(), $key);
1019     Net::Z3950::ZOOM::package_option_set($this->_p(), $key, $value)
1020         if defined $value;
1021
1022     return $oldval;
1023 }
1024
1025 sub send {
1026     my $this = shift();
1027     my($type) = @_;
1028
1029     Net::Z3950::ZOOM::package_send($this->_p(), $type);
1030     $this->{conn}->_check();
1031 }
1032
1033 sub destroy {
1034     my $this = shift();
1035
1036     Net::Z3950::ZOOM::package_destroy($this->_p());
1037     $this->{_p} = undef;
1038 }
1039
1040
1041 # There follows trivial support for YAZ logging.  This is wired out
1042 # into the Net::Z3950::ZOOM package, and we here provide wrapper
1043 # functions -- nothing more than aliases, really -- in the ZOOM::Log
1044 # package.  There really is no point in inventing an OO interface.
1045 #
1046 # Passing @_ directly to the underlying Net::Z3950::ZOOM::* functions
1047 # doesn't work, for reasons that I can't begin to fathom, and that
1048 # don't particularly interest me.  Unpacking into scalars and passing
1049 # those _does_ work, so that's what we do.
1050
1051 package ZOOM::Log;
1052
1053 sub mask_str      { my($a) = @_; Net::Z3950::ZOOM::yaz_log_mask_str($a); }
1054 sub module_level  { my($a) = @_; Net::Z3950::ZOOM::yaz_log_module_level($a); }
1055 sub init          { my($a, $b, $c) = @_;
1056                     Net::Z3950::ZOOM::yaz_log_init($a, $b, $c) }
1057 sub init_file     { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_file($a) }
1058 sub init_level    { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_level($a) }
1059 sub init_prefix   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_prefix($a) }
1060 sub time_format   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_time_format($a) }
1061 sub init_max_size { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_max_size($a) }
1062
1063 sub log {
1064     my($level, @message) = @_;
1065
1066     if ($level !~ /^(0x)?\d+$/) {
1067         # Assuming its log-level name, we look it up.
1068         my $num = module_level($level);
1069         ZOOM::_oops(ZOOM::Error::LOGLEVEL, $level)
1070             if $num == 0;
1071         $level = $num;
1072     }
1073
1074     Net::Z3950::ZOOM::yaz_log($level, join("", @message));
1075 }
1076
1077
1078 1;