lib/ZOOM.pm

   1 # $Id: ZOOM.pm,v 1.20 2005-11-16 17:26:23 mike Exp $
   2
   3 use strict;
   4 use warnings;
   5 use Net::Z3950::ZOOM;
   6
   7
   8 package ZOOM;
   9
  10
  11 # Member naming convention: hash-element names which begin with an
  12 # underscore represent underlying ZOOM-C object descriptors; those
  13 # which lack them represent Perl's ZOOM objects.  (The same convention
  14 # is used in naming local variables where appropriate.)
  15 #
  16 # So, for example, the ZOOM::Connection class has an {_conn} element,
  17 # which is a pointer to the ZOOM-C Connection object; but the
  18 # ZOOM::ResultSet class has a {conn} element, which is a reference to
  19 # the Perl-level Connection object by which it was created.  (It may
  20 # be that we find we have no need for these references, but for now
  21 # they are retained.)
  22 #
  23 # To get at the underlying ZOOM-C connection object of a result-set
  24 # (if you ever needed to do such a thing, which you probably don't)
  25 # you'd use $rs->{conn}->_conn().
  26
  27 # ----------------------------------------------------------------------------
  28
  29 # The "Error" package contains constants returned as error-codes.
  30 package ZOOM::Error;
  31 sub NONE { Net::Z3950::ZOOM::ERROR_NONE }
  32 sub CONNECT { Net::Z3950::ZOOM::ERROR_CONNECT }
  33 sub MEMORY { Net::Z3950::ZOOM::ERROR_MEMORY }
  34 sub ENCODE { Net::Z3950::ZOOM::ERROR_ENCODE }
  35 sub DECODE { Net::Z3950::ZOOM::ERROR_DECODE }
  36 sub CONNECTION_LOST { Net::Z3950::ZOOM::ERROR_CONNECTION_LOST }
  37 sub INIT { Net::Z3950::ZOOM::ERROR_INIT }
  38 sub INTERNAL { Net::Z3950::ZOOM::ERROR_INTERNAL }
  39 sub TIMEOUT { Net::Z3950::ZOOM::ERROR_TIMEOUT }
  40 sub UNSUPPORTED_PROTOCOL { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_PROTOCOL }
  41 sub UNSUPPORTED_QUERY { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_QUERY }
  42 sub INVALID_QUERY { Net::Z3950::ZOOM::ERROR_INVALID_QUERY }
  43 # The following are added specifically for this OO interface
  44 sub CREATE_QUERY { 20001 }
  45 sub QUERY_CQL { 20002 }
  46 sub QUERY_PQF { 20003 }
  47 sub SORTBY { 20004 }
  48 sub CLONE { 20005 }
  49 sub PACKAGE { 20006 }
  50 sub SCANTERM { 20007 }
  51
  52 # The "Event" package contains constants returned by last_event()
  53 package ZOOM::Event;
  54 sub NONE { Net::Z3950::ZOOM::EVENT_NONE }
  55 sub CONNECT { Net::Z3950::ZOOM::EVENT_CONNECT }
  56 sub SEND_DATA { Net::Z3950::ZOOM::EVENT_SEND_DATA }
  57 sub RECV_DATA { Net::Z3950::ZOOM::EVENT_RECV_DATA }
  58 sub TIMEOUT { Net::Z3950::ZOOM::EVENT_TIMEOUT }
  59 sub UNKNOWN { Net::Z3950::ZOOM::EVENT_UNKNOWN }
  60 sub SEND_APDU { Net::Z3950::ZOOM::EVENT_SEND_APDU }
  61 sub RECV_APDU { Net::Z3950::ZOOM::EVENT_RECV_APDU }
  62 sub RECV_RECORD { Net::Z3950::ZOOM::EVENT_RECV_RECORD }
  63 sub RECV_SEARCH { Net::Z3950::ZOOM::EVENT_RECV_SEARCH }
  64
  65 # ----------------------------------------------------------------------------
  66
  67 package ZOOM;
  68
  69 sub diag_str {
  70     my($code) = @_;
  71
  72     # Special cases for error specific to the OO layer
  73     if ($code == ZOOM::Error::CREATE_QUERY) {
  74         return "can't create query object";
  75     } elsif ($code == ZOOM::Error::QUERY_CQL) {
  76         return "can't set CQL query";
  77     } elsif ($code == ZOOM::Error::QUERY_PQF) {
  78         return "can't set prefix query";
  79     } elsif ($code == ZOOM::Error::SORTBY) {
  80         return "can't set sort-specification";
  81     } elsif ($code == ZOOM::Error::CLONE) {
  82         return "can't clone record";
  83     } elsif ($code == ZOOM::Error::PACKAGE) {
  84         return "can't create package";
  85     } elsif ($code == ZOOM::Error::SCANTERM) {
  86         return "can't retrieve term from scan-set";
  87     }
  88
  89     return Net::Z3950::ZOOM::diag_str($code);
  90 }
  91
  92 sub _oops {
  93     my($code, $addinfo, $diagset) = @_;
  94
  95     die new ZOOM::Exception($code, diag_str($code), $addinfo, $diagset);
  96 }
  97
  98 # ----------------------------------------------------------------------------
  99
 100 package ZOOM::Exception;
 101
 102 sub new {
 103     my $class = shift();
 104     my($code, $message, $addinfo, $diagset) = @_;
 105
 106     return bless {
 107         code => $code,
 108         message => $message,
 109         addinfo => $addinfo,
 110         diagset => $diagset || "ZOOM",
 111     }, $class;
 112 }
 113
 114 sub code {
 115     my $this = shift();
 116     return $this->{code};
 117 }
 118
 119 sub message {
 120     my $this = shift();
 121     return $this->{message};
 122 }
 123
 124 sub addinfo {
 125     my $this = shift();
 126     return $this->{addinfo};
 127 }
 128
 129 sub diagset {
 130     my $this = shift();
 131     return $this->{diagset};
 132 }
 133
 134 sub render {
 135     my $this = shift();
 136     my $res = "ZOOM error " . $this->code() . ' "' . $this->message() . '"';
 137     $res .= ' (addinfo: "' . $this->addinfo() . '")' if $this->addinfo();
 138     return $res;
 139 }
 140
 141 # This means that untrapped exceptions render nicely.
 142 use overload '""' => \&render;
 143
 144 # ----------------------------------------------------------------------------
 145
 146 package ZOOM::Options;
 147
 148 sub new {
 149     my $class = shift();
 150     my($p1, $p2) = @_;
 151
 152     my $opts;
 153     if (@_ == 0) {
 154         $opts = Net::Z3950::ZOOM::options_create();
 155     } elsif (@_ == 1) {
 156         $opts = Net::Z3950::ZOOM::options_create_with_parent($p1->_opts());
 157     } elsif (@_ == 2) {
 158         $opts = Net::Z3950::ZOOM::options_create_with_parent2($p1->_opts(),
 159                                                               $p2->_opts());
 160     } else {
 161         die "can't make $class object with more than 2 parents";
 162     }
 163
 164     return bless {
 165         _opts => $opts,
 166     }, $class;
 167 }
 168
 169 # PRIVATE to this class and ZOOM::Connection::create() and
 170 # ZOOM::Connection::package()
 171 #
 172 sub _opts {
 173     my $this = shift();
 174
 175     my $_opts = $this->{_opts};
 176     die "{_opts} undefined: has this Options block been destroy()ed?"
 177         if !defined $_opts;
 178
 179     return $_opts;
 180 }
 181
 182 sub option {
 183     my $this = shift();
 184     my($key, $value) = @_;
 185
 186     my $oldval = Net::Z3950::ZOOM::options_get($this->_opts(), $key);
 187     Net::Z3950::ZOOM::options_set($this->_opts(), $key, $value)
 188         if defined $value;
 189
 190     return $oldval;
 191 }
 192
 193 sub option_binary {
 194     my $this = shift();
 195     my($key, $value) = @_;
 196
 197     my $dummylen = 0;
 198     my $oldval = Net::Z3950::ZOOM::options_getl($this->_opts(),
 199                                                 $key, $dummylen);
 200     Net::Z3950::ZOOM::options_setl($this->_opts(), $key,
 201                                    $value, length($value))
 202         if defined $value;
 203
 204     return $oldval;
 205 }
 206
 207 # This is a bit stupid, since the scalar values that Perl returns from
 208 # option() can be used as a boolean; but it's just possible that some
 209 # applications will rely on ZOOM_options_get_bool()'s idiosyncratic
 210 # interpretation of what constitutes truth.
 211 #
 212 sub bool {
 213     my $this = shift();
 214     my($key, $default) = @_;
 215
 216     return Net::Z3950::ZOOM::options_get_bool($this->_opts(), $key, $default);
 217 }
 218
 219 # .. and the next two are even more stupid
 220 sub int {
 221     my $this = shift();
 222     my($key, $default) = @_;
 223
 224     return Net::Z3950::ZOOM::options_get_int($this->_opts(), $key, $default);
 225 }
 226
 227 sub set_int {
 228     my $this = shift();
 229     my($key, $value) = @_;
 230
 231     Net::Z3950::ZOOM::options_set_int($this->_opts(), $key, $value);
 232 }
 233
 234 #   ### Feel guilty.  Feel very, very guilty.  I've not been able to
 235 #       get the callback memory-management right in "ZOOM.xs", with
 236 #       the result that the values of $function and $udata passed into
 237 #       this function, which are on the stack, have sometimes been
 238 #       freed by the time they're used by __ZOOM_option_callback(),
 239 #       with hilarious results.  To avoid this, I copy the values into
 240 #       module-scoped globals, and pass _those_ into the extension
 241 #       function.  To avoid overwriting those globals by subsequent
 242 #       calls, I keep all the old ones, pushed onto the @_function and
 243 #       @_udata arrays, which means that THIS FUNCTION LEAKS MEMORY
 244 #       LIKE IT'S GOING OUT OF FASHION.  Not nice.  One day, I should
 245 #       fix this, but for now there's more important fish to fry.
 246 #
 247 my(@_function, @_udata);
 248 sub set_callback {
 249     my $o1 = shift();
 250     my($function, $udata) = @_;
 251
 252     push @_function, $function;
 253     push @_udata, $udata;
 254     Net::Z3950::ZOOM::options_set_callback($o1->_opts(),
 255                                            $_function[-1], $_udata[-1]);
 256 }
 257
 258 sub destroy {
 259     my $this = shift();
 260
 261     Net::Z3950::ZOOM::options_destroy($this->_opts());
 262     $this->{_opts} = undef;
 263 }
 264
 265
 266 # ----------------------------------------------------------------------------
 267
 268 package ZOOM::Connection;
 269
 270 sub new {
 271     my $class = shift();
 272     my($host, $port) = @_;
 273
 274     my $_conn = Net::Z3950::ZOOM::connection_new($host, $port || 0);
 275     my $conn = bless {
 276         host => $host,
 277         port => $port,
 278         _conn => $_conn,
 279     };
 280     $conn->_check();
 281     return $conn;
 282 }
 283
 284 # PRIVATE to this class
 285 sub _conn {
 286     my $this = shift();
 287
 288     my $_conn = $this->{_conn};
 289     die "{_conn} undefined: has this Connection been destroy()ed?"
 290         if !defined $_conn;
 291
 292     return $_conn;
 293 }
 294
 295 sub _check {
 296     my $this = shift();
 297
 298     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "x", "x", "x");
 299     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 300                                                     $addinfo, $diagset);
 301     die new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset)
 302         if $errcode;
 303 }
 304
 305 sub create {
 306     my $class = shift();
 307     my($options) = @_;
 308
 309     my $_conn = Net::Z3950::ZOOM::connection_create($options->_opts());
 310     return bless {
 311         host => undef,
 312         port => undef,
 313         _conn => $_conn,
 314     };
 315 }
 316
 317 sub error_x {
 318     my $this = shift();
 319
 320     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 321     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 322                                                     $addinfo, $diagset);
 323     return ($errcode, $errmsg, $addinfo, $diagset);
 324 }
 325
 326 sub errcode {
 327     my $this = shift();
 328     return Net::Z3950::ZOOM::connection_errcode($this->_conn());
 329 }
 330
 331 sub errmsg {
 332     my $this = shift();
 333     return Net::Z3950::ZOOM::connection_errmsg($this->_conn());
 334 }
 335
 336 sub addinfo {
 337     my $this = shift();
 338     return Net::Z3950::ZOOM::connection_addinfo($this->_conn());
 339 }
 340
 341 sub diagset {
 342     my $this = shift();
 343     return Net::Z3950::ZOOM::connection_diagset($this->_conn());
 344 }
 345
 346 sub connect {
 347     my $this = shift();
 348     my($host, $port) = @_;
 349
 350     Net::Z3950::ZOOM::connection_connect($this->_conn(), $host, $port);
 351     $this->_check();
 352     # No return value
 353 }
 354
 355 sub option {
 356     my $this = shift();
 357     my($key, $value) = @_;
 358
 359     my $oldval = Net::Z3950::ZOOM::connection_option_get($this->_conn(), $key);
 360     Net::Z3950::ZOOM::connection_option_set($this->_conn(), $key, $value)
 361         if defined $value;
 362
 363     return $oldval;
 364 }
 365
 366 sub option_binary {
 367     my $this = shift();
 368     my($key, $value) = @_;
 369
 370     my $dummylen = 0;
 371     my $oldval = Net::Z3950::ZOOM::connection_option_getl($this->_conn(),
 372                                                           $key, $dummylen);
 373     Net::Z3950::ZOOM::connection_option_setl($this->_conn(), $key,
 374                                              $value, length($value))
 375         if defined $value;
 376
 377     return $oldval;
 378 }
 379
 380 sub search {
 381     my $this = shift();
 382     my($query) = @_;
 383
 384     my $_rs = Net::Z3950::ZOOM::connection_search($this->_conn(),
 385                                                   $query->_query());
 386     $this->_check();
 387     return _new ZOOM::ResultSet($this, $query, $_rs);
 388 }
 389
 390 sub search_pqf {
 391     my $this = shift();
 392     my($pqf) = @_;
 393
 394     my $_rs = Net::Z3950::ZOOM::connection_search_pqf($this->_conn(), $pqf);
 395     $this->_check();
 396     return _new ZOOM::ResultSet($this, $pqf, $_rs);
 397 }
 398
 399 sub scan {
 400     my $this = shift();
 401     my($startterm) = @_;
 402
 403     my $_ss = Net::Z3950::ZOOM::connection_scan($this->_conn(), $startterm);
 404     $this->_check();
 405     return _new ZOOM::ScanSet($this, $startterm, $_ss);
 406 }
 407
 408 sub package {
 409     my $this = shift();
 410     my($options) = @_;
 411
 412     my $_o = defined $options ? $options->_opts() :
 413         Net::Z3950::ZOOM::options_create();
 414     my $_p = Net::Z3950::ZOOM::connection_package($this->_conn(), $_o)
 415         or ZOOM::_oops(ZOOM::Error::PACKAGE);
 416
 417     return _new ZOOM::Package($this, $options, $_p);
 418 }
 419
 420 sub destroy {
 421     my $this = shift();
 422
 423     Net::Z3950::ZOOM::connection_destroy($this->_conn());
 424     $this->{_conn} = undef;
 425 }
 426
 427
 428 # ----------------------------------------------------------------------------
 429
 430 package ZOOM::Query;
 431
 432 sub new {
 433     my $class = shift();
 434     die "You can't create $class objects: it's a virtual base class";
 435 }
 436
 437 # PRIVATE to this class and ZOOM::Connection::search()
 438 sub _query {
 439     my $this = shift();
 440
 441     my $_query = $this->{_query};
 442     die "{_query} undefined: has this Query been destroy()ed?"
 443         if !defined $_query;
 444
 445     return $_query;
 446 }
 447
 448 sub sortby {
 449     my $this = shift();
 450     my($sortby) = @_;
 451
 452     Net::Z3950::ZOOM::query_sortby($this->_query(), $sortby) == 0
 453         or ZOOM::_oops(ZOOM::Error::SORTBY, $sortby);
 454 }
 455
 456 sub destroy {
 457     my $this = shift();
 458
 459     Net::Z3950::ZOOM::query_destroy($this->_query());
 460     $this->{_query} = undef;
 461 }
 462
 463
 464 package ZOOM::Query::CQL;
 465 our @ISA = qw(ZOOM::Query);
 466
 467 sub new {
 468     my $class = shift();
 469     my($string) = @_;
 470
 471     my $q = Net::Z3950::ZOOM::query_create()
 472         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 473     Net::Z3950::ZOOM::query_cql($q, $string) == 0
 474         or ZOOM::_oops(ZOOM::Error::QUERY_CQL, $string);
 475
 476     return bless {
 477         _query => $q,
 478     }, $class;
 479 }
 480
 481
 482 package ZOOM::Query::PQF;
 483 our @ISA = qw(ZOOM::Query);
 484
 485 sub new {
 486     my $class = shift();
 487     my($string) = @_;
 488
 489     my $q = Net::Z3950::ZOOM::query_create()
 490         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 491     Net::Z3950::ZOOM::query_prefix($q, $string) == 0
 492         or ZOOM::_oops(ZOOM::Error::QUERY_PQF, $string);
 493
 494     return bless {
 495         _query => $q,
 496     }, $class;
 497 }
 498
 499
 500 # ----------------------------------------------------------------------------
 501
 502 package ZOOM::ResultSet;
 503
 504 sub new {
 505     my $class = shift();
 506     die "You can't create $class objects directly";
 507 }
 508
 509 # PRIVATE to ZOOM::Connection::search() and ZOOM::Connection::search_pqf()
 510 sub _new {
 511     my $class = shift();
 512     my($conn, $query, $_rs) = @_;
 513
 514     return bless {
 515         conn => $conn,
 516         query => $query,        # This is not currently used, which is
 517                                 # just as well since it could be
 518                                 # either a string (when the RS is
 519                                 # created with search_pqf()) or a
 520                                 # ZOOM::Query object (when it's
 521                                 # created with search())
 522         _rs => $_rs,
 523     }, $class;
 524 }
 525
 526 # PRIVATE to this class
 527 sub _rs {
 528     my $this = shift();
 529
 530     my $_rs = $this->{_rs};
 531     die "{_rs} undefined: has this ResultSet been destroy()ed?"
 532         if !defined $_rs;
 533
 534     return $_rs;
 535 }
 536
 537 sub option {
 538     my $this = shift();
 539     my($key, $value) = @_;
 540
 541     my $oldval = Net::Z3950::ZOOM::resultset_option_get($this->_rs(), $key);
 542     Net::Z3950::ZOOM::resultset_option_set($this->_rs(), $key, $value)
 543         if defined $value;
 544
 545     return $oldval;
 546 }
 547
 548 sub size {
 549     my $this = shift();
 550
 551     return Net::Z3950::ZOOM::resultset_size($this->_rs());
 552 }
 553
 554 sub record {
 555     my $this = shift();
 556     my($which) = @_;
 557
 558     my $_rec = Net::Z3950::ZOOM::resultset_record($this->_rs(), $which);
 559     $this->{conn}->_check();
 560
 561     # Even if no error has occurred, I think record() might
 562     # legitimately return undef if we're running in asynchronous mode
 563     # and the record just hasn't been retrieved yet.  This goes double
 564     # for record_immediate().
 565     return undef if !defined $_rec;
 566
 567     # For some reason, I have to use the explicit "->" syntax in order
 568     # to invoke the ZOOM::Record constructor here, even though I don't
 569     # have to do the same for _new ZOOM::ResultSet above.  Weird.
 570     return ZOOM::Record->_new($this, $which, $_rec);
 571 }
 572
 573 sub record_immediate {
 574     my $this = shift();
 575     my($which) = @_;
 576
 577     my $_rec = Net::Z3950::ZOOM::resultset_record_immediate($this->_rs(),
 578                                                             $which);
 579     $this->{conn}->_check();
 580     return undef if !defined $_rec;
 581
 582     return ZOOM::Record->_new($this, $which, $_rec);
 583 }
 584
 585 sub cache_reset {
 586     my $this = shift();
 587
 588     Net::Z3950::ZOOM::resultset_cache_reset($this->_rs());
 589 }
 590
 591 sub records {
 592     my $this = shift();
 593     my($start, $count, $return_records) = @_;
 594
 595     my $raw = Net::Z3950::ZOOM::resultset_records($this->_rs(), $start, $count,
 596                                                   $return_records);
 597     # By design, $raw may be undefined (if $return_records is true)
 598     return undef if !defined $raw;
 599
 600     # We need to package up the returned records in ZOOM::Record objects
 601     my @res = ();
 602     for my $i (0 .. @$raw-1) {
 603         my $_rec = $raw->[$i];
 604         if (!defined $_rec) {
 605             push @res, undef;
 606         } else {
 607             push @res, ZOOM::Record->_new($this, $start+$i, $_rec);
 608         }
 609     }
 610
 611     return \@res;
 612 }
 613
 614 sub sort {
 615     my $this = shift();
 616     my($sort_type, $sort_spec) = @_;
 617
 618     return Net::Z3950::ZOOM::resultset_sort1($this->_rs(),
 619                                              $sort_type, $sort_spec);
 620 }
 621
 622 sub destroy {
 623     my $this = shift();
 624
 625     Net::Z3950::ZOOM::resultset_destroy($this->_rs());
 626     $this->{_rs} = undef;
 627 }
 628
 629
 630 # ----------------------------------------------------------------------------
 631
 632 package ZOOM::Record;
 633
 634 sub new {
 635     my $class = shift();
 636     die "You can't create $class objects directly";
 637 }
 638
 639 # PRIVATE to ZOOM::ResultSet::record(),
 640 # ZOOM::ResultSet::record_immediate(), ZOOM::ResultSet::records() and
 641 # ZOOM::Record::clone()
 642 #
 643 sub _new {
 644     my $class = shift();
 645     my($rs, $which, $_rec) = @_;
 646
 647     return bless {
 648         rs => $rs,
 649         which => $which,
 650         _rec => $_rec,
 651     }, $class;
 652 }
 653
 654 # PRIVATE to this class
 655 sub _rec {
 656     my $this = shift();
 657
 658     my $_rec = $this->{_rec};
 659     die "{_rec} undefined: has this Record been destroy()ed?"
 660         if !defined $_rec;
 661
 662     return $_rec;
 663 }
 664
 665 sub render {
 666     my $this = shift();
 667
 668     my $len = 0;
 669     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), "render", $len);
 670     # I don't think we need '$len' at all.  ### Probably the Perl-to-C
 671     # glue code should use the value of `len' as well as the opaque
 672     # data-pointer returned, to ensure that the SV contains all of the
 673     # returned data and does not stop at the first NUL character in
 674     # binary data.  Carefully check the ZOOM_record_get() documentation.
 675     return $string;
 676 }
 677
 678 sub raw {
 679     my $this = shift();
 680
 681     my $len = 0;
 682     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), "raw", $len);
 683     # See comment about $len in render()
 684     return $string;
 685 }
 686
 687 sub clone {
 688     my $this = shift();
 689
 690     my $raw = Net::Z3950::ZOOM::record_clone($this->_rec())
 691         or ZOOM::_oops(ZOOM::Error::CLONE);
 692
 693     # Arg 1 (rs) is undefined as the new record doesn't belong to an RS
 694     return _new ZOOM::Record(undef, undef, $raw);
 695 }
 696
 697 sub destroy {
 698     my $this = shift();
 699
 700     Net::Z3950::ZOOM::record_destroy($this->_rec());
 701     $this->{_rec} = undef;
 702 }
 703
 704
 705 # ----------------------------------------------------------------------------
 706
 707 package ZOOM::ScanSet;
 708
 709 sub new {
 710     my $class = shift();
 711     die "You can't create $class objects directly";
 712 }
 713
 714 # PRIVATE to ZOOM::Connection::scan(),
 715 sub _new {
 716     my $class = shift();
 717     my($conn, $startterm, $_ss) = @_;
 718
 719     return bless {
 720         conn => $conn,
 721         startterm => $startterm,
 722         _ss => $_ss,
 723     }, $class;
 724 }
 725
 726 # PRIVATE to this class
 727 sub _ss {
 728     my $this = shift();
 729
 730     my $_ss = $this->{_ss};
 731     die "{_ss} undefined: has this ScanSet been destroy()ed?"
 732         if !defined $_ss;
 733
 734     return $_ss;
 735 }
 736
 737 sub option {
 738     my $this = shift();
 739     my($key, $value) = @_;
 740
 741     my $oldval = Net::Z3950::ZOOM::scanset_option_get($this->_ss(), $key);
 742     Net::Z3950::ZOOM::scanset_option_set($this->_ss(), $key, $value)
 743         if defined $value;
 744
 745     return $oldval;
 746 }
 747
 748 sub size {
 749     my $this = shift();
 750
 751     return Net::Z3950::ZOOM::scanset_size($this->_ss());
 752 }
 753
 754 sub term {
 755     my $this = shift();
 756     my($which) = @_;
 757
 758     my($occ, $len) = (0, 0);
 759     my $term = Net::Z3950::ZOOM::scanset_term($this->_ss(), $which,
 760                                               $occ, $len)
 761         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 762
 763     die "length of term '$term' differs from returned len=$len"
 764         if length($term) != $len;
 765
 766     return ($term, $occ);
 767 }
 768
 769 sub display_term {
 770     my $this = shift();
 771     my($which) = @_;
 772
 773     my($occ, $len) = (0, 0);
 774     my $term = Net::Z3950::ZOOM::scanset_display_term($this->_ss(), $which,
 775                                                       $occ, $len)
 776         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 777
 778     die "length of display term '$term' differs from returned len=$len"
 779         if length($term) != $len;
 780
 781     return ($term, $occ);
 782 }
 783
 784 sub destroy {
 785     my $this = shift();
 786
 787     Net::Z3950::ZOOM::scanset_destroy($this->_ss());
 788     $this->{_ss} = undef;
 789 }
 790
 791
 792 # ----------------------------------------------------------------------------
 793
 794 package ZOOM::Package;
 795
 796 sub new {
 797     my $class = shift();
 798     die "You can't create $class objects directly";
 799 }
 800
 801 # PRIVATE to ZOOM::Connection::package(),
 802 sub _new {
 803     my $class = shift();
 804     my($conn, $options, $_p) = @_;
 805
 806     return bless {
 807         conn => $conn,
 808         options => $options,
 809         _p => $_p,
 810     }, $class;
 811 }
 812
 813 # PRIVATE to this class
 814 sub _p {
 815     my $this = shift();
 816
 817     my $_p = $this->{_p};
 818     die "{_p} undefined: has this Package been destroy()ed?"
 819         if !defined $_p;
 820
 821     return $_p;
 822 }
 823
 824 sub option {
 825     my $this = shift();
 826     my($key, $value) = @_;
 827
 828     my $oldval = Net::Z3950::ZOOM::package_option_get($this->_p(), $key);
 829     Net::Z3950::ZOOM::package_option_set($this->_p(), $key, $value)
 830         if defined $value;
 831
 832     return $oldval;
 833 }
 834
 835 sub send {
 836     my $this = shift();
 837     my($type) = @_;
 838
 839     Net::Z3950::ZOOM::package_send($this->_p(), $type);
 840     $this->{conn}->_check();
 841 }
 842
 843 sub destroy {
 844     my $this = shift();
 845
 846     Net::Z3950::ZOOM::package_destroy($this->_p());
 847     $this->{_p} = undef;
 848 }
 849
 850
 851 1;