lib/ZOOM.pm

   1 # $Id: ZOOM.pm,v 1.36 2006-10-04 17:15:03 mike Exp $
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::Z3950::ZOOM;
   7
   8
   9 package ZOOM;
  10
  11 # Member naming convention: hash-element names which begin with an
  12 # underscore represent underlying ZOOM-C object descriptors; those
  13 # which lack them represent Perl's ZOOM objects.  (The same convention
  14 # is used in naming local variables where appropriate.)
  15 #
  16 # So, for example, the ZOOM::Connection class has an {_conn} element,
  17 # which is a pointer to the ZOOM-C Connection object; but the
  18 # ZOOM::ResultSet class has a {conn} element, which is a reference to
  19 # the Perl-level Connection object by which it was created.  (It may
  20 # be that we find we have no need for these references, but for now
  21 # they are retained.)
  22 #
  23 # To get at the underlying ZOOM-C connection object of a result-set
  24 # (if you ever needed to do such a thing, which you probably don't)
  25 # you'd use $rs->{conn}->_conn().
  26
  27 # ----------------------------------------------------------------------------
  28
  29 # The "Error" package contains constants returned as error-codes.
  30 package ZOOM::Error;
  31 sub NONE { Net::Z3950::ZOOM::ERROR_NONE }
  32 sub CONNECT { Net::Z3950::ZOOM::ERROR_CONNECT }
  33 sub MEMORY { Net::Z3950::ZOOM::ERROR_MEMORY }
  34 sub ENCODE { Net::Z3950::ZOOM::ERROR_ENCODE }
  35 sub DECODE { Net::Z3950::ZOOM::ERROR_DECODE }
  36 sub CONNECTION_LOST { Net::Z3950::ZOOM::ERROR_CONNECTION_LOST }
  37 sub INIT { Net::Z3950::ZOOM::ERROR_INIT }
  38 sub INTERNAL { Net::Z3950::ZOOM::ERROR_INTERNAL }
  39 sub TIMEOUT { Net::Z3950::ZOOM::ERROR_TIMEOUT }
  40 sub UNSUPPORTED_PROTOCOL { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_PROTOCOL }
  41 sub UNSUPPORTED_QUERY { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_QUERY }
  42 sub INVALID_QUERY { Net::Z3950::ZOOM::ERROR_INVALID_QUERY }
  43 sub CQL_PARSE { Net::Z3950::ZOOM::ERROR_CQL_PARSE }
  44 sub CQL_TRANSFORM { Net::Z3950::ZOOM::ERROR_CQL_TRANSFORM }
  45 sub CCL_CONFIG { Net::Z3950::ZOOM::ERROR_CCL_CONFIG }
  46 sub CCL_PARSE { Net::Z3950::ZOOM::ERROR_CCL_PARSE }
  47 # The following are added specifically for this OO interface
  48 sub CREATE_QUERY { 20001 }
  49 sub QUERY_CQL { 20002 }
  50 sub QUERY_PQF { 20003 }
  51 sub SORTBY { 20004 }
  52 sub CLONE { 20005 }
  53 sub PACKAGE { 20006 }
  54 sub SCANTERM { 20007 }
  55 sub LOGLEVEL { 20008 }
  56
  57 # Separate space for CCL errors.  Great.
  58 package ZOOM::CCL::Error;
  59 sub OK { Net::Z3950::ZOOM::CCL_ERR_OK }
  60 sub TERM_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_TERM_EXPECTED }
  61 sub RP_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_RP_EXPECTED }
  62 sub SETNAME_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_SETNAME_EXPECTED }
  63 sub OP_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_OP_EXPECTED }
  64 sub BAD_RP { Net::Z3950::ZOOM::CCL_ERR_BAD_RP }
  65 sub UNKNOWN_QUAL { Net::Z3950::ZOOM::CCL_ERR_UNKNOWN_QUAL }
  66 sub DOUBLE_QUAL { Net::Z3950::ZOOM::CCL_ERR_DOUBLE_QUAL }
  67 sub EQ_EXPECTED { Net::Z3950::ZOOM::CCL_ERR_EQ_EXPECTED }
  68 sub BAD_RELATION { Net::Z3950::ZOOM::CCL_ERR_BAD_RELATION }
  69 sub TRUNC_NOT_LEFT { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_LEFT }
  70 sub TRUNC_NOT_BOTH { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_BOTH }
  71 sub TRUNC_NOT_RIGHT { Net::Z3950::ZOOM::CCL_ERR_TRUNC_NOT_RIGHT }
  72
  73 # The "Event" package contains constants returned by last_event()
  74 package ZOOM::Event;
  75 sub NONE { Net::Z3950::ZOOM::EVENT_NONE }
  76 sub CONNECT { Net::Z3950::ZOOM::EVENT_CONNECT }
  77 sub SEND_DATA { Net::Z3950::ZOOM::EVENT_SEND_DATA }
  78 sub RECV_DATA { Net::Z3950::ZOOM::EVENT_RECV_DATA }
  79 sub TIMEOUT { Net::Z3950::ZOOM::EVENT_TIMEOUT }
  80 sub UNKNOWN { Net::Z3950::ZOOM::EVENT_UNKNOWN }
  81 sub SEND_APDU { Net::Z3950::ZOOM::EVENT_SEND_APDU }
  82 sub RECV_APDU { Net::Z3950::ZOOM::EVENT_RECV_APDU }
  83 sub RECV_RECORD { Net::Z3950::ZOOM::EVENT_RECV_RECORD }
  84 sub RECV_SEARCH { Net::Z3950::ZOOM::EVENT_RECV_SEARCH }
  85 sub ZEND { Net::Z3950::ZOOM::EVENT_END }
  86
  87 # ----------------------------------------------------------------------------
  88
  89 package ZOOM;
  90
  91 sub diag_str {
  92     my($code) = @_;
  93
  94     # Special cases for error specific to the OO layer
  95     if ($code == ZOOM::Error::CREATE_QUERY) {
  96         return "can't create query object";
  97     } elsif ($code == ZOOM::Error::QUERY_CQL) {
  98         return "can't set CQL query";
  99     } elsif ($code == ZOOM::Error::QUERY_PQF) {
 100         return "can't set prefix query";
 101     } elsif ($code == ZOOM::Error::SORTBY) {
 102         return "can't set sort-specification";
 103     } elsif ($code == ZOOM::Error::CLONE) {
 104         return "can't clone record";
 105     } elsif ($code == ZOOM::Error::PACKAGE) {
 106         return "can't create package";
 107     } elsif ($code == ZOOM::Error::SCANTERM) {
 108         return "can't retrieve term from scan-set";
 109     } elsif ($code == ZOOM::Error::LOGLEVEL) {
 110         return "unregistered log-level";
 111     }
 112
 113     return Net::Z3950::ZOOM::diag_str($code);
 114 }
 115
 116 sub event_str {
 117     return Net::Z3950::ZOOM::event_str(@_);
 118 }
 119
 120 sub event {
 121     my($connsref) = @_;
 122
 123     my @_connsref = map { $_->_conn() } @$connsref;
 124     return Net::Z3950::ZOOM::event(\@_connsref);
 125 }
 126
 127 sub _oops {
 128     my($code, $addinfo, $diagset) = @_;
 129
 130     die new ZOOM::Exception($code, undef, $addinfo, $diagset);
 131 }
 132
 133 # ----------------------------------------------------------------------------
 134
 135 package ZOOM::Exception;
 136
 137 sub new {
 138     my $class = shift();
 139     my($code, $message, $addinfo, $diagset) = @_;
 140
 141     $diagset ||= "ZOOM";
 142     if ($diagset eq "ZOOM") {
 143         $message ||= ZOOM::diag_str($code);
 144     } else {
 145         # Should fill in messages for other diagsets, too.
 146     }
 147
 148     return bless {
 149         code => $code,
 150         message => $message,
 151         addinfo => $addinfo,
 152         diagset => $diagset,
 153     }, $class;
 154 }
 155
 156 sub code {
 157     my $this = shift();
 158     return $this->{code};
 159 }
 160
 161 sub message {
 162     my $this = shift();
 163     return $this->{message};
 164 }
 165
 166 sub addinfo {
 167     my $this = shift();
 168     return $this->{addinfo};
 169 }
 170
 171 sub diagset {
 172     my $this = shift();
 173     return $this->{diagset};
 174 }
 175
 176 sub render {
 177     my $this = shift();
 178     my $res = "ZOOM error " . $this->code() . ' "' . $this->message() . '"';
 179     $res .= ' (addinfo: "' . $this->addinfo() . '")' if $this->addinfo();
 180     $res .= " from diag-set '" . $this->diagset() . "'" if $this->diagset();
 181     return $res;
 182 }
 183
 184 # This means that untrapped exceptions render nicely.
 185 use overload '""' => \&render;
 186
 187 # ----------------------------------------------------------------------------
 188
 189 package ZOOM::Options;
 190
 191 sub new {
 192     my $class = shift();
 193     my($p1, $p2) = @_;
 194
 195     my $opts;
 196     if (@_ == 0) {
 197         $opts = Net::Z3950::ZOOM::options_create();
 198     } elsif (@_ == 1) {
 199         $opts = Net::Z3950::ZOOM::options_create_with_parent($p1->_opts());
 200     } elsif (@_ == 2) {
 201         $opts = Net::Z3950::ZOOM::options_create_with_parent2($p1->_opts(),
 202                                                               $p2->_opts());
 203     } else {
 204         die "can't make $class object with more than 2 parents";
 205     }
 206
 207     return bless {
 208         _opts => $opts,
 209     }, $class;
 210 }
 211
 212 # PRIVATE to this class and ZOOM::Connection::create() and
 213 # ZOOM::Connection::package()
 214 #
 215 sub _opts {
 216     my $this = shift();
 217
 218     my $_opts = $this->{_opts};
 219     die "{_opts} undefined: has this Options block been destroy()ed?"
 220         if !defined $_opts;
 221
 222     return $_opts;
 223 }
 224
 225 sub option {
 226     my $this = shift();
 227     my($key, $value) = @_;
 228
 229     my $oldval = Net::Z3950::ZOOM::options_get($this->_opts(), $key);
 230     Net::Z3950::ZOOM::options_set($this->_opts(), $key, $value)
 231         if defined $value;
 232
 233     return $oldval;
 234 }
 235
 236 sub option_binary {
 237     my $this = shift();
 238     my($key, $value) = @_;
 239
 240     my $dummylen = 0;
 241     my $oldval = Net::Z3950::ZOOM::options_getl($this->_opts(),
 242                                                 $key, $dummylen);
 243     Net::Z3950::ZOOM::options_setl($this->_opts(), $key,
 244                                    $value, length($value))
 245         if defined $value;
 246
 247     return $oldval;
 248 }
 249
 250 # This is a bit stupid, since the scalar values that Perl returns from
 251 # option() can be used as a boolean; but it's just possible that some
 252 # applications will rely on ZOOM_options_get_bool()'s idiosyncratic
 253 # interpretation of what constitutes truth.
 254 #
 255 sub bool {
 256     my $this = shift();
 257     my($key, $default) = @_;
 258
 259     return Net::Z3950::ZOOM::options_get_bool($this->_opts(), $key, $default);
 260 }
 261
 262 # .. and the next two are even more stupid
 263 sub int {
 264     my $this = shift();
 265     my($key, $default) = @_;
 266
 267     return Net::Z3950::ZOOM::options_get_int($this->_opts(), $key, $default);
 268 }
 269
 270 sub set_int {
 271     my $this = shift();
 272     my($key, $value) = @_;
 273
 274     Net::Z3950::ZOOM::options_set_int($this->_opts(), $key, $value);
 275 }
 276
 277 #   ### Feel guilty.  Feel very, very guilty.  I've not been able to
 278 #       get the callback memory-management right in "ZOOM.xs", with
 279 #       the result that the values of $function and $udata passed into
 280 #       this function, which are on the stack, have sometimes been
 281 #       freed by the time they're used by __ZOOM_option_callback(),
 282 #       with hilarious results.  To avoid this, I copy the values into
 283 #       module-scoped globals, and pass _those_ into the extension
 284 #       function.  To avoid overwriting those globals by subsequent
 285 #       calls, I keep all the old ones, pushed onto the @_function and
 286 #       @_udata arrays, which means that THIS FUNCTION LEAKS MEMORY
 287 #       LIKE IT'S GOING OUT OF FASHION.  Not nice.  One day, I should
 288 #       fix this, but for now there's more important fish to fry.
 289 #
 290 my(@_function, @_udata);
 291 sub set_callback {
 292     my $o1 = shift();
 293     my($function, $udata) = @_;
 294
 295     push @_function, $function;
 296     push @_udata, $udata;
 297     Net::Z3950::ZOOM::options_set_callback($o1->_opts(),
 298                                            $_function[-1], $_udata[-1]);
 299 }
 300
 301 sub destroy {
 302     my $this = shift();
 303
 304     Net::Z3950::ZOOM::options_destroy($this->_opts());
 305     $this->{_opts} = undef;
 306 }
 307
 308
 309 # ----------------------------------------------------------------------------
 310
 311 package ZOOM::Connection;
 312
 313 sub new {
 314     my $class = shift();
 315     my($host, $port, @options) = @_;
 316
 317     my $_opts = Net::Z3950::ZOOM::options_create();
 318     while (@options >= 2) {
 319         my $key = shift(@options);
 320         my $val = shift(@options);
 321         Net::Z3950::ZOOM::options_set($_opts, $key, $val);
 322     }
 323
 324     die "Odd number of options specified"
 325         if @options;
 326
 327     my $_conn = Net::Z3950::ZOOM::connection_create($_opts);
 328     Net::Z3950::ZOOM::connection_connect($_conn, $host, $port || 0);
 329     my $conn = bless {
 330         host => $host,
 331         port => $port,
 332         _conn => $_conn,
 333     };
 334
 335     $conn->_check();
 336     return $conn;
 337 }
 338
 339 # PRIVATE to this class, to ZOOM::event() and to ZOOM::Query::CQL2RPN::new()
 340 sub _conn {
 341     my $this = shift();
 342
 343     my $_conn = $this->{_conn};
 344     die "{_conn} undefined: has this Connection been destroy()ed?"
 345         if !defined $_conn;
 346
 347     return $_conn;
 348 }
 349
 350 sub _check {
 351     my $this = shift();
 352
 353     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "x", "x", "x");
 354     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 355                                                     $addinfo, $diagset);
 356     die new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset)
 357         if $errcode;
 358 }
 359
 360 sub create {
 361     my $class = shift();
 362     my($options) = @_;
 363
 364     my $_conn = Net::Z3950::ZOOM::connection_create($options->_opts());
 365     return bless {
 366         host => undef,
 367         port => undef,
 368         _conn => $_conn,
 369     };
 370 }
 371
 372 sub error_x {
 373     my $this = shift();
 374
 375     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 376     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 377                                                     $addinfo, $diagset);
 378     return ($errcode, $errmsg, $addinfo, $diagset);
 379 }
 380
 381 sub errcode {
 382     my $this = shift();
 383     return Net::Z3950::ZOOM::connection_errcode($this->_conn());
 384 }
 385
 386 sub errmsg {
 387     my $this = shift();
 388     return Net::Z3950::ZOOM::connection_errmsg($this->_conn());
 389 }
 390
 391 sub addinfo {
 392     my $this = shift();
 393     return Net::Z3950::ZOOM::connection_addinfo($this->_conn());
 394 }
 395
 396 sub diagset {
 397     my $this = shift();
 398     return Net::Z3950::ZOOM::connection_diagset($this->_conn());
 399 }
 400
 401 sub connect {
 402     my $this = shift();
 403     my($host, $port) = @_;
 404
 405     $port = 0 if !defined $port;
 406     Net::Z3950::ZOOM::connection_connect($this->_conn(), $host, $port);
 407     $this->_check();
 408     # No return value
 409 }
 410
 411 sub option {
 412     my $this = shift();
 413     my($key, $value) = @_;
 414
 415     my $oldval = Net::Z3950::ZOOM::connection_option_get($this->_conn(), $key);
 416     Net::Z3950::ZOOM::connection_option_set($this->_conn(), $key, $value)
 417         if defined $value;
 418
 419     return $oldval;
 420 }
 421
 422 sub option_binary {
 423     my $this = shift();
 424     my($key, $value) = @_;
 425
 426     my $dummylen = 0;
 427     my $oldval = Net::Z3950::ZOOM::connection_option_getl($this->_conn(),
 428                                                           $key, $dummylen);
 429     Net::Z3950::ZOOM::connection_option_setl($this->_conn(), $key,
 430                                              $value, length($value))
 431         if defined $value;
 432
 433     return $oldval;
 434 }
 435
 436 sub search {
 437     my $this = shift();
 438     my($query) = @_;
 439
 440     my $_rs = Net::Z3950::ZOOM::connection_search($this->_conn(),
 441                                                   $query->_query());
 442     $this->_check();
 443     return _new ZOOM::ResultSet($this, $query, $_rs);
 444 }
 445
 446 sub search_pqf {
 447     my $this = shift();
 448     my($pqf) = @_;
 449
 450     my $_rs = Net::Z3950::ZOOM::connection_search_pqf($this->_conn(), $pqf);
 451     $this->_check();
 452     return _new ZOOM::ResultSet($this, $pqf, $_rs);
 453 }
 454
 455 sub scan_pqf {
 456     my $this = shift();
 457     my($startterm) = @_;
 458
 459     my $_ss = Net::Z3950::ZOOM::connection_scan($this->_conn(), $startterm);
 460     $this->_check();
 461     return _new ZOOM::ScanSet($this, $startterm, $_ss);
 462 }
 463
 464 sub scan {
 465     my $this = shift();
 466     my($query) = @_;
 467
 468     my $_ss = Net::Z3950::ZOOM::connection_scan1($this->_conn(),
 469                                                  $query->_query());
 470     $this->_check();
 471     return _new ZOOM::ScanSet($this, $query, $_ss);
 472 }
 473
 474 sub package {
 475     my $this = shift();
 476     my($options) = @_;
 477
 478     my $_o = defined $options ? $options->_opts() :
 479         Net::Z3950::ZOOM::options_create();
 480     my $_p = Net::Z3950::ZOOM::connection_package($this->_conn(), $_o)
 481         or ZOOM::_oops(ZOOM::Error::PACKAGE);
 482
 483     return _new ZOOM::Package($this, $options, $_p);
 484 }
 485
 486 sub last_event {
 487     my $this = shift();
 488
 489     return Net::Z3950::ZOOM::connection_last_event($this->_conn());
 490 }
 491
 492 sub is_idle {
 493     my $this = shift();
 494
 495     return Net::Z3950::ZOOM::connection_is_idle($this->_conn());
 496 }
 497
 498 sub destroy {
 499     my $this = shift();
 500
 501     Net::Z3950::ZOOM::connection_destroy($this->_conn());
 502     $this->{_conn} = undef;
 503 }
 504
 505
 506 # ----------------------------------------------------------------------------
 507
 508 package ZOOM::Query;
 509
 510 sub new {
 511     my $class = shift();
 512     die "You can't create $class objects: it's a virtual base class";
 513 }
 514
 515 # PRIVATE to this class and ZOOM::Connection::search()
 516 sub _query {
 517     my $this = shift();
 518
 519     my $_query = $this->{_query};
 520     die "{_query} undefined: has this Query been destroy()ed?"
 521         if !defined $_query;
 522
 523     return $_query;
 524 }
 525
 526 sub sortby {
 527     my $this = shift();
 528     my($sortby) = @_;
 529
 530     Net::Z3950::ZOOM::query_sortby($this->_query(), $sortby) == 0
 531         or ZOOM::_oops(ZOOM::Error::SORTBY, $sortby);
 532 }
 533
 534 sub destroy {
 535     my $this = shift();
 536
 537     Net::Z3950::ZOOM::query_destroy($this->_query());
 538     $this->{_query} = undef;
 539 }
 540
 541
 542 package ZOOM::Query::CQL;
 543 our @ISA = qw(ZOOM::Query);
 544
 545 sub new {
 546     my $class = shift();
 547     my($string) = @_;
 548
 549     my $q = Net::Z3950::ZOOM::query_create()
 550         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 551     Net::Z3950::ZOOM::query_cql($q, $string) == 0
 552         or ZOOM::_oops(ZOOM::Error::QUERY_CQL, $string);
 553
 554     return bless {
 555         _query => $q,
 556     }, $class;
 557 }
 558
 559
 560 package ZOOM::Query::CQL2RPN;
 561 our @ISA = qw(ZOOM::Query);
 562
 563 sub new {
 564     my $class = shift();
 565     my($string, $conn) = @_;
 566
 567     my $q = Net::Z3950::ZOOM::query_create()
 568         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 569     # check() throws the exception we want; but we only want it on failure!
 570     Net::Z3950::ZOOM::query_cql2rpn($q, $string, $conn->_conn()) == 0
 571         or $conn->_check();
 572
 573     return bless {
 574         _query => $q,
 575     }, $class;
 576 }
 577
 578
 579 # We have to work around the retarded ZOOM_query_ccl2rpn() API
 580 package ZOOM::Query::CCL2RPN;
 581 our @ISA = qw(ZOOM::Query);
 582
 583 sub new {
 584     my $class = shift();
 585     my($string, $conn) = @_;
 586
 587     my $q = Net::Z3950::ZOOM::query_create()
 588         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 589
 590     my $config = $conn->option("cclqual");
 591     if (!defined $config) {
 592         my $cclfile = $conn->option("cclfile")
 593             or ZOOM::_oops(ZOOM::Error::CCL_CONFIG,
 594                            "no 'cclqual' or 'cclfile' specified");
 595         my $fh = new IO::File("<$cclfile")
 596             or ZOOM::_oops(ZOOM::Error::CCL_CONFIG,
 597                            "can't open cclfile '$cclfile': $!");
 598         $config = join("", <$fh>);
 599         $fh->close();
 600     }
 601
 602     my($ccl_errcode, $ccl_errstr, $ccl_errpos) = (0, "", 0);
 603     if (Net::Z3950::ZOOM::query_ccl2rpn($q, $string, $config,
 604                                         $ccl_errcode, $ccl_errstr,
 605                                         $ccl_errpos) < 0) {
 606         # We have no use for $ccl_errcode or $ccl_errpos
 607         ZOOM::_oops(ZOOM::Error::CCL_PARSE, $ccl_errstr);
 608     }
 609
 610     return bless {
 611         _query => $q,
 612     }, $class;
 613 }
 614
 615
 616 package ZOOM::Query::PQF;
 617 our @ISA = qw(ZOOM::Query);
 618
 619 sub new {
 620     my $class = shift();
 621     my($string) = @_;
 622
 623     my $q = Net::Z3950::ZOOM::query_create()
 624         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 625     Net::Z3950::ZOOM::query_prefix($q, $string) == 0
 626         or ZOOM::_oops(ZOOM::Error::QUERY_PQF, $string);
 627
 628     return bless {
 629         _query => $q,
 630     }, $class;
 631 }
 632
 633
 634 # ----------------------------------------------------------------------------
 635
 636 package ZOOM::ResultSet;
 637
 638 sub new {
 639     my $class = shift();
 640     die "You can't create $class objects directly";
 641 }
 642
 643 # PRIVATE to ZOOM::Connection::search() and ZOOM::Connection::search_pqf()
 644 sub _new {
 645     my $class = shift();
 646     my($conn, $query, $_rs) = @_;
 647
 648     return bless {
 649         conn => $conn,
 650         query => $query,        # This is not currently used, which is
 651                                 # just as well since it could be
 652                                 # either a string (when the RS is
 653                                 # created with search_pqf()) or a
 654                                 # ZOOM::Query object (when it's
 655                                 # created with search())
 656         _rs => $_rs,
 657     }, $class;
 658 }
 659
 660 # PRIVATE to this class
 661 sub _rs {
 662     my $this = shift();
 663
 664     my $_rs = $this->{_rs};
 665     die "{_rs} undefined: has this ResultSet been destroy()ed?"
 666         if !defined $_rs;
 667
 668     return $_rs;
 669 }
 670
 671 sub option {
 672     my $this = shift();
 673     my($key, $value) = @_;
 674
 675     my $oldval = Net::Z3950::ZOOM::resultset_option_get($this->_rs(), $key);
 676     Net::Z3950::ZOOM::resultset_option_set($this->_rs(), $key, $value)
 677         if defined $value;
 678
 679     return $oldval;
 680 }
 681
 682 sub size {
 683     my $this = shift();
 684
 685     return Net::Z3950::ZOOM::resultset_size($this->_rs());
 686 }
 687
 688 sub record {
 689     my $this = shift();
 690     my($which) = @_;
 691
 692     my $_rec = Net::Z3950::ZOOM::resultset_record($this->_rs(), $which);
 693     $this->{conn}->_check();
 694
 695     # Even if no error has occurred, I think record() might
 696     # legitimately return undef if we're running in asynchronous mode
 697     # and the record just hasn't been retrieved yet.  This goes double
 698     # for record_immediate().
 699     return undef if !defined $_rec;
 700
 701     # For some reason, I have to use the explicit "->" syntax in order
 702     # to invoke the ZOOM::Record constructor here, even though I don't
 703     # have to do the same for _new ZOOM::ResultSet above.  Weird.
 704     return ZOOM::Record->_new($this, $which, $_rec);
 705 }
 706
 707 sub record_immediate {
 708     my $this = shift();
 709     my($which) = @_;
 710
 711     my $_rec = Net::Z3950::ZOOM::resultset_record_immediate($this->_rs(),
 712                                                             $which);
 713     $this->{conn}->_check();
 714     # The record might legitimately not be there yet
 715     return undef if !defined $_rec;
 716
 717     return ZOOM::Record->_new($this, $which, $_rec);
 718 }
 719
 720 sub cache_reset {
 721     my $this = shift();
 722
 723     Net::Z3950::ZOOM::resultset_cache_reset($this->_rs());
 724 }
 725
 726 sub records {
 727     my $this = shift();
 728     my($start, $count, $return_records) = @_;
 729
 730     my $raw = Net::Z3950::ZOOM::resultset_records($this->_rs(), $start, $count,
 731                                                   $return_records);
 732     # By design, $raw may be undefined (if $return_records is true)
 733     return undef if !defined $raw;
 734
 735     # We need to package up the returned records in ZOOM::Record objects
 736     my @res = ();
 737     for my $i (0 .. @$raw-1) {
 738         my $_rec = $raw->[$i];
 739         if (!defined $_rec) {
 740             push @res, undef;
 741         } else {
 742             push @res, ZOOM::Record->_new($this, $start+$i, $_rec);
 743         }
 744     }
 745
 746     return \@res;
 747 }
 748
 749 sub sort {
 750     my $this = shift();
 751     my($sort_type, $sort_spec) = @_;
 752
 753     return Net::Z3950::ZOOM::resultset_sort1($this->_rs(),
 754                                              $sort_type, $sort_spec);
 755 }
 756
 757 sub destroy {
 758     my $this = shift();
 759
 760     Net::Z3950::ZOOM::resultset_destroy($this->_rs());
 761     $this->{_rs} = undef;
 762 }
 763
 764
 765 # ----------------------------------------------------------------------------
 766
 767 package ZOOM::Record;
 768
 769 sub new {
 770     my $class = shift();
 771     die "You can't create $class objects directly";
 772 }
 773
 774 # PRIVATE to ZOOM::ResultSet::record(),
 775 # ZOOM::ResultSet::record_immediate(), ZOOM::ResultSet::records() and
 776 # ZOOM::Record::clone()
 777 #
 778 sub _new {
 779     my $class = shift();
 780     my($rs, $which, $_rec) = @_;
 781
 782     return bless {
 783         rs => $rs,
 784         which => $which,
 785         _rec => $_rec,
 786     }, $class;
 787 }
 788
 789 # PRIVATE to this class
 790 sub _rec {
 791     my $this = shift();
 792
 793     my $_rec = $this->{_rec};
 794     die "{_rec} undefined: has this Record been destroy()ed?"
 795         if !defined $_rec;
 796
 797     return $_rec;
 798 }
 799
 800 sub render {
 801     my $this = shift();
 802
 803     return $this->get("render", @_);
 804 }
 805
 806 sub raw {
 807     my $this = shift();
 808
 809     return $this->get("raw", @_);
 810 }
 811
 812 sub get {
 813     my $this = shift();
 814     my($type, $args) = @_;
 815
 816     $type = "$type;$args" if defined $args;
 817     my $len = 0;
 818     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), $type, $len);
 819     # I don't think we need '$len' at all.  ### Probably the Perl-to-C
 820     # glue code should use the value of `len' as well as the opaque
 821     # data-pointer returned, to ensure that the SV contains all of the
 822     # returned data and does not stop at the first NUL character in
 823     # binary data.  Carefully check the ZOOM_record_get() documentation.
 824     return $string;
 825 }
 826
 827 sub clone {
 828     my $this = shift();
 829
 830     my $raw = Net::Z3950::ZOOM::record_clone($this->_rec())
 831         or ZOOM::_oops(ZOOM::Error::CLONE);
 832
 833     # Arg 1 (rs) is undefined as the new record doesn't belong to an RS
 834     return _new ZOOM::Record(undef, undef, $raw);
 835 }
 836
 837 sub destroy {
 838     my $this = shift();
 839
 840     Net::Z3950::ZOOM::record_destroy($this->_rec());
 841     $this->{_rec} = undef;
 842 }
 843
 844
 845 # ----------------------------------------------------------------------------
 846
 847 package ZOOM::ScanSet;
 848
 849 sub new {
 850     my $class = shift();
 851     die "You can't create $class objects directly";
 852 }
 853
 854 # PRIVATE to ZOOM::Connection::scan(),
 855 sub _new {
 856     my $class = shift();
 857     my($conn, $startterm, $_ss) = @_;
 858
 859     return bless {
 860         conn => $conn,
 861         startterm => $startterm,# This is not currently used, which is
 862                                 # just as well since it could be
 863                                 # either a string (when the SS is
 864                                 # created with scan()) or a
 865                                 # ZOOM::Query object (when it's
 866                                 # created with scan1())
 867         _ss => $_ss,
 868     }, $class;
 869 }
 870
 871 # PRIVATE to this class
 872 sub _ss {
 873     my $this = shift();
 874
 875     my $_ss = $this->{_ss};
 876     die "{_ss} undefined: has this ScanSet been destroy()ed?"
 877         if !defined $_ss;
 878
 879     return $_ss;
 880 }
 881
 882 sub option {
 883     my $this = shift();
 884     my($key, $value) = @_;
 885
 886     my $oldval = Net::Z3950::ZOOM::scanset_option_get($this->_ss(), $key);
 887     Net::Z3950::ZOOM::scanset_option_set($this->_ss(), $key, $value)
 888         if defined $value;
 889
 890     return $oldval;
 891 }
 892
 893 sub size {
 894     my $this = shift();
 895
 896     return Net::Z3950::ZOOM::scanset_size($this->_ss());
 897 }
 898
 899 sub term {
 900     my $this = shift();
 901     my($which) = @_;
 902
 903     my($occ, $len) = (0, 0);
 904     my $term = Net::Z3950::ZOOM::scanset_term($this->_ss(), $which,
 905                                               $occ, $len)
 906         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 907
 908     die "length of term '$term' differs from returned len=$len"
 909         if length($term) != $len;
 910
 911     return ($term, $occ);
 912 }
 913
 914 sub display_term {
 915     my $this = shift();
 916     my($which) = @_;
 917
 918     my($occ, $len) = (0, 0);
 919     my $term = Net::Z3950::ZOOM::scanset_display_term($this->_ss(), $which,
 920                                                       $occ, $len)
 921         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 922
 923     die "length of display term '$term' differs from returned len=$len"
 924         if length($term) != $len;
 925
 926     return ($term, $occ);
 927 }
 928
 929 sub destroy {
 930     my $this = shift();
 931
 932     Net::Z3950::ZOOM::scanset_destroy($this->_ss());
 933     $this->{_ss} = undef;
 934 }
 935
 936
 937 # ----------------------------------------------------------------------------
 938
 939 package ZOOM::Package;
 940
 941 sub new {
 942     my $class = shift();
 943     die "You can't create $class objects directly";
 944 }
 945
 946 # PRIVATE to ZOOM::Connection::package(),
 947 sub _new {
 948     my $class = shift();
 949     my($conn, $options, $_p) = @_;
 950
 951     return bless {
 952         conn => $conn,
 953         options => $options,
 954         _p => $_p,
 955     }, $class;
 956 }
 957
 958 # PRIVATE to this class
 959 sub _p {
 960     my $this = shift();
 961
 962     my $_p = $this->{_p};
 963     die "{_p} undefined: has this Package been destroy()ed?"
 964         if !defined $_p;
 965
 966     return $_p;
 967 }
 968
 969 sub option {
 970     my $this = shift();
 971     my($key, $value) = @_;
 972
 973     my $oldval = Net::Z3950::ZOOM::package_option_get($this->_p(), $key);
 974     Net::Z3950::ZOOM::package_option_set($this->_p(), $key, $value)
 975         if defined $value;
 976
 977     return $oldval;
 978 }
 979
 980 sub send {
 981     my $this = shift();
 982     my($type) = @_;
 983
 984     Net::Z3950::ZOOM::package_send($this->_p(), $type);
 985     $this->{conn}->_check();
 986 }
 987
 988 sub destroy {
 989     my $this = shift();
 990
 991     Net::Z3950::ZOOM::package_destroy($this->_p());
 992     $this->{_p} = undef;
 993 }
 994
 995
 996 # There follows trivial support for YAZ logging.  This is wired out
 997 # into the Net::Z3950::ZOOM package, and we here provide wrapper
 998 # functions -- nothing more than aliases, really -- in the ZOOM::Log
 999 # package.  There really is no point in inventing an OO interface.
