web/htdocs/details/found.mc

   1 %# $Id: found.mc,v 1.11 2006-09-25 16:52:30 mike Exp $
   2 <%once>
   3 use XML::LibXML;
   4 use XML::LibXML::XPathContext;
   5 use URI::Escape;
   6
   7 sub print_navlink {
   8     my($params, $cond, $caption, $skip) = @_;
   9
  10     if ($cond) {
  11         print('     <a href="', navlink($params, $caption, $skip),
  12               '"', ">$caption</a>\n");
  13     } else {
  14         print qq[     <span class="disabled">$caption</span>\n];
  15     }
  16 }
  17
  18 sub navlink {
  19     my($params, $caption, $skip) = @_;
  20     local $params->{_skip} = $skip;
  21     my $url = "?" . join("&", map { "$_=" . $params->{$_}  } sort keys %$params);
  22     $url = xml_encode($url);
  23     return $url;
  24 }
  25
  26 </%once>
  27 <%perl>
  28 my %params = map { ( $_, $r->param($_)) } grep { $r->param($_) } $r->param();
  29 my $query = "";
  30 foreach my $key (keys %params) {
  31     next if $key =~ /^_/;
  32     my $val = $params{$key};
  33     next if $val eq "";
  34     $query .= " and " if $query ne "";
  35     $query .= "$key = ($val)";
  36 }
  37 $query = 'cql.allRecords=x' if $query eq "";
  38
  39 my $sort = $params{"_sort"};
  40 if ($sort) {
  41     my $modifiers = "";
  42     if ($sort =~ s/(\/.*)//) {
  43         $modifiers = $1;
  44     }
  45     $query .= " or $sort=/sort";
  46     $query .= "-desc" if $params{_desc};
  47     $query .= $modifiers;
  48     $query .= " 0";
  49 }
  50
  51 ### We can think about keeping the Connection object open to re-use
  52 # for multiple requests, but that may not get us much.  Same applies
  53 # for the XML parser.
  54 my $conn = new ZOOM::Connection("localhost:3313/IR-Explain---1");
  55 $conn->option(elementSetName => "zeerex");
  56 my $parser = new XML::LibXML();
  57
  58 my $rs = $conn->search(new ZOOM::Query::CQL($query));
  59 my $n = $rs->size();
  60
  61 my $skip = $params{"_skip"} || 0;
  62 my $count = $params{"_count"} || 10;
  63
  64 my $first = $skip+1;
  65 my $last = $first+$count-1;
  66 $last = $n if $last > $n;
  67 </%perl>
  68      <h2><% xml_encode($query) %></h2>
  69      <p>
  70 % if ($n == 0) {
  71       No matches
  72 % } elsif ($first > $n) {
  73 %# "Can't happen"
  74       Past end of <% $n %> records
  75 % } else {
  76       Records <% $first %> to <% $last %> of <% $n %><br/>
  77 <%perl>
  78 print_navlink(\%params, $skip > 0, "Prev", $count < $skip ? $skip-$count : 0);
  79 print_navlink(\%params, $last < $n, "Next", $skip+$count);
  80 </%perl>
  81 % }
  82      </p>
  83 % if ($n > 0 && $first <= $n) {
  84      <table width="100%">
  85       <tr class="thleft">
  86        <th>#</th>
  87        <th>Title</th>
  88        <th>Author</th>
  89        <th>Host</th>
  90        <th>Port</th>
  91        <th>DB</th>
  92        <th></th>
  93        <th></th>
  94       </tr>
  95 % my @ids;
  96 % foreach my $i ($first .. $last) {
  97 <%perl>
  98 my $rec = $rs->record($i-1);
  99 my $xml = $rec->render();
 100 my $doc = $parser->parse_string($xml);
 101 my $root = $doc->getDocumentElement();
 102 my $xc = XML::LibXML::XPathContext->new($root);
 103 $xc->registerNs(e => 'http://explain.z3950.org/dtd/2.0/');
 104 my $title = $xc->find("e:databaseInfo/e:title");
 105 my $author = $xc->find("e:databaseInfo/e:author");
 106 my $host = $xc->find("e:serverInfo/e:host");
 107 my $port = $xc->find("e:serverInfo/e:port");
 108 my $db = $xc->find("e:serverInfo/e:database");
 109 my $id = $xc->find("concat(e:serverInfo/e:host, ':',
 110                            e:serverInfo/e:port, '/',
 111                            e:serverInfo/e:database)");
 112 push @ids, $id;
 113 </%perl>
 114       <tr style="background: <% ($i % 2) ? '#ffffc0' : 'white' %>">
 115        <td><% $i %></td>
 116        <td><% xml_encode($title) %></td>
 117        <td><% xml_encode($author) %></td>
 118        <td><% xml_encode($host) %></td>
 119        <td><% xml_encode($port) %></td>
 120        <td><% xml_encode($db) %></td>
 121        <td><a href="<% xml_encode("/check.html?id=" . uri_escape($id))
 122         %>">[Test]</a></td>
 123        <td><a href="<% xml_encode("/raw.html?id=" . uri_escape($id))
 124         %>">[Raw]</a></td>
 125       </tr>
 126 % }
 127      </table>
 128 <%perl>
 129 print_navlink(\%params, $skip > 0, "Prev", $count < $skip ? $skip-$count : 0);
 130 print_navlink(\%params, $last < $n, "Next", $skip+$count);
 131 </%perl>
 132      <p>
 133       <a href="<% "/check.html?" .
 134         xml_encode(join("&", map { "id=" . uri_escape($_) } @ids))
 135         %>">[Test all targets on this list]</a>
 136      </p>
 137 % }