src/oidtoc.tcl

   1 # This file is part of the YAZ toolkit
   2 # Copyright (c) Index Data 2006-2007
   3 # See the file LICENSE for details.
   4 #
   5 # $Id: oidtoc.tcl,v 1.2 2007-04-18 08:08:02 adam Exp $
   6 #
   7 # Converts a CSV file with Object identifiers to C
   8
   9 proc readoids {input} {
  10     set csv [open $input r]
  11     set lineno 0
  12
  13     while {1} {
  14         incr lineno
  15         set cnt [gets $csv line]
  16         if {$cnt < 0} {
  17             break
  18         }
  19         if {![string compare [string index $line 0] \"]} {
  20             continue
  21         }
  22         set tokens [string map {, { }} $line]
  23         if {[llength $tokens] != 3} {
  24             puts "$input:$lineno: Bad line '$line'"
  25             exit 1
  26         }
  27         lappend oids $tokens
  28     }
  29     close $csv
  30     if {![info exists oids]} {
  31         puts "$input:0 No OIDS"
  32         exit 1
  33     }
  34     return $oids
  35 }
  36
  37 proc oid_to_c {srcdir input cname hname} {
  38     set oids [readoids "${srcdir}/${input}"]
  39
  40     set cfile [open "${srcdir}/${cname}" w]
  41     set hfile [open "${srcdir}/../include/yaz/${hname}" w]
  42
  43     puts $cfile "/** \\file $cname"
  44     puts $hfile "/** \\file $hname"
  45     set preamble "    \\brief Standard Object Identifiers: Generated from $input */"
  46     puts $cfile $preamble
  47     puts $hfile $preamble
  48
  49
  50     puts $cfile "\#include <yaz/oid_db.h>"
  51     puts $cfile ""
  52     foreach oid $oids {
  53         set lname [string tolower [lindex $oid 2]]
  54         set lname [string map {- _ . _ { } _ ( {} ) {}} $lname]
  55         set prefix [string tolower [lindex $oid 0]]
  56
  57         puts -nonewline $cfile "const int yaz_oid_${prefix}_${lname}\[\] = \{"
  58         puts -nonewline $cfile [string map {. ,} [lindex $oid 1]]
  59         puts $cfile ",-1\};"
  60
  61         puts $hfile "extern const int yaz_oid_${prefix}_${lname}\[\];"
  62     }
  63
  64     puts $cfile "struct yaz_oid_entry yaz_oid_standard_entries\[\] ="
  65     puts $cfile "\{"
  66     foreach oid $oids {
  67         set lname [string tolower [lindex $oid 2]]
  68         set lname [string map {- _ . _ { } _ ( {} ) {}} $lname]
  69         set prefix [string tolower [lindex $oid 0]]
  70
  71         puts -nonewline $cfile "\t\{CLASS_[lindex $oid 0], "
  72         puts -nonewline $cfile "yaz_oid_${prefix}_${lname}, "
  73         puts -nonewline $cfile \"[lindex $oid 2]\"
  74         puts $cfile "\},"
  75     }
  76
  77     puts $cfile "\t\{CLASS_NOP, 0, 0\}"
  78     puts $cfile "\};"
  79
  80     puts $hfile "extern struct yaz_oid_entry yaz_oid_standard_entries\[\];"
  81     close $cfile
  82     close $hfile
  83 }
  84
  85 if {[llength $argv] != 4} {
  86     puts "oidtoc.tcl srcdir csv cfile hfile"
  87     exit 1
  88 }
  89 oid_to_c [lindex $argv 0] [lindex $argv 1] [lindex $argv 2] [lindex $argv 3]