1000 #
1001 # Passing @_ directly to the underlying Net::Z3950::ZOOM::* functions
1002 # doesn't work, for reasons that I can't begin to fathom, and that
1003 # don't particularly interest me.  Unpacking into scalars and passing
1004 # those _does_ work, so that's what we do.
1005
1006 package ZOOM::Log;
1007
1008 sub mask_str      { my($a) = @_; Net::Z3950::ZOOM::yaz_log_mask_str($a); }
1009 sub module_level  { my($a) = @_; Net::Z3950::ZOOM::yaz_log_module_level($a); }
1010 sub init          { my($a, $b, $c) = @_;
1011                     Net::Z3950::ZOOM::yaz_log_init($a, $b, $c) }
1012 sub init_file     { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_file($a) }
1013 sub init_level    { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_level($a) }
1014 sub init_prefix   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_prefix($a) }
1015 sub time_format   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_time_format($a) }
1016 sub init_max_size { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_max_size($a) }
1017
1018 sub log {
1019     my($level, @message) = @_;
1020
1021     if ($level !~ /^(0x)?\d+$/) {
1022         # Assuming its log-level name, we look it up.
1023         my $num = module_level($level);
1024         ZOOM::_oops(ZOOM::Error::LOGLEVEL, $level)
1025             if $num == 0;
1026         $level = $num;
1027     }
1028
1029     Net::Z3950::ZOOM::yaz_log($level, join("", @message));
1030 }
1031
1032
1033 1;