web/htdocs/details/full.mc

   1 %# $Id: full.mc,v 1.25 2007-04-18 12:06:25 mike Exp $
   2 <%args>
   3 $id
   4 </%args>
   5 <%perl>
   6 my $conn = new ZOOM::Connection("localhost:8018/IR-Explain---1");
   7 $conn->option(elementSetName => "zeerex");
   8 my $qid = $id;
   9 $qid =~ s/"/\\"/g;
  10 my $query = qq[rec.id="$qid"];
  11 my $rs = $conn->search(new ZOOM::Query::CQL($query));
  12 my $n = $rs->size();
  13 if ($n == 0) {
  14     $m->comp("/details/error.mc",
  15              title => "Error", message => "No such ID '$id'");
  16 } else {
  17     my $xc = irspy_xpath_context($rs->record(0));
  18     my @fields = (
  19                   [ Name => "e:databaseInfo/e:title",
  20                     lang => "en", primary => "true" ],
  21                   [ Country => "i:status/i:country" ],
  22                   [ "Last Checked" => "i:status/i:probe[last()]" ],
  23                   [ Protocol => "e:serverInfo/\@protocol" ],
  24                   [ Host => "e:serverInfo/e:host" ],
  25                   [ Port => "e:serverInfo/e:port" ],
  26                   [ "Database Name" => "e:serverInfo/e:database" ],
  27                   [ "Type of Library" => "i:status/i:libraryType" ],
  28 #                 [ "Username (if needed)" => "e:serverInfo/e:authentication/e:user" ],
  29 #                 [ "Password (if needed)" => "e:serverInfo/e:authentication/e:password" ],
  30                   [ "Server ID" => 'i:status/i:serverImplementationId/@value' ],
  31                   [ "Server Name" => 'i:status/i:serverImplementationName/@value' ],
  32                   [ "Server Version" => 'i:status/i:serverImplementationVersion/@value' ],
  33                   [ Description => "e:databaseInfo/e:description",
  34                     lang => "en", primary => "true" ],
  35                   [ Author => "e:databaseInfo/e:author" ],
  36                   [ Contact => "e:databaseInfo/e:contact" ],
  37                   [ "URL to Hosting Organisation" => "i:status/i:hostURL" ],
  38                   [ Extent => "e:databaseInfo/e:extent" ],
  39                   [ History => "e:databaseInfo/e:history" ],
  40                   [ "Language of Records" => "e:databaseInfo/e:langUsage" ],
  41                   [ Restrictions => "e:databaseInfo/e:restrictions" ],
  42                   [ Subjects => "e:databaseInfo/e:subjects" ],
  43                   [ "Implementation ID" => "i:status/i:implementationId" ],
  44                   [ "Implementation Name" => "i:status/i:implementationName" ],
  45                   [ "Implementation Version" => "i:status/i:implementationVersion" ],
  46                   [ "Reliability" => \&calc_reliability, $xc ],
  47                   [ "Services" => \&calc_init_options, $xc ],
  48                   [ "Bib-1 Use attributes" => \&calc_ap, $xc, "bib-1" ],
  49                   [ "Dan-1 Use attributes" => \&calc_ap, $xc, "dan-1" ],
  50                   [ "Operators" => \&calc_boolean, $xc ],
  51                   [ "Named Result Sets" => \&calc_nrs, $xc ],
  52                   [ "Record syntaxes" => \&calc_recsyn, $xc ],
  53                   [ "Explain" => \&calc_explain, $xc ],
  54                   );
  55     my $title = $xc->find("e:databaseInfo/e:title");
  56 </%perl>
  57      <h2><% xml_encode($title, "") %></h2>
  58      <table class="fullrecord" border="1" cellspacing="0" cellpadding="5" width="100%">
  59 <%perl>
  60     foreach my $ref (@fields) {
  61         my($caption, $xpath, @args) = @$ref;
  62         my $data;
  63         if (ref $xpath && ref($xpath) eq "CODE") {
  64             $data = &$xpath(@args);
  65         } else {
  66             $data = $xc->find($xpath);
  67         }
  68         if ($data) {
  69 </%perl>
  70       <tr>
  71        <th><% xml_encode($caption) %></th>
  72        <td><% xml_encode($data) %></td>
  73       </tr>
  74 %       }
  75 %   }
  76      </table>
  77      <p>
  78       <a href="<% xml_encode("http://targettest.indexdata.com/targettest/search/index.zap?" .
  79         join("&",
  80              "target=" . uri_escape_utf8($id),
  81              "name=" . uri_escape_utf8($title),
  82              "attr=" . join(" ", list_ap($xc, "bib-1")),
  83              "formats=" . calc_recsyn($xc, " ")))
  84         %>">Search this target.</a>
  85      </p>
  86 % }
  87 <%perl>
  88
  89 sub calc_reliability {
  90     my($xc) = @_;
  91
  92     my @allpings = $xc->findnodes("i:status/i:probe");
  93     my $nall = @allpings;
  94     return "[untested]" if $nall == 0;
  95     my @okpings = $xc->findnodes('i:status/i:probe[@ok = "1"]');
  96     my $nok = @okpings;
  97     return "$nok/$nall = " . int(100*$nok/$nall) . "%";
  98 }
  99
 100 sub calc_init_options {
 101     my($xc) = @_;
 102
 103     my @ops;
 104     my @nodes = $xc->findnodes('e:configInfo/e:supports/@type');
 105     foreach my $node (@nodes) {
 106         my $type = $node->value();
 107         if ($type =~ s/^z3950_//) {
 108             push @ops, $type;
 109         }
 110     }
 111
 112     return join(", ", @ops);
 113 }
 114
 115 sub calc_ap {
 116     my($xc, $set) = @_;
 117
 118     my @aps = list_ap($xc, $set);
 119     my $n = @aps;
 120     return "[none]" if $n == 0;
 121
 122     my $res = "";
 123     my($first, $last);
 124     foreach my $ap (@aps) {
 125         if (!defined $first) {
 126             $first = $last = $ap;
 127         } elsif ($ap == $last+1) {
 128             $last++;
 129         } else {
 130             # Got a complete range
 131             $res .= ", " if $res ne "";
 132             $res .= "$first";
 133             $res .= "-$last" if $last > $first;
 134             $first = $last = $ap;
 135         }
 136     }
 137
 138     # Leftovers
 139     if (defined $first) {
 140         $res .= ", " if $res ne "";
 141         $res .= "$first";
 142         $res .= "-$last" if $last > $first;
 143     }
 144
 145     return "$n access points: $res";
 146 }
 147
 148 sub list_ap {
 149     my($xc, $set) = @_;
 150
 151     my $expr = 'e:indexInfo/e:index[@search = "true"]/e:map/e:attr[
 152         @set = "'.$set.'" and @type = "1"]';
 153     my @nodes = $xc->findnodes($expr);
 154     return sort { $a <=> $b } map { $_->findvalue(".") } @nodes;
 155 }
 156
 157 sub calc_boolean {
 158     my($xc) = @_;
 159
 160     ### Note that we are currently interrogating an IRSpy extension.
 161     #   The standard ZeeRex record should be extended with a
 162     #   "supports" type for this.
 163     my @nodes = $xc->findnodes('i:status/i:boolean[@ok = "1"]');
 164     my $res = join(", ", map { $_->findvalue('@operator') } @nodes);
 165     $res = "[none]" if $res eq "";
 166     return $res;
 167 }
 168
 169 sub calc_nrs {
 170     my($xc) = @_;
 171
 172     my @nodes = $xc->findnodes('i:status/i:named_resultset[@ok = "1"]');
 173     return @nodes ? "Yes" : "No";
 174 }
 175
 176 sub calc_recsyn {
 177     my($xc, $sep) = @_;
 178     $sep = ", " if !defined $sep;
 179
 180     my @nodes = $xc->findnodes('e:recordInfo/e:recordSyntax');
 181     my $res = join($sep, map { $_->findvalue('@name') } @nodes);
 182     $res = "[none]" if $res eq "";
 183     return $res;
 184 }
 185
 186 sub calc_explain {
 187     my($xc) = @_;
 188
 189     my @nodes = $xc->findnodes('i:status/i:explain[@ok = "1"]');
 190     my $res = join(", ", map { $_->findvalue('@category') } @nodes);
 191     $res = "[none]" if $res eq "";
 192     return $res;
 193 }
 194 </%perl>