web/htdocs/details/full.mc

   1 <%args>
   2 $id
   3 </%args>
   4 <%perl>
   5 my $db = ZOOM::IRSpy::connect_to_registry();
   6 my $conn = new ZOOM::Connection($db);
   7 $conn->option(elementSetName => "zeerex");
   8 my $query = cql_target($id);
   9 my $rs = $conn->search(new ZOOM::Query::CQL($query));
  10 my $n = $rs->size();
  11 if ($n == 0) {
  12     $m->comp("/details/error.mc",
  13              title => "Error", message => "No such ID '$id'");
  14 } else {
  15     my $xc = irspy_xpath_context($rs->record(0));
  16     my @fields = (
  17                   [ Name => "e:databaseInfo/e:title",
  18                     lang => "en", primary => "true" ],
  19                   [ Country => "i:status/i:country" ],
  20                   [ "Last Checked" => "i:status/i:probe[last()]" ],
  21                   [ Protocol => "e:serverInfo/\@protocol" ],
  22                   [ Host => "e:serverInfo/e:host" ],
  23                   [ Port => "e:serverInfo/e:port" ],
  24                   [ "Database Name" => "e:serverInfo/e:database" ],
  25                   [ "Type of Library" => "i:status/i:libraryType" ],
  26 #                 [ "Username (if needed)" => "e:serverInfo/e:authentication/e:user" ],
  27 #                 [ "Password (if needed)" => "e:serverInfo/e:authentication/e:password" ],
  28                   [ "Server ID" => 'i:status/i:serverImplementationId/@value' ],
  29                   [ "Server Name" => 'i:status/i:serverImplementationName/@value' ],
  30                   [ "Server Version" => 'i:status/i:serverImplementationVersion/@value' ],
  31                   [ Description => "e:databaseInfo/e:description",
  32                     lang => "en", primary => "true" ],
  33                   [ Author => "e:databaseInfo/e:author" ],
  34                   [ Contact => "e:databaseInfo/e:contact" ],
  35                   [ "URL to Hosting Organisation" => "i:status/i:hostURL" ],
  36                   [ Extent => "e:databaseInfo/e:extent" ],
  37                   [ History => "e:databaseInfo/e:history" ],
  38                   [ "Language of Records" => "e:databaseInfo/e:langUsage" ],
  39                   [ Restrictions => "e:databaseInfo/e:restrictions" ],
  40                   [ Subjects => "e:databaseInfo/e:subjects" ],
  41                   [ "Implementation ID" => "i:status/i:implementationId" ],
  42                   [ "Implementation Name" => "i:status/i:implementationName" ],
  43                   [ "Implementation Version" => "i:status/i:implementationVersion" ],
  44                   [ "Reliability/reliability" => \&calc_reliability_wrapper, $xc ],
  45                   [ "Services" => \&calc_init_options, $xc ],
  46                   [ "Bib-1 Use attributes" => \&calc_ap, $xc, "bib-1" ],
  47                   [ "Dan-1 Use attributes" => \&calc_ap, $xc, "dan-1" ],
  48                   [ "Operators" => \&calc_boolean, $xc ],
  49                   [ "Named Result Sets" => \&calc_nrs, $xc ],
  50                   [ "Record syntaxes" => \&calc_recsyn, $xc ],
  51                   [ "Explain" => \&calc_explain, $xc ],
  52                   );
  53     my $title = $xc->find("e:databaseInfo/e:title");
  54 </%perl>
  55      <h2><% xml_encode($title, "") %></h2>
  56      <table class="fullrecord" border="1" cellspacing="0" cellpadding="5" width="100%">
  57 <%perl>
  58     foreach my $ref (@fields) {
  59         my($caption, $xpath, @args) = @$ref;
  60         my($data, $linkURL);
  61         if (ref $xpath && ref($xpath) eq "CODE") {
  62             ($data, $linkURL) = &$xpath($id, @args);
  63         } else {
  64             $data = $xc->find($xpath);
  65         }
  66         if ($data) {
  67             print "      <tr>\n";
  68             $caption =~ s/\/(.*)//;
  69             my $help = $1;
  70             my($linkstart, $linkend) = ("", "");
  71             if (defined $linkURL) {
  72                 $linkstart = '<a href="' . xml_encode($linkURL) . '">';
  73                 $linkend = "</a>";
  74             }
  75 </%perl>
  76        <th><% xml_encode($caption) %><%
  77         !defined $help ? "" : $m->comp("/help/link.mc", help =>"info/$help")
  78         %></th>
  79        <td><% $linkstart . xml_encode($data) . $linkend %></td>
  80       </tr>
  81 %       }
  82 %   }
  83      </table>
  84      <p>
  85 % my $target = irspy_identifier2target($id);
  86 % $target =~ s/^tcp://; # Apparently ZAP can't handle the leading "tcp:"
  87       <a href="<% xml_encode("http://targettest.indexdata.com/targettest/search/index.zap?" .
  88         join("&",
  89              "target=" . uri_escape_utf8($target),
  90              "name=" . uri_escape_utf8($title),
  91              "attr=" . join(" ", _list_ap($xc, "bib-1")),
  92              "formats=" . calc_recsyn($id, $xc, " ")))
  93         %>">Search this target.</a>
  94      </p>
  95 % }
  96 <%perl>
  97
  98 sub calc_reliability_wrapper {
  99     my($id, $xc) = @_;
 100     return calc_reliability_string($xc);
 101 }
 102
 103 sub calc_init_options {
 104     my($id, $xc) = @_;
 105
 106     my @ops;
 107     my @nodes = $xc->findnodes('e:configInfo/e:supports/@type');
 108     foreach my $node (@nodes) {
 109         my $type = $node->value();
 110         if ($type =~ s/^z3950_//) {
 111             push @ops, $type;
 112         }
 113     }
 114
 115     return join(", ", @ops);
 116 }
 117
 118 sub calc_ap {
 119     my($id, $xc, $set) = @_;
 120
 121     my @aps = _list_ap($xc, $set);
 122     my $n = @aps;
 123     return "[none]" if $n == 0;
 124
 125     my $res = "";
 126     my($first, $last);
 127     foreach my $ap (@aps) {
 128         if (!defined $first) {
 129             $first = $last = $ap;
 130         } elsif ($ap == $last+1) {
 131             $last++;
 132         } else {
 133             # Got a complete range
 134             $res .= ", " if $res ne "";
 135             $res .= "$first";
 136             $res .= "-$last" if $last > $first;
 137             $first = $last = $ap;
 138         }
 139     }
 140
 141     # Leftovers
 142     if (defined $first) {
 143         $res .= ", " if $res ne "";
 144         $res .= "$first";
 145         $res .= "-$last" if $last > $first;
 146     }
 147
 148     return ("$n access points: $res",
 149             "/ap.html?id=$id&set=$set");
 150 }
 151
 152 sub _list_ap {
 153     my($xc, $set) = @_;
 154
 155     my $expr = 'e:indexInfo/e:index[@search = "true"]/e:map/e:attr[
 156         @set = "'.$set.'" and @type = "1"]';
 157     my @nodes = $xc->findnodes($expr);
 158     return sort { $a <=> $b } map { $_->findvalue(".") } @nodes;
 159 }
 160
 161 sub calc_boolean {
 162     my($id, $xc) = @_;
 163
 164     ### Note that we are currently interrogating an IRSpy extension.
 165     #   The standard ZeeRex record should be extended with a
 166     #   "supports" type for this.
 167     my @nodes = $xc->findnodes('i:status/i:boolean[@ok = "1"]');
 168     my $res = join(", ", map { $_->findvalue('@operator') } @nodes);
 169     $res = "[none]" if $res eq "";
 170     return $res;
 171 }
 172
 173 sub calc_nrs {
 174     my($id, $xc) = @_;
 175
 176     my @nodes = $xc->findnodes('i:status/i:named_resultset[@ok = "1"]');
 177     return @nodes ? "Yes" : "No";
 178 }
 179
 180 sub calc_recsyn {
 181     my($id, $xc, $sep) = @_;
 182     $sep = ", " if !defined $sep;
 183
 184     my @nodes = $xc->findnodes('e:recordInfo/e:recordSyntax');
 185     my $res = join($sep, map { $_->findvalue('@name') } @nodes);
 186     $res = "[none]" if $res eq "";
 187     return $res;
 188 }
 189
 190 sub calc_explain {
 191     my($id, $xc) = @_;
 192
 193     my @nodes = $xc->findnodes('i:status/i:explain[@ok = "1"]');
 194     my $res = join(", ", map { $_->findvalue('@category') } @nodes);
 195     $res = "[none]" if $res eq "";
 196     return $res;
 197 }
 198 </%perl>