lib/ZOOM.pm

   1 # $Id: ZOOM.pm,v 1.32 2006-04-11 16:27:01 mike Exp $
   2
   3 use strict;
   4 use warnings;
   5 use Net::Z3950::ZOOM;
   6
   7
   8 package ZOOM;
   9
  10 # Member naming convention: hash-element names which begin with an
  11 # underscore represent underlying ZOOM-C object descriptors; those
  12 # which lack them represent Perl's ZOOM objects.  (The same convention
  13 # is used in naming local variables where appropriate.)
  14 #
  15 # So, for example, the ZOOM::Connection class has an {_conn} element,
  16 # which is a pointer to the ZOOM-C Connection object; but the
  17 # ZOOM::ResultSet class has a {conn} element, which is a reference to
  18 # the Perl-level Connection object by which it was created.  (It may
  19 # be that we find we have no need for these references, but for now
  20 # they are retained.)
  21 #
  22 # To get at the underlying ZOOM-C connection object of a result-set
  23 # (if you ever needed to do such a thing, which you probably don't)
  24 # you'd use $rs->{conn}->_conn().
  25
  26 # ----------------------------------------------------------------------------
  27
  28 # The "Error" package contains constants returned as error-codes.
  29 package ZOOM::Error;
  30 sub NONE { Net::Z3950::ZOOM::ERROR_NONE }
  31 sub CONNECT { Net::Z3950::ZOOM::ERROR_CONNECT }
  32 sub MEMORY { Net::Z3950::ZOOM::ERROR_MEMORY }
  33 sub ENCODE { Net::Z3950::ZOOM::ERROR_ENCODE }
  34 sub DECODE { Net::Z3950::ZOOM::ERROR_DECODE }
  35 sub CONNECTION_LOST { Net::Z3950::ZOOM::ERROR_CONNECTION_LOST }
  36 sub INIT { Net::Z3950::ZOOM::ERROR_INIT }
  37 sub INTERNAL { Net::Z3950::ZOOM::ERROR_INTERNAL }
  38 sub TIMEOUT { Net::Z3950::ZOOM::ERROR_TIMEOUT }
  39 sub UNSUPPORTED_PROTOCOL { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_PROTOCOL }
  40 sub UNSUPPORTED_QUERY { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_QUERY }
  41 sub INVALID_QUERY { Net::Z3950::ZOOM::ERROR_INVALID_QUERY }
  42 sub CQL_PARSE { Net::Z3950::ZOOM::ERROR_CQL_PARSE }
  43 sub CQL_TRANSFORM { Net::Z3950::ZOOM::ERROR_CQL_TRANSFORM }
  44 # The following are added specifically for this OO interface
  45 sub CREATE_QUERY { 20001 }
  46 sub QUERY_CQL { 20002 }
  47 sub QUERY_PQF { 20003 }
  48 sub SORTBY { 20004 }
  49 sub CLONE { 20005 }
  50 sub PACKAGE { 20006 }
  51 sub SCANTERM { 20007 }
  52 sub LOGLEVEL { 20008 }
  53
  54 # The "Event" package contains constants returned by last_event()
  55 package ZOOM::Event;
  56 sub NONE { Net::Z3950::ZOOM::EVENT_NONE }
  57 sub CONNECT { Net::Z3950::ZOOM::EVENT_CONNECT }
  58 sub SEND_DATA { Net::Z3950::ZOOM::EVENT_SEND_DATA }
  59 sub RECV_DATA { Net::Z3950::ZOOM::EVENT_RECV_DATA }
  60 sub TIMEOUT { Net::Z3950::ZOOM::EVENT_TIMEOUT }
  61 sub UNKNOWN { Net::Z3950::ZOOM::EVENT_UNKNOWN }
  62 sub SEND_APDU { Net::Z3950::ZOOM::EVENT_SEND_APDU }
  63 sub RECV_APDU { Net::Z3950::ZOOM::EVENT_RECV_APDU }
  64 sub RECV_RECORD { Net::Z3950::ZOOM::EVENT_RECV_RECORD }
  65 sub RECV_SEARCH { Net::Z3950::ZOOM::EVENT_RECV_SEARCH }
  66 sub ZEND { Net::Z3950::ZOOM::EVENT_END }
  67
  68 # ----------------------------------------------------------------------------
  69
  70 package ZOOM;
  71
  72 sub diag_str {
  73     my($code) = @_;
  74
  75     # Special cases for error specific to the OO layer
  76     if ($code == ZOOM::Error::CREATE_QUERY) {
  77         return "can't create query object";
  78     } elsif ($code == ZOOM::Error::QUERY_CQL) {
  79         return "can't set CQL query";
  80     } elsif ($code == ZOOM::Error::QUERY_PQF) {
  81         return "can't set prefix query";
  82     } elsif ($code == ZOOM::Error::SORTBY) {
  83         return "can't set sort-specification";
  84     } elsif ($code == ZOOM::Error::CLONE) {
  85         return "can't clone record";
  86     } elsif ($code == ZOOM::Error::PACKAGE) {
  87         return "can't create package";
  88     } elsif ($code == ZOOM::Error::SCANTERM) {
  89         return "can't retrieve term from scan-set";
  90     } elsif ($code == ZOOM::Error::LOGLEVEL) {
  91         return "unregistered log-level";
  92     }
  93
  94     return Net::Z3950::ZOOM::diag_str($code);
  95 }
  96
  97 ### Undocumented
  98 sub event_str {
  99     return Net::Z3950::ZOOM::event_str(@_);
 100 }
 101
 102 ### Undocumented
 103 sub event {
 104     my($connsref) = @_;
 105
 106     my @_connsref = map { $_->_conn() } @$connsref;
 107     return Net::Z3950::ZOOM::event(\@_connsref);
 108 }
 109
 110 sub _oops {
 111     my($code, $addinfo, $diagset) = @_;
 112
 113     die new ZOOM::Exception($code, diag_str($code), $addinfo, $diagset);
 114 }
 115
 116 # ----------------------------------------------------------------------------
 117
 118 package ZOOM::Exception;
 119
 120 sub new {
 121     my $class = shift();
 122     my($code, $message, $addinfo, $diagset) = @_;
 123
 124     return bless {
 125         code => $code,
 126         message => $message,
 127         addinfo => $addinfo,
 128         diagset => $diagset || "ZOOM",
 129     }, $class;
 130 }
 131
 132 sub code {
 133     my $this = shift();
 134     return $this->{code};
 135 }
 136
 137 sub message {
 138     my $this = shift();
 139     return $this->{message};
 140 }
 141
 142 sub addinfo {
 143     my $this = shift();
 144     return $this->{addinfo};
 145 }
 146
 147 sub diagset {
 148     my $this = shift();
 149     return $this->{diagset};
 150 }
 151
 152 sub render {
 153     my $this = shift();
 154     my $res = "ZOOM error " . $this->code() . ' "' . $this->message() . '"';
 155     $res .= ' (addinfo: "' . $this->addinfo() . '")' if $this->addinfo();
 156     $res .= " from diag-set '" . $this->diagset() . "'" if $this->diagset();
 157     return $res;
 158 }
 159
 160 # This means that untrapped exceptions render nicely.
 161 use overload '""' => \&render;
 162
 163 # ----------------------------------------------------------------------------
 164
 165 package ZOOM::Options;
 166
 167 sub new {
 168     my $class = shift();
 169     my($p1, $p2) = @_;
 170
 171     my $opts;
 172     if (@_ == 0) {
 173         $opts = Net::Z3950::ZOOM::options_create();
 174     } elsif (@_ == 1) {
 175         $opts = Net::Z3950::ZOOM::options_create_with_parent($p1->_opts());
 176     } elsif (@_ == 2) {
 177         $opts = Net::Z3950::ZOOM::options_create_with_parent2($p1->_opts(),
 178                                                               $p2->_opts());
 179     } else {
 180         die "can't make $class object with more than 2 parents";
 181     }
 182
 183     return bless {
 184         _opts => $opts,
 185     }, $class;
 186 }
 187
 188 # PRIVATE to this class and ZOOM::Connection::create() and
 189 # ZOOM::Connection::package()
 190 #
 191 sub _opts {
 192     my $this = shift();
 193
 194     my $_opts = $this->{_opts};
 195     die "{_opts} undefined: has this Options block been destroy()ed?"
 196         if !defined $_opts;
 197
 198     return $_opts;
 199 }
 200
 201 sub option {
 202     my $this = shift();
 203     my($key, $value) = @_;
 204
 205     my $oldval = Net::Z3950::ZOOM::options_get($this->_opts(), $key);
 206     Net::Z3950::ZOOM::options_set($this->_opts(), $key, $value)
 207         if defined $value;
 208
 209     return $oldval;
 210 }
 211
 212 sub option_binary {
 213     my $this = shift();
 214     my($key, $value) = @_;
 215
 216     my $dummylen = 0;
 217     my $oldval = Net::Z3950::ZOOM::options_getl($this->_opts(),
 218                                                 $key, $dummylen);
 219     Net::Z3950::ZOOM::options_setl($this->_opts(), $key,
 220                                    $value, length($value))
 221         if defined $value;
 222
 223     return $oldval;
 224 }
 225
 226 # This is a bit stupid, since the scalar values that Perl returns from
 227 # option() can be used as a boolean; but it's just possible that some
 228 # applications will rely on ZOOM_options_get_bool()'s idiosyncratic
 229 # interpretation of what constitutes truth.
 230 #
 231 sub bool {
 232     my $this = shift();
 233     my($key, $default) = @_;
 234
 235     return Net::Z3950::ZOOM::options_get_bool($this->_opts(), $key, $default);
 236 }
 237
 238 # .. and the next two are even more stupid
 239 sub int {
 240     my $this = shift();
 241     my($key, $default) = @_;
 242
 243     return Net::Z3950::ZOOM::options_get_int($this->_opts(), $key, $default);
 244 }
 245
 246 sub set_int {
 247     my $this = shift();
 248     my($key, $value) = @_;
 249
 250     Net::Z3950::ZOOM::options_set_int($this->_opts(), $key, $value);
 251 }
 252
 253 #   ### Feel guilty.  Feel very, very guilty.  I've not been able to
 254 #       get the callback memory-management right in "ZOOM.xs", with
 255 #       the result that the values of $function and $udata passed into
 256 #       this function, which are on the stack, have sometimes been
 257 #       freed by the time they're used by __ZOOM_option_callback(),
 258 #       with hilarious results.  To avoid this, I copy the values into
 259 #       module-scoped globals, and pass _those_ into the extension
 260 #       function.  To avoid overwriting those globals by subsequent
 261 #       calls, I keep all the old ones, pushed onto the @_function and
 262 #       @_udata arrays, which means that THIS FUNCTION LEAKS MEMORY
 263 #       LIKE IT'S GOING OUT OF FASHION.  Not nice.  One day, I should
 264 #       fix this, but for now there's more important fish to fry.
 265 #
 266 my(@_function, @_udata);
 267 sub set_callback {
 268     my $o1 = shift();
 269     my($function, $udata) = @_;
 270
 271     push @_function, $function;
 272     push @_udata, $udata;
 273     Net::Z3950::ZOOM::options_set_callback($o1->_opts(),
 274                                            $_function[-1], $_udata[-1]);
 275 }
 276
 277 sub destroy {
 278     my $this = shift();
 279
 280     Net::Z3950::ZOOM::options_destroy($this->_opts());
 281     $this->{_opts} = undef;
 282 }
 283
 284
 285 # ----------------------------------------------------------------------------
 286
 287 package ZOOM::Connection;
 288
 289 sub new {
 290     my $class = shift();
 291     my($host, $port, @options) = @_;
 292
 293     my $_opts = Net::Z3950::ZOOM::options_create();
 294     while (@options >= 2) {
 295         my $key = shift(@options);
 296         my $val = shift(@options);
 297         Net::Z3950::ZOOM::options_set($_opts, $key, $val);
 298     }
 299
 300     die "Odd number of options specified"
 301         if @options;
 302
 303     my $_conn = Net::Z3950::ZOOM::connection_create($_opts);
 304     Net::Z3950::ZOOM::connection_connect($_conn, $host, $port);
 305     my $conn = bless {
 306         host => $host,
 307         port => $port,
 308         _conn => $_conn,
 309     };
 310
 311     $conn->_check();
 312     return $conn;
 313 }
 314
 315 # PRIVATE to this class, to ZOOM::event() and to ZOOM::Query::CQL2RPN::new()
 316 sub _conn {
 317     my $this = shift();
 318
 319     my $_conn = $this->{_conn};
 320     die "{_conn} undefined: has this Connection been destroy()ed?"
 321         if !defined $_conn;
 322
 323     return $_conn;
 324 }
 325
 326 sub _check {
 327     my $this = shift();
 328
 329     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "x", "x", "x");
 330     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 331                                                     $addinfo, $diagset);
 332     die new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset)
 333         if $errcode;
 334 }
 335
 336 sub create {
 337     my $class = shift();
 338     my($options) = @_;
 339
 340     my $_conn = Net::Z3950::ZOOM::connection_create($options->_opts());
 341     return bless {
 342         host => undef,
 343         port => undef,
 344         _conn => $_conn,
 345     };
 346 }
 347
 348 sub error_x {
 349     my $this = shift();
 350
 351     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 352     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 353                                                     $addinfo, $diagset);
 354     return ($errcode, $errmsg, $addinfo, $diagset);
 355 }
 356
 357 sub errcode {
 358     my $this = shift();
 359     return Net::Z3950::ZOOM::connection_errcode($this->_conn());
 360 }
 361
 362 sub errmsg {
 363     my $this = shift();
 364     return Net::Z3950::ZOOM::connection_errmsg($this->_conn());
 365 }
 366
 367 sub addinfo {
 368     my $this = shift();
 369     return Net::Z3950::ZOOM::connection_addinfo($this->_conn());
 370 }
 371
 372 sub diagset {
 373     my $this = shift();
 374     return Net::Z3950::ZOOM::connection_diagset($this->_conn());
 375 }
 376
 377 sub connect {
 378     my $this = shift();
 379     my($host, $port) = @_;
 380
 381     $port = 0 if !defined $port;
 382     Net::Z3950::ZOOM::connection_connect($this->_conn(), $host, $port);
 383     $this->_check();
 384     # No return value
 385 }
 386
 387 sub option {
 388     my $this = shift();
 389     my($key, $value) = @_;
 390
 391     my $oldval = Net::Z3950::ZOOM::connection_option_get($this->_conn(), $key);
 392     Net::Z3950::ZOOM::connection_option_set($this->_conn(), $key, $value)
 393         if defined $value;
 394
 395     return $oldval;
 396 }
 397
 398 sub option_binary {
 399     my $this = shift();
 400     my($key, $value) = @_;
 401
 402     my $dummylen = 0;
 403     my $oldval = Net::Z3950::ZOOM::connection_option_getl($this->_conn(),
 404                                                           $key, $dummylen);
 405     Net::Z3950::ZOOM::connection_option_setl($this->_conn(), $key,
 406                                              $value, length($value))
 407         if defined $value;
 408
 409     return $oldval;
 410 }
 411
 412 sub search {
 413     my $this = shift();
 414     my($query) = @_;
 415
 416     my $_rs = Net::Z3950::ZOOM::connection_search($this->_conn(),
 417                                                   $query->_query());
 418     $this->_check();
 419     return _new ZOOM::ResultSet($this, $query, $_rs);
 420 }
 421
 422 sub search_pqf {
 423     my $this = shift();
 424     my($pqf) = @_;
 425
 426     my $_rs = Net::Z3950::ZOOM::connection_search_pqf($this->_conn(), $pqf);
 427     $this->_check();
 428     return _new ZOOM::ResultSet($this, $pqf, $_rs);
 429 }
 430
 431 sub scan_pqf {
 432     my $this = shift();
 433     my($startterm) = @_;
 434
 435     my $_ss = Net::Z3950::ZOOM::connection_scan($this->_conn(), $startterm);
 436     $this->_check();
 437     return _new ZOOM::ScanSet($this, $startterm, $_ss);
 438 }
 439
 440 sub scan {
 441     my $this = shift();
 442     my($query) = @_;
 443
 444     my $_ss = Net::Z3950::ZOOM::connection_scan1($this->_conn(),
 445                                                  $query->_query());
 446     $this->_check();
 447     return _new ZOOM::ScanSet($this, $query, $_ss);
 448 }
 449
 450 sub package {
 451     my $this = shift();
 452     my($options) = @_;
 453
 454     my $_o = defined $options ? $options->_opts() :
 455         Net::Z3950::ZOOM::options_create();
 456     my $_p = Net::Z3950::ZOOM::connection_package($this->_conn(), $_o)
 457         or ZOOM::_oops(ZOOM::Error::PACKAGE);
 458
 459     return _new ZOOM::Package($this, $options, $_p);
 460 }
 461
 462 ### Undocumented
 463 sub last_event {
 464     my $this = shift();
 465
 466     return Net::Z3950::ZOOM::connection_last_event($this->_conn());
 467 }
 468
 469 sub destroy {
 470     my $this = shift();
 471
 472     Net::Z3950::ZOOM::connection_destroy($this->_conn());
 473     $this->{_conn} = undef;
 474 }
 475
 476
 477 # ----------------------------------------------------------------------------
 478
 479 package ZOOM::Query;
 480
 481 sub new {
 482     my $class = shift();
 483     die "You can't create $class objects: it's a virtual base class";
 484 }
 485
 486 # PRIVATE to this class and ZOOM::Connection::search()
 487 sub _query {
 488     my $this = shift();
 489
 490     my $_query = $this->{_query};
 491     die "{_query} undefined: has this Query been destroy()ed?"
 492         if !defined $_query;
 493
 494     return $_query;
 495 }
 496
 497 sub sortby {
 498     my $this = shift();
 499     my($sortby) = @_;
 500
 501     Net::Z3950::ZOOM::query_sortby($this->_query(), $sortby) == 0
 502         or ZOOM::_oops(ZOOM::Error::SORTBY, $sortby);
 503 }
 504
 505 sub destroy {
 506     my $this = shift();
 507
 508     Net::Z3950::ZOOM::query_destroy($this->_query());
 509     $this->{_query} = undef;
 510 }
 511
 512
 513 package ZOOM::Query::CQL;
 514 our @ISA = qw(ZOOM::Query);
 515
 516 sub new {
 517     my $class = shift();
 518     my($string) = @_;
 519
 520     my $q = Net::Z3950::ZOOM::query_create()
 521         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 522     Net::Z3950::ZOOM::query_cql($q, $string) == 0
 523         or ZOOM::_oops(ZOOM::Error::QUERY_CQL, $string);
 524
 525     return bless {
 526         _query => $q,
 527     }, $class;
 528 }
 529
 530
 531 package ZOOM::Query::CQL2RPN;
 532 our @ISA = qw(ZOOM::Query);
 533
 534 sub new {
 535     my $class = shift();
 536     my($string, $conn) = @_;
 537
 538     my $q = Net::Z3950::ZOOM::query_create()
 539         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 540     # check() throws the exception we want; but we only want it on failure!
 541     Net::Z3950::ZOOM::query_cql2rpn($q, $string, $conn->_conn()) == 0
 542         or $conn->_check();
 543
 544     return bless {
 545         _query => $q,
 546     }, $class;
 547 }
 548
 549
 550 package ZOOM::Query::PQF;
 551 our @ISA = qw(ZOOM::Query);
 552
 553 sub new {
 554     my $class = shift();
 555     my($string) = @_;
 556
 557     my $q = Net::Z3950::ZOOM::query_create()
 558         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 559     Net::Z3950::ZOOM::query_prefix($q, $string) == 0
 560         or ZOOM::_oops(ZOOM::Error::QUERY_PQF, $string);
 561
 562     return bless {
 563         _query => $q,
 564     }, $class;
 565 }
 566
 567
 568 # ----------------------------------------------------------------------------
 569
 570 package ZOOM::ResultSet;
 571
 572 sub new {
 573     my $class = shift();
 574     die "You can't create $class objects directly";
 575 }
 576
 577 # PRIVATE to ZOOM::Connection::search() and ZOOM::Connection::search_pqf()
 578 sub _new {
 579     my $class = shift();
 580     my($conn, $query, $_rs) = @_;
 581
 582     return bless {
 583         conn => $conn,
 584         query => $query,        # This is not currently used, which is
 585                                 # just as well since it could be
 586                                 # either a string (when the RS is
 587                                 # created with search_pqf()) or a
 588                                 # ZOOM::Query object (when it's
 589                                 # created with search())
 590         _rs => $_rs,
 591     }, $class;
 592 }
 593
 594 # PRIVATE to this class
 595 sub _rs {
 596     my $this = shift();
 597
 598     my $_rs = $this->{_rs};
 599     die "{_rs} undefined: has this ResultSet been destroy()ed?"
 600         if !defined $_rs;
 601
 602     return $_rs;
 603 }
 604
 605 sub option {
 606     my $this = shift();
 607     my($key, $value) = @_;
 608
 609     my $oldval = Net::Z3950::ZOOM::resultset_option_get($this->_rs(), $key);
 610     Net::Z3950::ZOOM::resultset_option_set($this->_rs(), $key, $value)
 611         if defined $value;
 612
 613     return $oldval;
 614 }
 615
 616 sub size {
 617     my $this = shift();
 618
 619     return Net::Z3950::ZOOM::resultset_size($this->_rs());
 620 }
 621
 622 sub record {
 623     my $this = shift();
 624     my($which) = @_;
 625
 626     my $_rec = Net::Z3950::ZOOM::resultset_record($this->_rs(), $which);
 627     $this->{conn}->_check();
 628
 629     # Even if no error has occurred, I think record() might
 630     # legitimately return undef if we're running in asynchronous mode
 631     # and the record just hasn't been retrieved yet.  This goes double
 632     # for record_immediate().
 633     return undef if !defined $_rec;
 634
 635     # For some reason, I have to use the explicit "->" syntax in order
 636     # to invoke the ZOOM::Record constructor here, even though I don't
 637     # have to do the same for _new ZOOM::ResultSet above.  Weird.
 638     return ZOOM::Record->_new($this, $which, $_rec);
 639 }
 640
 641 sub record_immediate {
 642     my $this = shift();
 643     my($which) = @_;
 644
 645     my $_rec = Net::Z3950::ZOOM::resultset_record_immediate($this->_rs(),
 646                                                             $which);
 647     $this->{conn}->_check();
 648     # The record might legitimately not be there yet
 649     return undef if !defined $_rec;
 650
 651     return ZOOM::Record->_new($this, $which, $_rec);
 652 }
 653
 654 sub cache_reset {
 655     my $this = shift();
 656
 657     Net::Z3950::ZOOM::resultset_cache_reset($this->_rs());
 658 }
 659
 660 sub records {
 661     my $this = shift();
 662     my($start, $count, $return_records) = @_;
 663
 664     my $raw = Net::Z3950::ZOOM::resultset_records($this->_rs(), $start, $count,
 665                                                   $return_records);
 666     # By design, $raw may be undefined (if $return_records is true)
 667     return undef if !defined $raw;
 668
 669     # We need to package up the returned records in ZOOM::Record objects
 670     my @res = ();
 671     for my $i (0 .. @$raw-1) {
 672         my $_rec = $raw->[$i];
 673         if (!defined $_rec) {
 674             push @res, undef;
 675         } else {
 676             push @res, ZOOM::Record->_new($this, $start+$i, $_rec);
 677         }
 678     }
 679
 680     return \@res;
 681 }
 682
 683 sub sort {
 684     my $this = shift();
 685     my($sort_type, $sort_spec) = @_;
 686
 687     return Net::Z3950::ZOOM::resultset_sort1($this->_rs(),
 688                                              $sort_type, $sort_spec);
 689 }
 690
 691 sub destroy {
 692     my $this = shift();
 693
 694     Net::Z3950::ZOOM::resultset_destroy($this->_rs());
 695     $this->{_rs} = undef;
 696 }
 697
 698
 699 # ----------------------------------------------------------------------------
 700
 701 package ZOOM::Record;
 702
 703 sub new {
 704     my $class = shift();
 705     die "You can't create $class objects directly";
 706 }
 707
 708 # PRIVATE to ZOOM::ResultSet::record(),
 709 # ZOOM::ResultSet::record_immediate(), ZOOM::ResultSet::records() and
 710 # ZOOM::Record::clone()
 711 #
 712 sub _new {
 713     my $class = shift();
 714     my($rs, $which, $_rec) = @_;
 715
 716     return bless {
 717         rs => $rs,
 718         which => $which,
 719         _rec => $_rec,
 720     }, $class;
 721 }
 722
 723 # PRIVATE to this class
 724 sub _rec {
 725     my $this = shift();
 726
 727     my $_rec = $this->{_rec};
 728     die "{_rec} undefined: has this Record been destroy()ed?"
 729         if !defined $_rec;
 730
 731     return $_rec;
 732 }
 733
 734 sub render {
 735     my $this = shift();
 736
 737     return $this->get("render", @_);
 738 }
 739
 740 sub raw {
 741     my $this = shift();
 742
 743     return $this->get("raw", @_);
 744 }
 745
 746 sub get {
 747     my $this = shift();
 748     my($type, $args) = @_;
 749
 750     $type = "$type;$args" if defined $args;
 751     my $len = 0;
 752     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), $type, $len);
 753     # I don't think we need '$len' at all.  ### Probably the Perl-to-C
 754     # glue code should use the value of `len' as well as the opaque
 755     # data-pointer returned, to ensure that the SV contains all of the
 756     # returned data and does not stop at the first NUL character in
 757     # binary data.  Carefully check the ZOOM_record_get() documentation.
 758     return $string;
 759 }
 760
 761 sub clone {
 762     my $this = shift();
 763
 764     my $raw = Net::Z3950::ZOOM::record_clone($this->_rec())
 765         or ZOOM::_oops(ZOOM::Error::CLONE);
 766
 767     # Arg 1 (rs) is undefined as the new record doesn't belong to an RS
 768     return _new ZOOM::Record(undef, undef, $raw);
 769 }
 770
 771 sub destroy {
 772     my $this = shift();
 773
 774     Net::Z3950::ZOOM::record_destroy($this->_rec());
 775     $this->{_rec} = undef;
 776 }
 777
 778
 779 # ----------------------------------------------------------------------------
 780
 781 package ZOOM::ScanSet;
 782
 783 sub new {
 784     my $class = shift();
 785     die "You can't create $class objects directly";
 786 }
 787
 788 # PRIVATE to ZOOM::Connection::scan(),
 789 sub _new {
 790     my $class = shift();
 791     my($conn, $startterm, $_ss) = @_;
 792
 793     return bless {
 794         conn => $conn,
 795         startterm => $startterm,# This is not currently used, which is
 796                                 # just as well since it could be
 797                                 # either a string (when the SS is
 798                                 # created with scan()) or a
 799                                 # ZOOM::Query object (when it's
 800                                 # created with scan1())
 801         _ss => $_ss,
 802     }, $class;
 803 }
 804
 805 # PRIVATE to this class
 806 sub _ss {
 807     my $this = shift();
 808
 809     my $_ss = $this->{_ss};
 810     die "{_ss} undefined: has this ScanSet been destroy()ed?"
 811         if !defined $_ss;
 812
 813     return $_ss;
 814 }
 815
 816 sub option {
 817     my $this = shift();
 818     my($key, $value) = @_;
 819
 820     my $oldval = Net::Z3950::ZOOM::scanset_option_get($this->_ss(), $key);
 821     Net::Z3950::ZOOM::scanset_option_set($this->_ss(), $key, $value)
 822         if defined $value;
 823
 824     return $oldval;
 825 }
 826
 827 sub size {
 828     my $this = shift();
 829
 830     return Net::Z3950::ZOOM::scanset_size($this->_ss());
 831 }
 832
 833 sub term {
 834     my $this = shift();
 835     my($which) = @_;
 836
 837     my($occ, $len) = (0, 0);
 838     my $term = Net::Z3950::ZOOM::scanset_term($this->_ss(), $which,
 839                                               $occ, $len)
 840         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 841
 842     die "length of term '$term' differs from returned len=$len"
 843         if length($term) != $len;
 844
 845     return ($term, $occ);
 846 }
 847
 848 sub display_term {
 849     my $this = shift();
 850     my($which) = @_;
 851
 852     my($occ, $len) = (0, 0);
 853     my $term = Net::Z3950::ZOOM::scanset_display_term($this->_ss(), $which,
 854                                                       $occ, $len)
 855         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 856
 857     die "length of display term '$term' differs from returned len=$len"
 858         if length($term) != $len;
 859
 860     return ($term, $occ);
 861 }
 862
 863 sub destroy {
 864     my $this = shift();
 865
 866     Net::Z3950::ZOOM::scanset_destroy($this->_ss());
 867     $this->{_ss} = undef;
 868 }
 869
 870
 871 # ----------------------------------------------------------------------------
 872
 873 package ZOOM::Package;
 874
 875 sub new {
 876     my $class = shift();
 877     die "You can't create $class objects directly";
 878 }
 879
 880 # PRIVATE to ZOOM::Connection::package(),
 881 sub _new {
 882     my $class = shift();
 883     my($conn, $options, $_p) = @_;
 884
 885     return bless {
 886         conn => $conn,
 887         options => $options,
 888         _p => $_p,
 889     }, $class;
 890 }
 891
 892 # PRIVATE to this class
 893 sub _p {
 894     my $this = shift();
 895
 896     my $_p = $this->{_p};
 897     die "{_p} undefined: has this Package been destroy()ed?"
 898         if !defined $_p;
 899
 900     return $_p;
 901 }
 902
 903 sub option {
 904     my $this = shift();
 905     my($key, $value) = @_;
 906
 907     my $oldval = Net::Z3950::ZOOM::package_option_get($this->_p(), $key);
 908     Net::Z3950::ZOOM::package_option_set($this->_p(), $key, $value)
 909         if defined $value;
 910
 911     return $oldval;
 912 }
 913
 914 sub send {
 915     my $this = shift();
 916     my($type) = @_;
 917
 918     Net::Z3950::ZOOM::package_send($this->_p(), $type);
 919     $this->{conn}->_check();
 920 }
 921
 922 sub destroy {
 923     my $this = shift();
 924
 925     Net::Z3950::ZOOM::package_destroy($this->_p());
 926     $this->{_p} = undef;
 927 }
 928
 929
 930 # There follows trivial support for YAZ logging.  This is wired out
 931 # into the Net::Z3950::ZOOM package, and we here provide wrapper
 932 # functions -- nothing more than aliases, really -- in the ZOOM::Log
 933 # package.  There really is no point in inventing an OO interface.
 934 #
 935 # Passing @_ directly to the underlying Net::Z3950::ZOOM::* functions
 936 # doesn't work, for reasons that I can't begin to fathom, and that
 937 # don't particularly interest me.  Unpacking into scalars and passing
 938 # those _does_ work, so that's what we do.
 939
 940 package ZOOM::Log;
 941
 942 sub mask_str      { my($a) = @_; Net::Z3950::ZOOM::yaz_log_mask_str($a); }
 943 sub module_level  { my($a) = @_; Net::Z3950::ZOOM::yaz_log_module_level($a); }
 944 sub init          { my($a, $b, $c) = @_;
 945                     Net::Z3950::ZOOM::yaz_log_init($a, $b, $c) }
 946 sub init_file     { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_file($a) }
 947 sub init_level    { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_level($a) }
 948 sub init_prefix   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_prefix($a) }
 949 sub time_format   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_time_format($a) }
 950 sub init_max_size { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_max_size($a) }
 951
 952 sub log {
 953     my($level, @message) = @_;
 954
 955     if ($level !~ /^(0x)?\d+$/) {
 956         # Assuming its log-level name, we look it up.
 957         my $num = module_level($level);
 958         ZOOM::_oops(ZOOM::Error::LOGLEVEL, $level)
 959             if $num == 0;
 960         $level = $num;
 961     }
 962
 963     Net::Z3950::ZOOM::yaz_log($level, join("", @message));
 964 }
 965
 966
 967 1;