lib/ZOOM.pm

   1 # $Id: ZOOM.pm,v 1.48 2007-05-09 12:03:52 mike Exp $
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::Z3950::ZOOM;
   7
   8
   9 package ZOOM;
  10
  11 # Member naming convention: hash-element names which begin with an
  12 # underscore represent underlying ZOOM-C object descriptors; those
  13 # which lack them represent Perl's ZOOM objects.  (The same convention
  14 # is used in naming local variables where appropriate.)
  15 #
  16 # So, for example, the ZOOM::Connection class has an {_conn} element,
  17 # which is a pointer to the ZOOM-C Connection object; but the
  18 # ZOOM::ResultSet class has a {conn} element, which is a reference to
  19 # the Perl-level Connection object by which it was created.  (It may
  20 # be that we find we have no need for these references, but for now
  21 # they are retained.)
  22 #
  23 # To get at the underlying ZOOM-C connection object of a result-set
  24 # (if you ever needed to do such a thing, which you probably don't)
  25 # you'd use $rs->{conn}->_conn().
  26
  27 # ----------------------------------------------------------------------------
  28
  29 # The "Error" package contains constants returned as error-codes.
  30 package ZOOM::Error;
  31 sub NONE { Net::Z3950::ZOOM::ERROR_NONE }
  32 sub CONNECT { Net::Z3950::ZOOM::ERROR_CONNECT }
  33 sub MEMORY { Net::Z3950::ZOOM::ERROR_MEMORY }
  34 sub ENCODE { Net::Z3950::ZOOM::ERROR_ENCODE }
  35 sub DECODE { Net::Z3950::ZOOM::ERROR_DECODE }
  36 sub CONNECTION_LOST { Net::Z3950::ZOOM::ERROR_CONNECTION_LOST }
  37 sub ZINIT { Net::Z3950::ZOOM::ERROR_INIT }
  38 sub INTERNAL { Net::Z3950::ZOOM::ERROR_INTERNAL }
  39 sub TIMEOUT { Net::Z3950::ZOOM::ERROR_TIMEOUT }
  40 sub UNSUPPORTED_PROTOCOL { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_PROTOCOL }
  41 sub UNSUPPORTED_QUERY { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_QUERY }
  42 sub INVALID_QUERY { Net::Z3950::ZOOM::ERROR_INVALID_QUERY }
  43 sub CQL_PARSE { Net::Z3950::ZOOM::ERROR_CQL_PARSE }
  44 sub CQL_TRANSFORM { Net::Z3950::ZOOM::ERROR_CQL_TRANSFORM }
  45 sub CCL_CONFIG { Net::Z3950::ZOOM::ERROR_CCL_CONFIG }
  46 sub CCL_PARSE { Net::Z3950::ZOOM::ERROR_CCL_PARSE }
  47 # The following are added specifically for this OO interface
  48 sub CREATE_QUERY { 20001 }
  49 sub QUERY_CQL { 20002 }
  50 sub QUERY_PQF { 20003 }
  51 sub SORTBY { 20004 }
  52 sub CLONE { 20005 }
  53 sub PACKAGE { 20006 }
  54 sub SCANTERM { 20007 }
  55 sub LOGLEVEL { 20008 }
  56
  57 # Separate space for CCL errors.  Great.
  58 package ZOOM::CCL::Error;
  59 sub OK { Net::Z3950::ZOOM::CCL_ERR_OK }
  60 sub TERM_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_TERM_EXPECTED }
  61 sub RP_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_RP_EXPECTED }
  62 sub SETNAME_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_SETNAME_EXPECTED }
  63 sub OP_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_OP_EXPECTED }
  64 sub BAD_RP { Net::Z3950::ZOOM::CCL_ERR_BAD_RP }
  65 sub UNKNOWN_QUAL { Net::Z3950::ZOOM::CCL_ERR_UNKNOWN_QUAL }
  66 sub DOUBLE_QUAL { Net::Z3950::ZOOM::CCL_ERR_DOUBLE_QUAL }
  67 sub EQ_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_EQ_EXPECTED }
  68 sub BAD_RELATION { Net::Z3950::ZOOM::CCL_ERR_BAD_RELATION }
  69 sub TRUNC_NOT_LEFT { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_LEFT }
  70 sub TRUNC_NOT_BOTH { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_BOTH }
  71 sub TRUNC_NOT_RIGHT { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_RIGHT }
  72
  73 # The "Event" package contains constants returned by last_event()
  74 package ZOOM::Event;
  75 sub NONE { Net::Z3950::ZOOM::EVENT_NONE }
  76 sub CONNECT { Net::Z3950::ZOOM::EVENT_CONNECT }
  77 sub SEND_DATA { Net::Z3950::ZOOM::EVENT_SEND_DATA }
  78 sub RECV_DATA { Net::Z3950::ZOOM::EVENT_RECV_DATA }
  79 sub TIMEOUT { Net::Z3950::ZOOM::EVENT_TIMEOUT }
  80 sub UNKNOWN { Net::Z3950::ZOOM::EVENT_UNKNOWN }
  81 sub SEND_APDU { Net::Z3950::ZOOM::EVENT_SEND_APDU }
  82 sub RECV_APDU { Net::Z3950::ZOOM::EVENT_RECV_APDU }
  83 sub RECV_RECORD { Net::Z3950::ZOOM::EVENT_RECV_RECORD }
  84 sub RECV_SEARCH { Net::Z3950::ZOOM::EVENT_RECV_SEARCH }
  85 sub ZEND { Net::Z3950::ZOOM::EVENT_END }
  86
  87 # ----------------------------------------------------------------------------
  88
  89 package ZOOM;
  90
  91 sub diag_str {
  92     my($code) = @_;
  93
  94     # Special cases for error specific to the OO layer
  95     if ($code == ZOOM::Error::CREATE_QUERY) {
  96         return "can't create query object";
  97     } elsif ($code == ZOOM::Error::QUERY_CQL) {
  98         return "can't set CQL query";
  99     } elsif ($code == ZOOM::Error::QUERY_PQF) {
 100         return "can't set prefix query";
 101     } elsif ($code == ZOOM::Error::SORTBY) {
 102         return "can't set sort-specification";
 103     } elsif ($code == ZOOM::Error::CLONE) {
 104         return "can't clone record";
 105     } elsif ($code == ZOOM::Error::PACKAGE) {
 106         return "can't create package";
 107     } elsif ($code == ZOOM::Error::SCANTERM) {
 108         return "can't retrieve term from scan-set";
 109     } elsif ($code == ZOOM::Error::LOGLEVEL) {
 110         return "unregistered log-level";
 111     }
 112
 113     return Net::Z3950::ZOOM::diag_str($code);
 114 }
 115
 116 sub event_str {
 117     return Net::Z3950::ZOOM::event_str(@_);
 118 }
 119
 120 sub event {
 121     my($connsref) = @_;
 122
 123     my @_connsref = map { $_->_conn() } @$connsref;
 124     return Net::Z3950::ZOOM::event(\@_connsref);
 125 }
 126
 127 sub _oops {
 128     my($code, $addinfo, $diagset) = @_;
 129
 130     die new ZOOM::Exception($code, undef, $addinfo, $diagset);
 131 }
 132
 133 # ----------------------------------------------------------------------------
 134
 135 package ZOOM::Exception;
 136
 137 sub new {
 138     my $class = shift();
 139     my($code, $message, $addinfo, $diagset) = @_;
 140
 141     $diagset ||= "ZOOM";
 142     if (uc($diagset) eq "ZOOM" || uc($diagset) eq "BIB-1") {
 143         $message ||= ZOOM::diag_str($code);
 144     } else {
 145         # Should fill in messages for other diagsets, too.
 146     }
 147
 148     return bless {
 149         code => $code,
 150         message => $message,
 151         addinfo => $addinfo,
 152         diagset => $diagset,
 153     }, $class;
 154 }
 155
 156 sub code {
 157     my $this = shift();
 158     return $this->{code};
 159 }
 160
 161 sub message {
 162     my $this = shift();
 163     return $this->{message};
 164 }
 165
 166 sub addinfo {
 167     my $this = shift();
 168     return $this->{addinfo};
 169 }
 170
 171 sub diagset {
 172     my $this = shift();
 173     return $this->{diagset};
 174 }
 175
 176 sub render {
 177     my $this = shift();
 178     my $res = "ZOOM error " . $this->code() . ' "' . $this->message() . '"';
 179     $res .= ' (addinfo: "' . $this->addinfo() . '")' if $this->addinfo();
 180     $res .= " from diag-set '" . $this->diagset() . "'" if $this->diagset();
 181     return $res;
 182 }
 183
 184 # This means that untrapped exceptions render nicely.
 185 use overload '""' => \&render;
 186
 187 # ----------------------------------------------------------------------------
 188
 189 package ZOOM::Options;
 190
 191 sub new {
 192     my $class = shift();
 193     my($p1, $p2) = @_;
 194
 195     my $opts;
 196     if (@_ == 0) {
 197         $opts = Net::Z3950::ZOOM::options_create();
 198     } elsif (@_ == 1) {
 199         $opts = Net::Z3950::ZOOM::options_create_with_parent($p1->_opts());
 200     } elsif (@_ == 2) {
 201         $opts = Net::Z3950::ZOOM::options_create_with_parent2($p1->_opts(),
 202                                                               $p2->_opts());
 203     } else {
 204         die "can't make $class object with more than 2 parents";
 205     }
 206
 207     return bless {
 208         _opts => $opts,
 209     }, $class;
 210 }
 211
 212 # PRIVATE to this class and ZOOM::Connection::create() and
 213 # ZOOM::Connection::package()
 214 #
 215 sub _opts {
 216     my $this = shift();
 217
 218     my $_opts = $this->{_opts};
 219     die "{_opts} undefined: has this Options block been destroy()ed?"
 220         if !defined $_opts;
 221
 222     return $_opts;
 223 }
 224
 225 sub option {
 226     my $this = shift();
 227     my($key, $value) = @_;
 228
 229     my $oldval = Net::Z3950::ZOOM::options_get($this->_opts(), $key);
 230     Net::Z3950::ZOOM::options_set($this->_opts(), $key, $value)
 231         if defined $value;
 232
 233     return $oldval;
 234 }
 235
 236 sub option_binary {
 237     my $this = shift();
 238     my($key, $value) = @_;
 239
 240     my $dummylen = 0;
 241     my $oldval = Net::Z3950::ZOOM::options_getl($this->_opts(),
 242                                                 $key, $dummylen);
 243     Net::Z3950::ZOOM::options_setl($this->_opts(), $key,
 244                                    $value, length($value))
 245         if defined $value;
 246
 247     return $oldval;
 248 }
 249
 250 # This is a bit stupid, since the scalar values that Perl returns from
 251 # option() can be used as a boolean; but it's just possible that some
 252 # applications will rely on ZOOM_options_get_bool()'s idiosyncratic
 253 # interpretation of what constitutes truth.
 254 #
 255 sub bool {
 256     my $this = shift();
 257     my($key, $default) = @_;
 258
 259     return Net::Z3950::ZOOM::options_get_bool($this->_opts(), $key, $default);
 260 }
 261
 262 # .. and the next two are even more stupid
 263 sub int {
 264     my $this = shift();
 265     my($key, $default) = @_;
 266
 267     return Net::Z3950::ZOOM::options_get_int($this->_opts(), $key, $default);
 268 }
 269
 270 sub set_int {
 271     my $this = shift();
 272     my($key, $value) = @_;
 273
 274     Net::Z3950::ZOOM::options_set_int($this->_opts(), $key, $value);
 275 }
 276
 277 #   ### Feel guilty.  Feel very, very guilty.  I've not been able to
 278 #       get the callback memory-management right in "ZOOM.xs", with
 279 #       the result that the values of $function and $udata passed into
 280 #       this function, which are on the stack, have sometimes been
 281 #       freed by the time they're used by __ZOOM_option_callback(),
 282 #       with hilarious results.  To avoid this, I copy the values into
 283 #       module-scoped globals, and pass _those_ into the extension
 284 #       function.  To avoid overwriting those globals by subsequent
 285 #       calls, I keep all the old ones, pushed onto the @_function and
 286 #       @_udata arrays, which means that THIS FUNCTION LEAKS MEMORY
 287 #       LIKE IT'S GOING OUT OF FASHION.  Not nice.  One day, I should
 288 #       fix this, but for now there's more important fish to fry.
 289 #
 290 my(@_function, @_udata);
 291 sub set_callback {
 292     my $o1 = shift();
 293     my($function, $udata) = @_;
 294
 295     push @_function, $function;
 296     push @_udata, $udata;
 297     Net::Z3950::ZOOM::options_set_callback($o1->_opts(),
 298                                            $_function[-1], $_udata[-1]);
 299 }
 300
 301 sub destroy {
 302     my $this = shift();
 303
 304     Net::Z3950::ZOOM::options_destroy($this->_opts());
 305     $this->{_opts} = undef;
 306 }
 307
 308
 309 # ----------------------------------------------------------------------------
 310
 311 package ZOOM::Connection;
 312
 313 sub new {
 314     my $class = shift();
 315     my($host, $port, @options) = @_;
 316
 317     my $conn = $class->create(@options);
 318     $conn->{host} = $host;
 319     $conn->{port} = $port;
 320
 321     Net::Z3950::ZOOM::connection_connect($conn->_conn(), $host, $port || 0);
 322     $conn->_check();
 323
 324     return $conn;
 325 }
 326
 327 # PRIVATE to this class, to ZOOM::event() and to ZOOM::Query::CQL2RPN::new()
 328 sub _conn {
 329     my $this = shift();
 330
 331     my $_conn = $this->{_conn};
 332     die "{_conn} undefined: has this Connection been destroy()ed?"
 333         if !defined $_conn;
 334
 335     return $_conn;
 336 }
 337
 338 sub _check {
 339     my $this = shift();
 340     my($always_die_on_error) = @_;
 341
 342     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "x", "x", "x");
 343     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 344                                                     $addinfo, $diagset);
 345     if ($errcode) {
 346         my $exception = new ZOOM::Exception($errcode, $errmsg, $addinfo,
 347                                             $diagset);
 348         if (!$this->option("async") || $always_die_on_error) {
 349             ZOOM::Log::log("zoom_check", "throwing error $exception");
 350             die $exception;
 351         } else {
 352             ZOOM::Log::log("zoom_check", "not reporting error $exception");
 353         }
 354     }
 355 }
 356
 357 # This wrapper for _check() is called only from outside the ZOOM
 358 # module, and therefore only in situations where an asynchronous
 359 # application is actively asking for an exception to be thrown if an
 360 # error has been detected.  So it passed always_die_on_error=1 to the
 361 # underlying _check() method.
 362 #
 363 sub check {
 364     my $this = shift();
 365     return $this->_check(1);
 366 }
 367
 368 sub create {
 369     my $class = shift();
 370     my(@options) = @_;
 371
 372     my $_opts;
 373     if (@_ == 1) {
 374         $_opts = $_[0]->_opts();
 375     } else {
 376         $_opts = Net::Z3950::ZOOM::options_create();
 377         while (@options >= 2) {
 378             my $key = shift(@options);
 379             my $val = shift(@options);
 380             Net::Z3950::ZOOM::options_set($_opts, $key, $val);
 381         }
 382
 383         die "Odd number of options specified"
 384             if @options;
 385     }
 386
 387     my $_conn = Net::Z3950::ZOOM::connection_create($_opts);
 388     my $conn = bless {
 389         host => undef,
 390         port => undef,
 391         _conn => $_conn,
 392     }, $class;
 393     return $conn;
 394 }
 395
 396 sub error_x {
 397     my $this = shift();
 398
 399     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 400     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 401                                                     $addinfo, $diagset);
 402     return wantarray() ? ($errcode, $errmsg, $addinfo, $diagset) : $errcode;
 403 }
 404
 405 sub exception {
 406     my $this = shift();
 407
 408     my($errcode, $errmsg, $addinfo, $diagset) = $this->error_x();
 409     return undef if $errcode == 0;
 410     return new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset);
 411 }
 412
 413 sub errcode {
 414     my $this = shift();
 415     return Net::Z3950::ZOOM::connection_errcode($this->_conn());
 416 }
 417
 418 sub errmsg {
 419     my $this = shift();
 420     return Net::Z3950::ZOOM::connection_errmsg($this->_conn());
 421 }
 422
 423 sub addinfo {
 424     my $this = shift();
 425     return Net::Z3950::ZOOM::connection_addinfo($this->_conn());
 426 }
 427
 428 sub diagset {
 429     my $this = shift();
 430     return Net::Z3950::ZOOM::connection_diagset($this->_conn());
 431 }
 432
 433 sub connect {
 434     my $this = shift();
 435     my($host, $port) = @_;
 436
 437     $port = 0 if !defined $port;
 438     Net::Z3950::ZOOM::connection_connect($this->_conn(), $host, $port);
 439     $this->_check();
 440     # No return value
 441 }
 442
 443 sub option {
 444     my $this = shift();
 445     my($key, $value) = @_;
 446
 447     my $oldval = Net::Z3950::ZOOM::connection_option_get($this->_conn(), $key);
 448     Net::Z3950::ZOOM::connection_option_set($this->_conn(), $key, $value)
 449         if defined $value;
 450
 451     return $oldval;
 452 }
 453
 454 sub option_binary {
 455     my $this = shift();
 456     my($key, $value) = @_;
 457
 458     my $dummylen = 0;
 459     my $oldval = Net::Z3950::ZOOM::connection_option_getl($this->_conn(),
 460                                                           $key, $dummylen);
 461     Net::Z3950::ZOOM::connection_option_setl($this->_conn(), $key,
 462                                              $value, length($value))
 463         if defined $value;
 464
 465     return $oldval;
 466 }
 467
 468 sub search {
 469     my $this = shift();
 470     my($query) = @_;
 471
 472     my $_rs = Net::Z3950::ZOOM::connection_search($this->_conn(),
 473                                                   $query->_query());
 474     $this->_check();
 475     return _new ZOOM::ResultSet($this, $query, $_rs);
 476 }
 477
 478 sub search_pqf {
 479     my $this = shift();
 480     my($pqf) = @_;
 481
 482     my $_rs = Net::Z3950::ZOOM::connection_search_pqf($this->_conn(), $pqf);
 483     $this->_check();
 484     return _new ZOOM::ResultSet($this, $pqf, $_rs);
 485 }
 486
 487 sub scan_pqf {
 488     my $this = shift();
 489     my($startterm) = @_;
 490
 491     my $_ss = Net::Z3950::ZOOM::connection_scan($this->_conn(), $startterm);
 492     $this->_check();
 493     return _new ZOOM::ScanSet($this, $startterm, $_ss);
 494 }
 495
 496 sub scan {
 497     my $this = shift();
 498     my($query) = @_;
 499
 500     my $_ss = Net::Z3950::ZOOM::connection_scan1($this->_conn(),
 501                                                  $query->_query());
 502     $this->_check();
 503     return _new ZOOM::ScanSet($this, $query, $_ss);
 504 }
 505
 506 sub package {
 507     my $this = shift();
 508     my($options) = @_;
 509
 510     my $_o = defined $options ? $options->_opts() :
 511         Net::Z3950::ZOOM::options_create();
 512     my $_p = Net::Z3950::ZOOM::connection_package($this->_conn(), $_o)
 513         or ZOOM::_oops(ZOOM::Error::PACKAGE);
 514
 515     return _new ZOOM::Package($this, $options, $_p);
 516 }
 517
 518 sub last_event {
 519     my $this = shift();
 520
 521     return Net::Z3950::ZOOM::connection_last_event($this->_conn());
 522 }
 523
 524 sub is_idle {
 525     my $this = shift();
 526
 527     return Net::Z3950::ZOOM::connection_is_idle($this->_conn());
 528 }
 529
 530 sub peek_event {
 531     my $this = shift();
 532
 533     return Net::Z3950::ZOOM::connection_peek_event($this->_conn());
 534 }
 535
 536 sub destroy {
 537     my $this = shift();
 538
 539     Net::Z3950::ZOOM::connection_destroy($this->_conn());
 540     $this->{_conn} = undef;
 541 }
 542
 543
 544 # ----------------------------------------------------------------------------
 545
 546 package ZOOM::Query;
 547
 548 sub new {
 549     my $class = shift();
 550     die "You can't create $class objects: it's a virtual base class";
 551 }
 552
 553 # PRIVATE to this class and ZOOM::Connection::search()
 554 sub _query {
 555     my $this = shift();
 556
 557     my $_query = $this->{_query};
 558     die "{_query} undefined: has this Query been destroy()ed?"
 559         if !defined $_query;
 560
 561     return $_query;
 562 }
 563
 564 sub sortby {
 565     my $this = shift();
 566     my($sortby) = @_;
 567
 568     Net::Z3950::ZOOM::query_sortby($this->_query(), $sortby) == 0
 569         or ZOOM::_oops(ZOOM::Error::SORTBY, $sortby);
 570 }
 571
 572 sub destroy {
 573     my $this = shift();
 574
 575     Net::Z3950::ZOOM::query_destroy($this->_query());
 576     $this->{_query} = undef;
 577 }
 578
 579
 580 package ZOOM::Query::CQL;
 581 our @ISA = qw(ZOOM::Query);
 582
 583 sub new {
 584     my $class = shift();
 585     my($string) = @_;
 586
 587     my $q = Net::Z3950::ZOOM::query_create()
 588         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 589     Net::Z3950::ZOOM::query_cql($q, $string) == 0
 590         or ZOOM::_oops(ZOOM::Error::QUERY_CQL, $string);
 591
 592     return bless {
 593         _query => $q,
 594     }, $class;
 595 }
 596
 597
 598 package ZOOM::Query::CQL2RPN;
 599 our @ISA = qw(ZOOM::Query);
 600
 601 sub new {
 602     my $class = shift();
 603     my($string, $conn) = @_;
 604
 605     my $q = Net::Z3950::ZOOM::query_create()
 606         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 607     # check() throws the exception we want; but we only want it on failure!
 608     Net::Z3950::ZOOM::query_cql2rpn($q, $string, $conn->_conn()) == 0
 609         or $conn->_check();
 610
 611     return bless {
 612         _query => $q,
 613     }, $class;
 614 }
 615
 616
 617 # We have to work around the retarded ZOOM_query_ccl2rpn() API
 618 package ZOOM::Query::CCL2RPN;
 619 our @ISA = qw(ZOOM::Query);
 620
 621 sub new {
 622     my $class = shift();
 623     my($string, $conn) = @_;
 624
 625     my $q = Net::Z3950::ZOOM::query_create()
 626         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 627
 628     my $config = $conn->option("cclqual");
 629     if (!defined $config) {
 630         my $cclfile = $conn->option("cclfile")
 631             or ZOOM::_oops(ZOOM::Error::CCL_CONFIG,
 632                            "no 'cclqual' or 'cclfile' specified");
 633         my $fh = new IO::File("<$cclfile")
 634             or ZOOM::_oops(ZOOM::Error::CCL_CONFIG,
 635                            "can't open cclfile '$cclfile': $!");
 636         $config = join("", <$fh>);
 637         $fh->close();
 638     }
 639
 640     my($ccl_errcode, $ccl_errstr, $ccl_errpos) = (0, "", 0);
 641     if (Net::Z3950::ZOOM::query_ccl2rpn($q, $string, $config,
 642                                         $ccl_errcode, $ccl_errstr,
 643                                         $ccl_errpos) < 0) {
 644         # We have no use for $ccl_errcode or $ccl_errpos
 645         ZOOM::_oops(ZOOM::Error::CCL_PARSE, $ccl_errstr);
 646     }
 647
 648     return bless {
 649         _query => $q,
 650     }, $class;
 651 }
 652
 653
 654 package ZOOM::Query::PQF;
 655 our @ISA = qw(ZOOM::Query);
 656
 657 sub new {
 658     my $class = shift();
 659     my($string) = @_;
 660
 661     my $q = Net::Z3950::ZOOM::query_create()
 662         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 663     Net::Z3950::ZOOM::query_prefix($q, $string) == 0
 664         or ZOOM::_oops(ZOOM::Error::QUERY_PQF, $string);
 665
 666     return bless {
 667         _query => $q,
 668     }, $class;
 669 }
 670
 671
 672 # ----------------------------------------------------------------------------
 673
 674 package ZOOM::ResultSet;
 675
 676 sub new {
 677     my $class = shift();
 678     die "You can't create $class objects directly";
 679 }
 680
 681 # PRIVATE to ZOOM::Connection::search() and ZOOM::Connection::search_pqf()
 682 sub _new {
 683     my $class = shift();
 684     my($conn, $query, $_rs) = @_;
 685
 686     return bless {
 687         conn => $conn,
 688         query => $query,        # This is not currently used, which is
 689                                 # just as well since it could be
 690                                 # either a string (when the RS is
 691                                 # created with search_pqf()) or a
 692                                 # ZOOM::Query object (when it's
 693                                 # created with search())
 694         _rs => $_rs,
 695     }, $class;
 696 }
 697
 698 # PRIVATE to this class
 699 sub _rs {
 700     my $this = shift();
 701
 702     my $_rs = $this->{_rs};
 703     die "{_rs} undefined: has this ResultSet been destroy()ed?"
 704         if !defined $_rs;
 705
 706     return $_rs;
 707 }
 708
 709 sub option {
 710     my $this = shift();
 711     my($key, $value) = @_;
 712
 713     my $oldval = Net::Z3950::ZOOM::resultset_option_get($this->_rs(), $key);
 714     Net::Z3950::ZOOM::resultset_option_set($this->_rs(), $key, $value)
 715         if defined $value;
 716
 717     return $oldval;
 718 }
 719
 720 sub size {
 721     my $this = shift();
 722
 723     return Net::Z3950::ZOOM::resultset_size($this->_rs());
 724 }
 725
 726 sub record {
 727     my $this = shift();
 728     my($which) = @_;
 729
 730     my $_rec = Net::Z3950::ZOOM::resultset_record($this->_rs(), $which);
 731     $this->{conn}->_check();
 732
 733     # Even if no error has occurred, I think record() might
 734     # legitimately return undef if we're running in asynchronous mode
 735     # and the record just hasn't been retrieved yet.  This goes double
 736     # for record_immediate().
 737     return undef if !defined $_rec;
 738
 739     # For some reason, I have to use the explicit "->" syntax in order
 740     # to invoke the ZOOM::Record constructor here, even though I don't
 741     # have to do the same for _new ZOOM::ResultSet above.  Weird.
 742     return ZOOM::Record->_new($this, $which, $_rec);
 743 }
 744
 745 sub record_immediate {
 746     my $this = shift();
 747     my($which) = @_;
 748
 749     my $_rec = Net::Z3950::ZOOM::resultset_record_immediate($this->_rs(),
 750                                                             $which);
 751     $this->{conn}->_check();
 752     # The record might legitimately not be there yet
 753     return undef if !defined $_rec;
 754
 755     return ZOOM::Record->_new($this, $which, $_rec);
 756 }
 757
 758 sub cache_reset {
 759     my $this = shift();
 760
 761     Net::Z3950::ZOOM::resultset_cache_reset($this->_rs());
 762 }
 763
 764 sub records {
 765     my $this = shift();
 766     my($start, $count, $return_records) = @_;
 767
 768     # If the request is out of range, ZOOM-C will currently (as of YAZ
 769     # 2.1.38) no-op: it understandably refuses to build and send a
 770     # known-bad APDU, but it doesn't set a diagnostic as it ought.  So
 771     # for now, we do it here.  It would be more polite to stash the
 772     # error-code in the ZOOM-C connection object for subsequent
 773     # discovery (which is what ZOOM-C will presumably do itself when
 774     # it's fixed) but since there is no API that allows us to do that,
 775     # we just have to throw the exception right now.  That's probably
 776     # OK for synchronous applications, but not really for
 777     # multiplexers.
 778     my $size = $this->size();
 779     if ($start + $count-1 >= $size) {
 780         # BIB-1 diagnostic 13 is "Present request out-of-range"
 781         ZOOM::_oops(13, undef, "BIB-1");
 782     }
 783
 784     my $raw = Net::Z3950::ZOOM::resultset_records($this->_rs(), $start, $count,
 785                                                   $return_records);
 786     # By design, $raw may be undefined (if $return_records is true)
 787     return undef if !defined $raw;
 788
 789     # We need to package up the returned records in ZOOM::Record objects
 790     my @res = ();
 791     for my $i (0 .. @$raw-1) {
 792         my $_rec = $raw->[$i];
 793         if (!defined $_rec) {
 794             push @res, undef;
 795         } else {
 796             push @res, ZOOM::Record->_new($this, $start+$i, $_rec);
 797         }
 798     }
 799
 800     return \@res;
 801 }
 802
 803 sub sort {
 804     my $this = shift();
 805     my($sort_type, $sort_spec) = @_;
 806
 807     return Net::Z3950::ZOOM::resultset_sort1($this->_rs(),
 808                                              $sort_type, $sort_spec);
 809 }
 810
 811 sub destroy {
 812     my $this = shift();
 813
 814     Net::Z3950::ZOOM::resultset_destroy($this->_rs());
 815     $this->{_rs} = undef;
 816 }
 817
 818
 819 # ----------------------------------------------------------------------------
 820
 821 package ZOOM::Record;
 822
 823 sub new {
 824     my $class = shift();
 825     die "You can't create $class objects directly";
 826 }
 827
 828 # PRIVATE to ZOOM::ResultSet::record(),
 829 # ZOOM::ResultSet::record_immediate(), ZOOM::ResultSet::records() and
 830 # ZOOM::Record::clone()
 831 #
 832 sub _new {
 833     my $class = shift();
 834     my($rs, $which, $_rec) = @_;
 835
 836     return bless {
 837         rs => $rs,
 838         which => $which,
 839         _rec => $_rec,
 840     }, $class;
 841 }
 842
 843 # PRIVATE to this class
 844 sub _rec {
 845     my $this = shift();
 846
 847     my $_rec = $this->{_rec};
 848     die "{_rec} undefined: has this Record been destroy()ed?"
 849         if !defined $_rec;
 850
 851     return $_rec;
 852 }
 853
 854 sub error {
 855     my $this = shift();
 856
 857     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 858     $errcode = Net::Z3950::ZOOM::record_error($this->_rec(), $errmsg,
 859                                               $addinfo, $diagset);
 860
 861     return wantarray() ? ($errcode, $errmsg, $addinfo, $diagset) : $errcode;
 862 }
 863
 864 sub exception {
 865     my $this = shift();
 866
 867     my($errcode, $errmsg, $addinfo, $diagset) = $this->error();
 868     return undef if $errcode == 0;
 869     return new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset);
 870 }
 871
 872
 873 sub render {
 874     my $this = shift();
 875
 876     return $this->get("render", @_);
 877 }
 878
 879 sub raw {
 880     my $this = shift();
 881
 882     return $this->get("raw", @_);
 883 }
 884
 885 sub get {
 886     my $this = shift();
 887     my($type, $args) = @_;
 888
 889     $type = "$type;$args" if defined $args;
 890     my $len = 0;
 891     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), $type, $len);
 892     # I don't think we need '$len' at all.  ### Probably the Perl-to-C
 893     # glue code should use the value of `len' as well as the opaque
 894     # data-pointer returned, to ensure that the SV contains all of the
 895     # returned data and does not stop at the first NUL character in
 896     # binary data.  Carefully check the ZOOM_record_get() documentation.
 897     return $string;
 898 }
 899
 900 sub clone {
 901     my $this = shift();
 902
 903     my $raw = Net::Z3950::ZOOM::record_clone($this->_rec())
 904         or ZOOM::_oops(ZOOM::Error::CLONE);
 905
 906     # Arg 1 (rs) is undefined as the new record doesn't belong to an RS
 907     return _new ZOOM::Record(undef, undef, $raw);
 908 }
 909
 910 sub destroy {
 911     my $this = shift();
 912
 913     Net::Z3950::ZOOM::record_destroy($this->_rec());
 914     $this->{_rec} = undef;
 915 }
 916
 917
 918 # ----------------------------------------------------------------------------
 919
 920 package ZOOM::ScanSet;
 921
 922 sub new {
 923     my $class = shift();
 924     die "You can't create $class objects directly";
 925 }
 926
 927 # PRIVATE to ZOOM::Connection::scan(),
 928 sub _new {
 929     my $class = shift();
 930     my($conn, $startterm, $_ss) = @_;
 931
 932     return bless {
 933         conn => $conn,
 934         startterm => $startterm,# This is not currently used, which is
 935                                 # just as well since it could be
 936                                 # either a string (when the SS is
 937                                 # created with scan()) or a
 938                                 # ZOOM::Query object (when it's
 939                                 # created with scan1())
 940         _ss => $_ss,
 941     }, $class;
 942 }
 943
 944 # PRIVATE to this class
 945 sub _ss {
 946     my $this = shift();
 947
 948     my $_ss = $this->{_ss};
 949     die "{_ss} undefined: has this ScanSet been destroy()ed?"
 950         if !defined $_ss;
 951
 952     return $_ss;
 953 }
 954
 955 sub option {
 956     my $this = shift();
 957     my($key, $value) = @_;
 958
 959     my $oldval = Net::Z3950::ZOOM::scanset_option_get($this->_ss(), $key);
 960     Net::Z3950::ZOOM::scanset_option_set($this->_ss(), $key, $value)
 961         if defined $value;
 962
 963     return $oldval;
 964 }
 965
 966 sub size {
 967     my $this = shift();
 968
 969     return Net::Z3950::ZOOM::scanset_size($this->_ss());
 970 }
 971
 972 sub term {
 973     my $this = shift();
 974     my($which) = @_;
 975
 976     my($occ, $len) = (0, 0);
 977     my $term = Net::Z3950::ZOOM::scanset_term($this->_ss(), $which,
 978                                               $occ, $len)
 979         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 980
 981     die "length of term '$term' differs from returned len=$len"
 982         if length($term) != $len;
 983
 984     return ($term, $occ);
 985 }
 986
 987 sub display_term {
 988     my $this = shift();
 989     my($which) = @_;
 990
 991     my($occ, $len) = (0, 0);
 992     my $term = Net::Z3950::ZOOM::scanset_display_term($this->_ss(), $which,
 993                                                       $occ, $len)
 994         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 995
 996     die "length of display term '$term' differs from returned len=$len"
 997         if length($term) != $len;
 998
 999     return ($term, $occ);
1000 }
1001
1002 sub destroy {
1003     my $this = shift();
1004
1005     Net::Z3950::ZOOM::scanset_destroy($this->_ss());
1006     $this->{_ss} = undef;
1007 }
1008
1009
1010 # ----------------------------------------------------------------------------
1011
1012 package ZOOM::Package;
1013
1014 sub new {
1015     my $class = shift();
1016     die "You can't create $class objects directly";
1017 }
1018
1019 # PRIVATE to ZOOM::Connection::package(),
1020 sub _new {
1021     my $class = shift();
1022     my($conn, $options, $_p) = @_;
1023
1024     return bless {
1025         conn => $conn,
1026         options => $options,
1027         _p => $_p,
1028     }, $class;
1029 }
1030
1031 # PRIVATE to this class
1032 sub _p {
1033     my $this = shift();
1034
1035     my $_p = $this->{_p};
1036     die "{_p} undefined: has this Package been destroy()ed?"
1037         if !defined $_p;
1038
1039     return $_p;
1040 }
1041
1042 sub option {
1043     my $this = shift();
1044     my($key, $value) = @_;
1045
1046     my $oldval = Net::Z3950::ZOOM::package_option_get($this->_p(), $key);
1047     Net::Z3950::ZOOM::package_option_set($this->_p(), $key, $value)
1048         if defined $value;
1049
1050     return $oldval;
1051 }
1052
1053 sub send {
1054     my $this = shift();
1055     my($type) = @_;
1056
1057     Net::Z3950::ZOOM::package_send($this->_p(), $type);
1058     $this->{conn}->_check();
1059 }
1060
1061 sub destroy {
1062     my $this = shift();
1063
1064     Net::Z3950::ZOOM::package_destroy($this->_p());
1065     $this->{_p} = undef;
1066 }
1067
1068
1069 # There follows trivial support for YAZ logging.  This is wired out
1070 # into the Net::Z3950::ZOOM package, and we here provide wrapper
1071 # functions -- nothing more than aliases, really -- in the ZOOM::Log
1072 # package.  There really is no point in inventing an OO interface.
1073 #
1074 # Passing @_ directly to the underlying Net::Z3950::ZOOM::* functions
1075 # doesn't work, for reasons that I can't begin to fathom, and that
1076 # don't particularly interest me.  Unpacking into scalars and passing
1077 # those _does_ work, so that's what we do.
1078
1079 package ZOOM::Log;
1080
1081 sub mask_str      { my($a) = @_; Net::Z3950::ZOOM::yaz_log_mask_str($a); }
1082 sub module_level  { my($a) = @_; Net::Z3950::ZOOM::yaz_log_module_level($a); }
1083 sub init          { my($a, $b, $c) = @_;
1084                     Net::Z3950::ZOOM::yaz_log_init($a, $b, $c) }
1085 sub init_file     { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_file($a) }
1086 sub init_level    { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_level($a) }
1087 sub init_prefix   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_prefix($a) }
1088 sub time_format   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_time_format($a) }
1089 sub init_max_size { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_max_size($a) }
1090
1091 sub log {
1092     my($level, @message) = @_;
1093
1094     if ($level !~ /^(0x)?\d+$/) {
1095         # Assuming its log-level name, we look it up.
1096         my $num = module_level($level);
1097         ZOOM::_oops(ZOOM::Error::LOGLEVEL, $level)
1098             if $num == 0;
1099         $level = $num;
1100     }
1101
1102     Net::Z3950::ZOOM::yaz_log($level, join("", @message));
1103 }
1104
1105 BEGIN { ZOOM::Log::mask_str("zoom_check"); }
1106
1107 1;