SimpleServer.pm

   1 ##
   2 ##  Copyright (c) 2000-2006, Index Data.
   3 ##
   4 ##  Permission to use, copy, modify, distribute, and sell this software and
   5 ##  its documentation, in whole or in part, for any purpose, is hereby granted,
   6 ##  provided that:
   7 ##
   8 ##  1. This copyright and permission notice appear in all copies of the
   9 ##  software and its documentation. Notices of copyright or attribution
  10 ##  which appear at the beginning of any file must remain unchanged.
  11 ##
  12 ##  2. The name of Index Data or the individual authors may not be used to
  13 ##  endorse or promote products derived from this software without specific
  14 ##  prior written permission.
  15 ##
  16 ##  THIS SOFTWARE IS PROVIDED "AS IS" AND WITHOUT WARRANTY OF ANY KIND,
  17 ##  EXPRESS, IMPLIED, OR OTHERWISE, INCLUDING WITHOUT LIMITATION, ANY
  18 ##  WARRANTY OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.
  19 ##  IN NO EVENT SHALL INDEX DATA BE LIABLE FOR ANY SPECIAL, INCIDENTAL,
  20 ##  INDIRECT OR CONSEQUENTIAL DAMAGES OF ANY KIND, OR ANY DAMAGES
  21 ##  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER OR
  22 ##  NOT ADVISED OF THE POSSIBILITY OF DAMAGE, AND ON ANY THEORY OF
  23 ##  LIABILITY, ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE
  24 ##  OF THIS SOFTWARE.
  25 ##
  26 ##
  27
  28 ## $Id: SimpleServer.pm,v 1.41 2007-08-20 15:34:29 mike Exp $
  29
  30 package Net::Z3950::SimpleServer;
  31
  32 use strict;
  33 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);
  34 use Carp;
  35
  36 require Exporter;
  37 require DynaLoader;
  38 require AutoLoader;
  39
  40 @ISA = qw(Exporter AutoLoader DynaLoader);
  41 @EXPORT = qw( );
  42 $VERSION = '1.07';
  43
  44 bootstrap Net::Z3950::SimpleServer $VERSION;
  45
  46 # Preloaded methods go here.
  47
  48 my $count = 0;
  49
  50 sub new {
  51         my $class = shift;
  52         my %args = @_;
  53         my $self = \%args;
  54
  55         if ($count) {
  56                 carp "SimpleServer.pm: WARNING: Multithreaded server unsupported";
  57         }
  58         $count = 1;
  59
  60         croak "SimpleServer.pm: ERROR: Unspecified search handler" unless defined($self->{SEARCH});
  61         croak "SimpleServer.pm: ERROR: Unspecified fetch handler" unless defined($self->{FETCH});
  62
  63         bless $self, $class;
  64         return $self;
  65 }
  66
  67
  68 sub launch_server {
  69         my $self = shift;
  70         my @args = @_;
  71
  72         ### This modal internal interface, in which we set a bunch of
  73         #   globals and then call start_server(), is asking for
  74         #   trouble.  Instead, we should just pass the $self object
  75         #   as a parameter into start_server().
  76         if (defined($self->{GHANDLE})) {
  77                 set_ghandle($self->{GHANDLE});
  78         }
  79         if (defined($self->{INIT})) {
  80                 set_init_handler($self->{INIT});
  81         }
  82         set_search_handler($self->{SEARCH});
  83         set_fetch_handler($self->{FETCH});
  84         if (defined($self->{CLOSE})) {
  85                 set_close_handler($self->{CLOSE});
  86         }
  87         if (defined($self->{PRESENT})) {
  88                 set_present_handler($self->{PRESENT});
  89         }
  90         if (defined($self->{SCAN})) {
  91                 set_scan_handler($self->{SCAN});
  92         }
  93         if (defined($self->{SORT})) {
  94                 set_sort_handler($self->{SORT});
  95         }
  96         if (defined($self->{EXPLAIN})) {
  97                 set_explain_handler($self->{EXPLAIN});
  98         }
  99         if (defined($self->{DELETE})) {
 100                 set_delete_handler($self->{DELETE});
 101         }
 102
 103         start_server(@args);
 104 }
 105
 106
 107 # Register packages that we will use in translated RPNs
 108 package Net::Z3950::RPN::Node;
 109 package Net::Z3950::APDU::Query;
 110 our @ISA = qw(Net::Z3950::RPN::Node);
 111 package Net::Z3950::APDU::OID;
 112 package Net::Z3950::RPN::And;
 113 our @ISA = qw(Net::Z3950::RPN::Node);
 114 package Net::Z3950::RPN::Or;
 115 our @ISA = qw(Net::Z3950::RPN::Node);
 116 package Net::Z3950::RPN::AndNot;
 117 our @ISA = qw(Net::Z3950::RPN::Node);
 118 package Net::Z3950::RPN::Term;
 119 our @ISA = qw(Net::Z3950::RPN::Node);
 120 package Net::Z3950::RPN::RSID;
 121 our @ISA = qw(Net::Z3950::RPN::Node);
 122 package Net::Z3950::RPN::Attributes;
 123 package Net::Z3950::RPN::Attribute;
 124
 125
 126 # Utility method for re-rendering Type-1 query back down to PQF
 127 package Net::Z3950::RPN::Node;
 128
 129 sub toPQF {
 130     my $this = shift();
 131     my $class = ref $this;
 132
 133     if ($class eq "Net::Z3950::APDU::Query") {
 134         my $res = "";
 135         my $set = $this->{attributeSet};
 136         $res .= "\@attrset $set " if defined $set;
 137         return $res . $this->{query}->toPQF();
 138     } elsif ($class eq "Net::Z3950::RPN::Or") {
 139         return '@or ' . $this->[0]->toPQF() . ' ' . $this->[1]->toPQF();
 140     } elsif ($class eq "Net::Z3950::RPN::And") {
 141         return '@and ' . $this->[0]->toPQF() . ' ' . $this->[1]->toPQF();
 142     } elsif ($class eq "Net::Z3950::RPN::AndNot") {
 143         return '@not ' . $this->[0]->toPQF() . ' ' . $this->[1]->toPQF();
 144     } elsif ($class eq "Net::Z3950::RPN::RSID") {
 145         return '@set ' . $this->{id};
 146     } elsif ($class ne "Net::Z3950::RPN::Term") {
 147         die "unknown PQF node-type '$class'";
 148     }
 149
 150     my $res = "";
 151     foreach my $attr (@{ $this->{attributes} }) {
 152         $res .= "\@attr ";
 153         my $set = $attr->{attributeSet};
 154         $res .= "$set " if defined $set;
 155         $res .= $attr->{attributeType} . "=" . $attr->{attributeValue} . " ";
 156     }
 157
 158     return $res . $this->{term};
 159 }
 160
 161
 162 # Must revert to original package for Autoloader's benefit
 163 package Net::Z3950::SimpleServer;
 164
 165
 166 # Autoload methods go after =cut, and are processed by the autosplit program.
 167
 168 1;
 169 __END__
 170 # Below is the stub of documentation for your module. You better edit it!
 171
 172 =head1 NAME
 173
 174 Net::Z3950::SimpleServer - Simple Perl API for building Z39.50 servers.
 175
 176 =head1 SYNOPSIS
 177
 178   use Net::Z3950::SimpleServer;
 179
 180   sub my_search_handler {
 181         my $args = shift;
 182
 183         my $set_id = $args->{SETNAME};
 184         my @database_list = @{ $args->{DATABASES} };
 185         my $query = $args->{QUERY};
 186
 187         ## Perform the query on the specified set of databases
 188         ## and return the number of hits:
 189
 190         $args->{HITS} = $hits;
 191   }
 192
 193   sub my_fetch_handler {        # Get a record for the user
 194         my $args = shift;
 195
 196         my $set_id = $args->{SETNAME};
 197
 198         my $record = fetch_a_record($args->{OFFSET});
 199
 200         $args->{RECORD} = $record;
 201         if (number_of_hits() == $args->{OFFSET}) {      ## Last record in set?
 202                 $args->{LAST} = 1;
 203         } else {
 204                 $args->{LAST} = 0;
 205         }
 206   }
 207
 208   ## Register custom event handlers:
 209   my $z = new Net::Z3950::SimpleServer(GHANDLE = $someObject,
 210                                        INIT   =>  \&my_init_handler,
 211                                        CLOSE  =>  \&my_close_handler,
 212                                        SEARCH =>  \&my_search_handler,
 213                                        FETCH  =>  \&my_fetch_handler);
 214
 215   ## Launch server:
 216   $z->launch_server("ztest.pl", @ARGV);
 217
 218 =head1 DESCRIPTION
 219
 220 The SimpleServer module is a tool for constructing Z39.50 "Information
 221 Retrieval" servers in Perl. The module is easy to use, but it
 222 does help to have an understanding of the Z39.50 query
 223 structure and the construction of structured retrieval records.
 224
 225 Z39.50 is a network protocol for searching remote databases and
 226 retrieving the results in the form of structured "records". It is widely
 227 used in libraries around the world, as well as in the US Federal Government.
 228 In addition, it is generally useful whenever you wish to integrate a number
 229 of different database systems around a shared, asbtract data model.
 230
 231 The model of the module is simple: It implements a "generic" Z39.50
 232 server, which invokes callback functions supplied by you to search
 233 for content in your database. You can use any tools available in
 234 Perl to supply the content, including modules like DBI and
 235 WWW::Search.
 236
 237 The server will take care of managing the network connections for
 238 you, and it will spawn a new process (or thread, in some
 239 environments) whenever a new connection is received.
 240
 241 The programmer can specify subroutines to take care of the following type
 242 of events:
 243
 244   - Initialize request
 245   - Search request
 246   - Present request
 247   - Fetching of records
 248   - Scan request (browsing)
 249   - Closing down connection
 250
 251 Note that only the Search and Fetch handler functions are required.
 252 The module can supply default responses to the other on its own.
 253
 254 After the launching of the server, all control is given away from
 255 the Perl script to the server. The server calls the registered
 256 subroutines to field incoming requests from Z39.50 clients.
 257
 258 A reference to an anonymous hash is passed to each handler. Some of
 259 the entries of these hashes are to be considered input and others
 260 output parameters.
 261
 262 The Perl programmer specifies the event handlers for the server by
 263 means of the SimpleServer object constructor
 264
 265   my $z = new Net::Z3950::SimpleServer(
 266                         INIT    =>      \&my_init_handler,
 267                         CLOSE   =>      \&my_close_handler,
 268                         SEARCH  =>      \&my_search_handler,
 269                         PRESENT =>      \&my_present_handler,
 270                         SCAN    =>      \&my_scan_handler,
 271                         FETCH   =>      \&my_fetch_handler,
 272                         EXPLAIN =>      \&my_explain_handler,
 273                         DELETE =>       \&my_delete_handler);
 274
 275 In addition, the arguments to the constructor may include GHANDLE, a
 276 global handle which is made available to each invocation of every
 277 callback function.  This is typically a reference to either a hash or
 278 an object.
 279
 280 If you want your SimpleServer to start a thread (threaded mode) to
 281 handle each incoming Z39.50 request instead of forking a process
 282 (forking mode), you need to register the handlers by symbol rather
 283 than by code reference. Thus, in threaded mode, you will need to
 284 register your handlers this way:
 285
 286   my $z = new Net::Z3950::SimpleServer(
 287                         INIT    =>      "my_package::my_init_handler",
 288                         CLOSE   =>      "my_package::my_close_handler",
 289                         ....
 290                         ....          );
 291
 292 where my_package is the Perl package in which your handler is
 293 located.
 294
 295 After the custom event handlers are declared, the server is launched
 296 by means of the method
 297
 298   $z->launch_server("MyServer.pl", @ARGV);
 299
 300 Notice, the first argument should be the name of your server
 301 script (for logging purposes), while the rest of the arguments
 302 are documented in the YAZ toolkit manual: The section on
 303 application invocation: <http://www.indexdata.dk/yaz/yaz-7.php>
 304
 305 In particular, you need to use the -T switch to start your SimpleServer
 306 in threaded mode.
 307
 308 =head2 Init handler
 309
 310 The init handler is called whenever a Z39.50 client is attempting
 311 to logon to the server. The exchange of parameters between the
 312 server and the handler is carried out via an anonymous hash reached
 313 by a reference, i.e.
 314
 315   $args = shift;
 316
 317 The argument hash passed to the init handler has the form
 318
 319   $args = {
 320                                     ## Response parameters:
 321
 322              IMP_ID    =>  "",      ## Z39.50 Implementation ID
 323              IMP_NAME  =>  "",      ## Z39.50 Implementation name
 324              IMP_VER   =>  "",      ## Z39.50 Implementation version
 325              ERR_CODE  =>  0,       ## Error code, cnf. Z39.50 manual
 326              ERR_STR   =>  "",      ## Error string (additional info.)
 327              USER      =>  "xxx"    ## If Z39.50 authentication is used,
 328                                     ## this member contains user name
 329              PASS      =>  "yyy"    ## Under same conditions, this member
 330                                     ## contains the password in clear text
 331              GHANDLE   =>  $obj     ## Global handler specified at creation
 332              HANDLE    =>  undef    ## Handler of Perl data structure
 333           };
 334
 335 The HANDLE member can be used to store any scalar value which will then
 336 be provided as input to all subsequent calls (ie. for searching, record
 337 retrieval, etc.). A common use of the handle is to store a reference to
 338 a hash which may then be used to store session-specific parameters.
 339 If you have any session-specific information (such as a list of
 340 result sets or a handle to a back-end search engine of some sort),
 341 it is always best to store them in a private session structure -
 342 rather than leaving them in global variables in your script.
 343
 344 The Implementation ID, name and version are only really used by Z39.50
 345 client developers to see what kind of server they're dealing with.
 346 Filling these in is optional.
 347
 348 The ERR_CODE should be left at 0 (the default value) if you wish to
 349 accept the connection. Any other value is interpreted as a failure
 350 and the client will be shown the door, with the code and the
 351 associated additional information, ERR_STR returned.
 352
 353 =head2 Search handler
 354
 355 Similarly, the search handler is called with a reference to an anony-
 356 mous hash. The structure is the following:
 357
 358   $args = {
 359                                     ## Request parameters:
 360
 361              GHANDLE   =>  $obj     ## Global handler specified at creation
 362              HANDLE    =>  ref,     ## Your session reference.
 363              SETNAME   =>  "id",    ## ID of the result set
 364              REPL_SET  =>  0,       ## Replace set if already existing?
 365              DATABASES =>  ["xxx"], ## Reference to a list of data-
 366                                     ## bases to search
 367              QUERY     =>  "query", ## The query expression
 368              RPN       =>  $obj,    ## Reference to a Net::Z3950::APDU::Query
 369
 370                                     ## Response parameters:
 371
 372              ERR_CODE  =>  0,       ## Error code (0=Succesful search)
 373              ERR_STR   =>  "",      ## Error string
 374              HITS      =>  0        ## Number of matches
 375           };
 376
 377 Note that a search which finds 0 hits is considered successful in
 378 Z39.50 terms - you should only set the ERR_CODE to a non-zero value
 379 if there was a problem processing the request. The Z39.50 standard
 380 provides a comprehensive list of standard diagnostic codes, and you
 381 should use these whenever possible.
 382
 383 The QUERY is a tree-structure of terms combined by operators, the
 384 terms being qualified by lists of attributes. The query is presented
 385 to the search function in the Prefix Query Format (PQF) which is
 386 used in many applications based on the YAZ toolkit. The full grammar
 387 is described in the YAZ manual.
 388
 389 The following are all examples of valid queries in the PQF.
 390
 391         dylan
 392
 393         "bob dylan"
 394
 395         @or "dylan" "zimmerman"
 396
 397         @set Result-1
 398
 399         @or @and bob dylan @set Result-1
 400
 401         @and @attr 1=1 "bob dylan" @attr 1=4 "slow train coming"
 402
 403         @attrset @attr 4=1 @attr 1=4 "self portrait"
 404
 405 You will need to write a recursive function or something similar to
 406 parse incoming query expressions, and this is usually where a lot of
 407 the work in writing a database-backend happens. Fortunately, you don't
 408 need to support anymore functionality than you want to. For instance,
 409 it is perfectly legal to not accept boolean operators, but you SHOULD
 410 try to return good error codes if you run into something you can't or
 411 won't support.
 412
 413 A more convenient alternative to the QUERY member may be the RPN
 414 member, which is a reference to a Net::Z3950::APDU::Query object
 415 representing the RPN query tree.  The structure of that object is
 416 supposed to be self-documenting, but here's a brief summary of what
 417 you get:
 418
 419 =over 4
 420
 421 =item *
 422
 423 C<Net::Z3950::APDU::Query> is a hash with two fields:
 424
 425 Z<>
 426
 427 =over 4
 428
 429 =item C<attributeSet>
 430
 431 Optional.  If present, it is a reference to a
 432 C<Net::Z3950::APDU::OID>.  This is a string of dot-separated integers
 433 representing the OID of the query's top-level attribute set.
 434
 435 =item C<query>
 436
 437 Mandatory: a refererence to the RPN tree itself.
 438
 439 =back
 440
 441 =item *
 442
 443 Each node of the tree is an object of one of the following types:
 444
 445 Z<>
 446
 447 =over 4
 448
 449 =item C<Net::Z3950::RPN::And>
 450
 451 =item C<Net::Z3950::RPN::Or>
 452
 453 =item C<Net::Z3950::RPN::AndNot>
 454
 455 These three classes are all arrays of two elements, each of which is a
 456 node of one of the above types.
 457
 458 =item C<Net::Z3950::RPN::Term>
 459
 460 See below for details.
 461
 462 =item C<Net::Z3950::RPN::RSID>
 463
 464 A reference to a result-set ID indicating a previous search.  The ID
 465 of the result-set is in the C<id> element.
 466
 467 =back
 468
 469 =back
 470
 471 =over 4
 472
 473 =item *
 474
 475 C<Net::Z3950::RPN::Term> is a hash with two fields:
 476
 477 Z<>
 478
 479 =over 4
 480
 481 =item C<term>
 482
 483 A string containing the search term itself.
 484
 485 =item C<attributes>
 486
 487 A reference to a C<Net::Z3950::RPN::Attributes> object.
 488
 489 =back
 490
 491 =item *
 492
 493 C<Net::Z3950::RPN::Attributes> is an array of references to
 494 C<Net::Z3950::RPN::Attribute> objects.  (Note the plural/singular
 495 distinction.)
 496
 497 =item *
 498
 499 C<Net::Z3950::RPN::Attribute> is a hash with three elements:
 500
 501 Z<>
 502
 503 =over 4
 504
 505 =item C<attributeSet>
 506
 507 Optional.  If present, it is dot-separated OID string, as above.
 508
 509 =item C<attributeType>
 510
 511 An integer indicating the type of the attribute - for example, under
 512 the BIB-1 attribute set, type 1 indicates a ``use'' attribute, type 2
 513 a ``relation'' attribute, etc.
 514
 515 =item C<attributeValue>
 516
 517 An integer or string indicating the value of the attribute - for example, under
 518 BIB-1, if the attribute type is 1, then value 4 indictates a title
 519 search and 7 indictates an ISBN search; but if the attribute type is
 520 2, then value 4 indicates a ``greater than or equal'' search, and 102
 521 indicates a relevance match.
 522
 523 =back
 524
 525 =back
 526
 527 All of these classes except C<Attributes> and C<Attribute> are
 528 subclasses of the abstract class C<Net::Z3950::RPN::Node>.  That class
 529 has a single method, C<toPQF()>, which may be used to turn an RPN
 530 tree, or part of one, back into a textual prefix query.
 531
 532 Note that, apart to C<toPQF()>, none of these classes have any methods at
 533 all: the blessing into classes is largely just a documentation thing
 534 so that, for example, if you do
 535
 536         { use Data::Dumper; print Dumper($args->{RPN}) }
 537
 538 you get something fairly human-readable.  But of course, the type
 539 distinction between the three different kinds of boolean node is
 540 important.
 541
 542 By adding your own methods to these classes (building what I call
 543 ``augmented classes''), you can easily build code that walks the tree
 544 of the incoming RPN.  Take a look at C<samples/render-search.pl> for a
 545 sample implementation of such an augmented classes technique.
 546
 547
 548 =head2 Present handler
 549
 550 The presence of a present handler in a SimpleServer front-end is optional.
 551 Each time a client wishes to retrieve records, the present service is
 552 called. The present service allows the origin to request a certain number
 553 of records retrieved from a given result set.
 554 When the present handler is called, the front-end server should prepare a
 555 result set for fetching. In practice, this means to get access to the
 556 data from the backend database and store the data in a temporary fashion
 557 for fast and efficient fetching. The present handler does *not* fetch
 558 anything. This task is taken care of by the fetch handler, which will be
 559 called the correct number of times by the YAZ library. More about this
 560 below.
 561 If no present handler is implemented in the front-end, the YAZ toolkit
 562 will take care of a minimum of preparations itself. This default present
 563 handler is sufficient in many situations, where only a small amount of
 564 records are expected to be retrieved. If on the other hand, large result
 565 sets are likely to occur, the implementation of a reasonable present
 566 handler can gain performance significantly.
 567
 568 The informations exchanged between client and present handle are:
 569
 570   $args = {
 571                                     ## Client/server request:
 572
 573              GHANDLE   =>  $obj     ## Global handler specified at creation
 574              HANDLE    =>  ref,     ## Reference to datastructure
 575              SETNAME   =>  "id",    ## Result set ID
 576              START     =>  xxx,     ## Start position
 577              COMP      =>  "",      ## Desired record composition
 578              NUMBER    =>  yyy,     ## Number of requested records
 579
 580
 581                                     ## Respons parameters:
 582
 583              HITS      =>  zzz,     ## Number of returned records
 584              ERR_CODE  =>  0,       ## Error code
 585              ERR_STR   =>  ""       ## Error message
 586           };
 587
 588
 589 =head2 Fetch handler
 590
 591 The fetch handler is asked to retrieve a SINGLE record from a given
 592 result set (the front-end server will automatically call the fetch
 593 handler as many times as required).
 594
 595 The parameters exchanged between the server and the fetch handler are
 596
 597   $args = {
 598                                     ## Client/server request:
 599
 600              GHANDLE   =>  $obj     ## Global handler specified at creation
 601              HANDLE    =>  ref      ## Reference to data structure
 602              SETNAME   =>  "id"     ## ID of the requested result set
 603              OFFSET    =>  nnn      ## Record offset number
 604              REQ_FORM  =>  "n.m.k.l"## Client requested format OID
 605              COMP      =>  "xyz"    ## Formatting instructions
 606              SCHEMA    =>  "abc"    ## Requested schema, if any
 607
 608                                     ## Handler response:
 609
 610              RECORD    =>  ""       ## Record string
 611              BASENAME  =>  ""       ## Origin of returned record
 612              LAST      =>  0        ## Last record in set?
 613              ERR_CODE  =>  0        ## Error code
 614              ERR_STR   =>  ""       ## Error string
 615              SUR_FLAG  =>  0        ## Surrogate diagnostic flag
 616              REP_FORM  =>  "n.m.k.l"## Provided format OID
 617              SCHEMA    =>  "abc"    ## Provided schema, if any
 618           };
 619
 620 The REP_FORM value has by default the REQ_FORM value but can be set to
 621 something different if the handler desires. The BASENAME value should
 622 contain the name of the database from where the returned record originates.
 623 The ERR_CODE and ERR_STR works the same way they do in the search
 624 handler. If there is an error condition, the SUR_FLAG is used to
 625 indicate whether the error condition pertains to the record currently
 626 being retrieved, or whether it pertains to the operation as a whole
 627 (eg. the client has specified a result set which does not exist.)
 628
 629 If you need to return USMARC records, you might want to have a look at
 630 the MARC module on CPAN, if you don't already have a way of generating
 631 these.
 632
 633 NOTE: The record offset is 1-indexed - 1 is the offset of the first
 634 record in the set.
 635
 636 =head2 Scan handler
 637
 638 A full featured Z39.50 server should support scan (or in some literature
 639 browse). The client specifies a starting term of the scan, and the server
 640 should return an ordered list of specified length consisting of terms
 641 actually occurring in the data base. Each of these terms should be close
 642 to or equal to the term originally specified. The quality of scan compared
 643 to simple search is a guarantee of hits. It is simply like browsing through
 644 an index of a book, you always find something! The parameters exchanged are
 645
 646   $args = {
 647                                                 ## Client request
 648
 649                 GHANDLE         => $obj,        ## Global handler specified at creation
 650                 HANDLE          => $ref,        ## Reference to data structure
 651                 DATABASES       => ["xxx"],     ## Reference to a list of data-
 652                                                 ## bases to search
 653                 TERM            => 'start',     ## The start term
 654                 RPN             =>  $obj,       ## Reference to a Net::Z3950::RPN::Term
 655
 656                 NUMBER          => xx,          ## Number of requested terms
 657                 POS             => yy,          ## Position of starting point
 658                                                 ## within returned list
 659                 STEP            => 0,           ## Step size
 660
 661                                                 ## Server response
 662
 663                 ERR_CODE        => 0,           ## Error code
 664                 ERR_STR         => '',          ## Diagnostic message
 665                 NUMBER          => zz,          ## Number of returned terms
 666                 STATUS          => $status,     ## ScanSuccess/ScanFailure
 667                 ENTRIES         => $entries     ## Referenced list of terms
 668         };
 669
 670 where the term list is returned by reference in the scalar $entries, which
 671 should point at a data structure of this kind,
 672
 673   my $entries = [
 674                         {       TERM            => 'energy',
 675                                 OCCURRENCE      => 5            },
 676
 677                         {       TERM            => 'energy density',
 678                                 OCCURRENCE      => 6,           },
 679
 680                         {       TERM            => 'energy flow',
 681                                 OCCURRENCE      => 3            },
 682
 683                                 ...
 684
 685                                 ...
 686         ];
 687
 688 The $status flag is only meaningful after a successful scan, and
 689 should be assigned one of two values:
 690
 691   Net::Z3950::SimpleServer::ScanSuccess  Full success (default)
 692   Net::Z3950::SimpleServer::ScanPartial  Fewer terms returned than requested
 693
 694 The STEP member contains the requested number of entries in the term-list
 695 between two adjacent entries in the response.
 696
 697 A better alternative to the TERM member is the the RPN
 698 member, which is a reference to a Net::Z3950::RPN::Term object
 699 representing the scan cloause.  The structure of that object is the
 700 same as for Term objects included as part of the RPN tree passed to
 701 search handlers.  This is more useful than the simple TERM because it
 702 includes attributes (e.g. access points associated with the term),
 703 which are discarded by the TERM element.
 704
 705 =head2 Close handler
 706
 707 The argument hash recieved by the close handler has two elements only:
 708
 709   $args = {
 710                                     ## Server provides:
 711
 712              GHANDLE   =>  $obj     ## Global handler specified at creation
 713              HANDLE    =>  ref      ## Reference to data structure
 714           };
 715
 716 What ever data structure the HANDLE value points at goes out of scope
 717 after this call. If you need to close down a connection to your server
 718 or something similar, this is the place to do it.
 719
 720 =head2 Delete handler
 721
 722 The argument hash recieved by the delete handler has the following elements:
 723
 724   $args = {
 725                                     ## Client request:
 726              GHANDLE   =>  $obj,    ## Global handler specified at creation
 727              HANDLE    =>  ref,     ## Reference to data structure
 728              SETNAME   =>  "id",    ## Result set ID
 729
 730                                     ## Server response:
 731              STATUS    => 0         ## Deletion status
 732           };
 733
 734 The SETNAME element of the argument hash may or may not be defined.
 735 If it is, then SETNAME is the name of a result set to be deleted; if
 736 not, then all result-sets associated with the current session should
 737 be deleted.  In either case, the callback function should report on
 738 success or failure by setting the STATUS element either to zero, on
 739 success, or to an integer from 1 to 10, to indicate one of the ten
 740 possible failure codes described in section 3.2.4.1.4 of the Z39.50
 741 standard -- see
 742 http://www.loc.gov/z3950/agency/markup/05.html#Delete-list-statuses1
 743
 744 =head2 Support for SRU and SRW
 745
 746 Since release 1.0, SimpleServer includes support for serving the SRU
 747 and SRW protocols as well as Z39.50.  These ``web-friendly'' protocols
 748 enable similar functionality to that of Z39.50, but by means of rich
 749 URLs in the case of SRU, and a SOAP-based web-service in the case of
 750 SRW.  These protocols are described at
 751 http://www.loc.gov/sru
 752
 753 In order to serve these protocols from a SimpleServer-based
 754 application, it is necessary to launch the application with a YAZ
 755 Generic Frontend Server (GFS) configuration file, which can be
 756 specified using the command-line argument C<-f> I<filename>.  A
 757 minimal configuration file looks like this:
 758
 759   <yazgfs>
 760     <server>
 761       <cql2rpn>pqf.properties</cql2rpn>
 762     </server>
 763   </yazgfs>
 764
 765 This file specifies only that C<pqf.properties> should be used to
 766 translate the CQL queries of SRU and SRW into corresponding Z39.50
 767 Type-1 queries.  For more information about YAZ GFS configuration,
 768 including how to specify an Explain record, see the I<Virtual Hosts>
 769 section of the YAZ manual at
 770 http://indexdata.com/yaz/doc/server.vhosts.tkl
 771
 772 The mapping of CQL queries into Z39.50 Type-1 queries is specified by
 773 a file that indicates which BIB-1 attributes should be generated for
 774 each CQL index, relation, modifiers, etc.  A typical section of this
 775 file looks like this:
 776
 777   index.dc.title                        = 1=4
 778   index.dc.subject                      = 1=21
 779   index.dc.creator                      = 1=1003
 780   relation.<                            = 2=1
 781   relation.le                           = 2=2
 782
 783 This file specifies the BIB-1 access points (type=1) for the Dublin
 784 Core indexes C<title>, C<subject> and C<creator>, and the BIB-1
 785 relations (type=2) corresponding to the CQL relations C<E<lt>> and
 786 C<E<lt>=>.  For more information about the format of this file, see
 787 the I<CQL> section of the YAZ manual at
 788 http://indexdata.com/yaz/doc/tools.tkl#tools.cql
 789
 790 The YAZ distribution include a sample CQL-to-PQF mapping configuration
 791 file called C<pqf.properties>; this is sufficient for many
 792 applications, and a good base to work from for most others.
 793
 794 If a SimpleServer-based application is run without this SRU-specific
 795 configuration, it can still serve SRU; however, CQL queries will not
 796 be translated, but passed straight through to the search-handler
 797 function, as the C<CQL> member of the parameters hash.  It is then the
 798 responsibility of the back-end application to parse and handle the CQL
 799 query, which is most easily done using Ed Summers' fine C<CQL::Parser>
 800 module, available from CPAN at
 801 http://search.cpan.org/~esummers/CQL-Parser/
 802
 803 =head1 AUTHORS
 804
 805 Anders Sønderberg (sondberg@indexdata.dk),
 806 Sebastian Hammer (quinn@indexdata.dk),
 807 Mike Taylor (indexdata.com).
 808
 809 =head1 SEE ALSO
 810
 811 Any Perl module which is useful for accessing the database of your
 812 choice.
 813
 814 =cut