lib/ZOOM/IRSpy.pm

   1 # $Id: IRSpy.pm,v 1.45 2006-10-30 16:13:49 mike Exp $
   2
   3 package ZOOM::IRSpy;
   4
   5 use 5.008;
   6 use strict;
   7 use warnings;
   8
   9 use Data::Dumper;               # For debugging only
  10 use File::Basename;
  11 use XML::LibXSLT;
  12 use XML::LibXML;
  13 use XML::LibXML::XPathContext;
  14 use ZOOM;
  15 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  16 use ZOOM::IRSpy::Node;
  17 use ZOOM::IRSpy::Connection;
  18 use ZOOM::IRSpy::Record;
  19 use ZOOM::IRSpy::Utils;
  20
  21 our @ISA = qw();
  22 our $VERSION = '0.02';
  23 our $irspy_ns = 'http://indexdata.com/irspy/1.0';
  24 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  25
  26
  27 # Enumeration for callback functions to return
  28 package ZOOM::IRSpy::Status;
  29 sub OK { 29 }                   # No problems, task is still progressing
  30 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  31 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  32 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  33 package ZOOM::IRSpy;
  34
  35
  36 =head1 NAME
  37
  38 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  39
  40 =head1 SYNOPSIS
  41
  42  use ZOOM::IRSpy;
  43  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  44  print $spy->report_status();
  45
  46 =head1 DESCRIPTION
  47
  48 This module exists to implement the IRspy program, which discovers,
  49 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  50 protocols.  It is a successor to the ZSpy program.
  51
  52 =cut
  53
  54 BEGIN {
  55     ZOOM::Log::mask_str("irspy");
  56     ZOOM::Log::mask_str("irspy_debug");
  57     ZOOM::Log::mask_str("irspy_event");
  58     ZOOM::Log::mask_str("irspy_unhandled");
  59     ZOOM::Log::mask_str("irspy_test");
  60     ZOOM::Log::mask_str("irspy_task");
  61 }
  62
  63 sub new {
  64     my $class = shift();
  65     my($dbname, $user, $password) = @_;
  66
  67     my @options;
  68     push @options, (user => $user, password => $password)
  69         if defined $user;
  70
  71     my $conn = new ZOOM::Connection($dbname, 0, @options)
  72         or die "$0: can't connection to IRSpy database 'dbname'";
  73
  74     my $xslt = new XML::LibXSLT;
  75     my $libxml = new XML::LibXML;
  76     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  77     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  78
  79     my $this = bless {
  80         conn => $conn,
  81         allrecords => 1,        # unless overridden by targets()
  82         query => undef,         # filled in later
  83         targets => undef,       # filled in later
  84         connections => undef,   # filled in later
  85         libxml => $libxml,
  86         irspy_to_zeerex_style => $irspy_to_zeerex_style,
  87         tests => [],            # stack of tests currently being executed
  88     }, $class;
  89     $this->log("irspy", "starting up with database '$dbname'");
  90
  91     return $this;
  92 }
  93
  94
  95 sub log {
  96     my $this = shift();
  97     ZOOM::Log::log(@_);
  98 }
  99
 100
 101 # Explicitly nominate a set of targets to check, overriding the
 102 # default which is to re-check everything in the database.  Each
 103 # target already in the database results in the existing record being
 104 # updated; each new target causes a new record to be added.
 105 #
 106 sub targets {
 107     my $this = shift();
 108     my(@targets) = @_;
 109
 110     $this->log("irspy", "setting explicit list of targets ",
 111                join(", ", map { "'$_'" } @targets));
 112     $this->{allrecords} = 0;
 113     my @qlist;
 114     foreach my $target (@targets) {
 115         my($host, $port, $db, $newtarget) = _parse_target_string($target);
 116         if ($newtarget ne $target) {
 117             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 118             $target = $newtarget; # This is written through the ref
 119         }
 120         push @qlist, (qq[(host="$host" and port="$port" and path="$db")]);
 121     }
 122
 123     $this->{targets} = \@targets;
 124     $this->{query} = join(" or ", @qlist);
 125 }
 126
 127
 128 # Also used by ZOOM::IRSpy::Record
 129 sub _parse_target_string {
 130     my($target) = @_;
 131
 132     my($host, $port, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 133     if (!defined $host) {
 134         $port = 210;
 135         ($host, $db) = ($target =~ /(.*?)\/(.*)/);
 136         $target = "$host:$port/$db";
 137     }
 138     die "$0: invalid target string '$target'"
 139         if !defined $host;
 140
 141     return ($host, $port, $db, $target);
 142 }
 143
 144
 145 # There are two cases.
 146 #
 147 # 1. A specific set of targets is nominated on the command line.
 148 #       - Records must be fetched for those targets that are in the DB
 149 #       - New, empty records must be made for those that are not.
 150 #       - Updated records written to the DB may or may not be new.
 151 #
 152 # 2. All records in the database are to be checked.
 153 #       - Records must be fetched for all targets in the DB
 154 #       - Updated records written to the DB may not be new.
 155 #
 156 # That's all -- what could be simpler?
 157 #
 158 sub initialise {
 159     my $this = shift();
 160
 161     my %target2record;
 162     if ($this->{allrecords}) {
 163         # We need to check on every target in the database, which
 164         # means we need to do a "find all".  According to the BIB-1
 165         # semantics document at
 166         #       http://www.loc.gov/z3950/agency/bib1.html
 167         # the query
 168         #       @attr 2=103 @attr 1=1035 x
 169         # should find all records, but it seems that Zebra doesn't
 170         # support this.  Furthermore, when using the "alvis" filter
 171         # (as we do for IRSpy) it doesn't support the use of any BIB-1
 172         # access point -- not even 1035 "everywhere" -- so instead we
 173         # hack together a search that we know will find all records.
 174         $this->{query} = "port=?*";
 175     } else {
 176         # Prepopulate the target map with nulls so that after we fill
 177         # in what we can from the database query, we know which target
 178         # IDs we need new records for.
 179         foreach my $target (@{ $this->{targets} }) {
 180             $target2record{lc($target)} = undef;
 181         }
 182     }
 183
 184     $this->log("irspy_debug", "query '", $this->{query}, "'");
 185     my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 186     delete $this->{query};      # No longer needed at all
 187     $this->log("irspy_debug", "found ", $rs->size(), " target records");
 188     foreach my $i (1 .. $rs->size()) {
 189         my $target = _render_record($rs, $i-1, "id");
 190         my $zeerex = _render_record($rs, $i-1, "zeerex");
 191         #print STDERR "making '$target' record with '$zeerex'\n";
 192         $target2record{lc($target)} =
 193             new ZOOM::IRSpy::Record($this, $target, $zeerex);
 194         push @{ $this->{targets} }, $target
 195             if $this->{allrecords};
 196     }
 197
 198     # Make records for targets not previously in the database
 199     foreach my $target (keys %target2record) {
 200         my $record = $target2record{$target};
 201         if (!defined $record) {
 202             $this->log("irspy_debug", "made new record for '$target'");
 203             $target2record{$target} = new ZOOM::IRSpy::Record($this, $target);
 204         } else {
 205             $this->log("irspy_debug", "using existing record for '$target'");
 206         }
 207     }
 208
 209     my @connections;
 210     foreach my $target (@{ $this->{targets} }) {
 211         my $conn = create ZOOM::IRSpy::Connection($this, async => 1);
 212         $conn->option(host => $target);
 213         my $record = delete $target2record{lc($target)};
 214         $conn->record($record);
 215         push @connections, $conn;
 216     }
 217     die("remaining target2record = { " .
 218         join(", ", map { "$_ ->'" . $target2record{$_}. "'" }
 219              sort keys %target2record) . " }")
 220         if %target2record;
 221
 222     $this->{connections} = \@connections;
 223     delete $this->{targets};    # The information is now in {connections}
 224 }
 225
 226
 227 sub _render_record {
 228     my($rs, $which, $elementSetName) = @_;
 229
 230     # There is a slight race condition here on the element-set name,
 231     # but it shouldn't be a problem as this is (currently) only called
 232     # from parts of the program that run single-threaded.
 233     my $old = $rs->option(elementSetName => $elementSetName);
 234     my $rec = $rs->record($which);
 235     $rs->option(elementSetName => $old);
 236
 237     return $rec->render();
 238 }
 239
 240
 241 sub _irspy_to_zeerex {
 242     my ($this, $conn) = @_;
 243     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 244     my %params = ();
 245     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 246
 247     return $result->documentElement();
 248 }
 249
 250
 251 sub _rewrite_record {
 252     my $this = shift();
 253     my($conn) = @_;
 254
 255     $conn->log("irspy", "rewriting XML record");
 256     my $rec = $this->_irspy_to_zeerex($conn);
 257     _really_rewrite_record($this->{conn}, $rec);
 258 }
 259
 260
 261 sub _really_rewrite_record {
 262     my($conn, $rec) = @_;
 263
 264     my $p = $conn->package();
 265     $p->option(action => "specialUpdate");
 266     my $xml = $rec->toString();
 267     $p->option(record => $xml);
 268     $p->send("update");
 269     $p->destroy();
 270
 271     $p = $conn->package();
 272     $p->send("commit");
 273     $p->destroy();
 274     if (0) {
 275         $xml =~ s/&/&amp/g;
 276         $xml =~ s/</&lt;/g;
 277         $xml =~ s/>/&gt;/g;
 278         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 279     }
 280 }
 281
 282
 283 # The approach: gather declarative information about test hierarchy,
 284 # then go into a loop.  In the loop, we ensure that each connection is
 285 # running a test, and within that test a task, until its list of tests
 286 # is exhausted.  No individual test ever calls wait(): tests just queue
 287 # up tasks and return immediately.  When the tasks are run (one at a
 288 # time on each connection) they generate events, and it is these that
 289 # are harvested by ZOOM::event().  Since each connection knows what
 290 # task it is running, it can invoke the appropriate callbacks.
 291 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 292 # loop how to continue.
 293 #
 294 # Invariants:
 295 #       While a connection is running a task, its current_task()
 296 #       points at the task structure.  When it finishes its task,
 297 #       next_task() is pointed at the next task to execute (if there
 298 #       is one), and its current_task() is set to zero.  When the next
 299 #       task is executed, the connection's next_task() is set to zero
 300 #       and its current_task() pointed to the task structure.
 301 #       current_task() and next_task() are both zero only when there
 302 #       are no more queued tasks, which is when a new test is
 303 #       started.
 304 #
 305 #       Each connection's current test is stored in its
 306 #       "current_test_address" option.  The next test to execute is
 307 #       calculated by walking the declarative tree of tests.  This
 308 #       option begins empty; the "next test" after this is of course
 309 #       the root test.
 310 #
 311 sub check {
 312     my $this = shift();
 313     my($tname) = @_;
 314
 315     $tname = "Main" if !defined $tname;
 316     $this->{tree} = $this->_gather_tests($tname)
 317         or die "No tests defined for '$tname'";
 318     #$this->{tree}->print(0);
 319     my $nskipped = 0;
 320
 321     my @conn = @{ $this->{connections} };
 322
 323     while (1) {
 324         my @copy_conn = @conn;  # avoid alias problems after splice()
 325         my $nconn = scalar(@copy_conn);
 326         foreach my $i0 (0 .. $#copy_conn) {
 327             my $conn = $copy_conn[$i0];
 328             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 329             if (!$conn->current_task()) {
 330                 if (!$conn->next_task()) {
 331                     # Out of tasks: we need a new test
 332                   NEXT_TEST:
 333                     my $address = $conn->option("current_test_address");
 334                     my $nextaddr;
 335                     if (!defined $address) {
 336                         $nextaddr = "";
 337                     } else {
 338                         $this->log("irspy_test",
 339                                    "checking for next test after '$address'");
 340                         $nextaddr = $this->_next_test($address);
 341                     }
 342                     if (!defined $nextaddr) {
 343                         $conn->log("irspy", "has no more tests: removing");
 344                         splice @conn, $i0, 1;
 345                         $this->_rewrite_record($conn);
 346                         next;
 347                     }
 348
 349                     my $node = $this->{tree}->select($nextaddr)
 350                         or die "invalid nextaddr '$nextaddr'";
 351                     $conn->option(current_test_address => $nextaddr);
 352                     my $tname = $node->name();
 353                     $conn->log("irspy_test",
 354                                "starting test '$nextaddr' = $tname");
 355                     my $tasks = $conn->tasks();
 356                     my $oldcount = @$tasks;
 357                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 358                     $tasks = $conn->tasks();
 359                     if (@$tasks > $oldcount) {
 360                         # Prepare to start the first of the newly added tasks
 361                         $conn->next_task($tasks->[$oldcount]);
 362                     } else {
 363                         $conn->log("irspy_task",
 364                                    "no tasks added by new test $tname");
 365                         goto NEXT_TEST;
 366                     }
 367                 }
 368
 369                 my $task = $conn->next_task();
 370                 die "no next task queued for $conn" if !defined $task;
 371                 $conn->log("irspy_task", "preparing task $task");
 372                 $conn->next_task(0);
 373                 $conn->current_task($task);
 374                 $task->run();
 375             }
 376
 377             # Do we need to test $conn->is_idle()?  I don't think so!
 378         }
 379
 380         my $i0 = ZOOM::event(\@conn);
 381         $this->log("irspy_event",
 382                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 383         last if $i0 == 0 || $i0 == -3; # no events or no connections
 384         my $conn = $conn[$i0-1];
 385         my $ev = $conn->last_event();
 386         my $evstr = ZOOM::event_str($ev);
 387         $conn->log("irspy_event", "event $ev ($evstr)");
 388
 389         my $task = $conn->current_task();
 390         die "$conn has no current task for event $ev ($evstr)" if !$task;
 391         eval { $conn->_check() };
 392         if ($@ &&
 393             ($ev == ZOOM::Event::RECV_DATA ||
 394              $ev == ZOOM::Event::RECV_APDU ||
 395              $ev == ZOOM::Event::ZEND)) {
 396             # An error in, say, a search response, becomes visible to
 397             # ZOOM before the Receive Data event is sent and persists
 398             # until after the End, which means that successive events
 399             # each report the same error.  So we just ignore errors on
 400             # "unimportant" events.  ### But this doesn't work for,
 401             # say, a Connection Refused, as the only event that shows
 402             # us this error is the End.
 403             $conn->log("irspy_event", "ignoring error ",
 404                        "on event $ev ($evstr): $@");
 405             next;
 406         }
 407
 408         my $res;
 409         if ($@) {
 410             my $sub = $task->{cb}->{exception};
 411             die $@ if !defined $sub;
 412             $res = &$sub($conn, $task, $task->udata(), $@);
 413         } else {
 414             my $sub = $task->{cb}->{$ev};
 415             if (!defined $sub) {
 416                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 417                 next;
 418             }
 419
 420             $res = &$sub($conn, $task, $task->udata(), $ev);
 421         }
 422
 423         if ($res == ZOOM::IRSpy::Status::OK) {
 424             # Nothing to do -- life continues
 425
 426         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 427             my $task = $conn->current_task();
 428             die "no task for TASK_DONE on $conn" if !$task;
 429             die "next task already defined for $conn" if $conn->next_task();
 430             $conn->log("irspy_task", "completed task $task");
 431             $conn->next_task($task->{next});
 432             $conn->current_task(0);
 433
 434         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 435                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 436             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 437             $conn->log("irspy_task", "test ended during task $task ($x)");
 438             $conn->log("irspy_test", "test completed ($x)");
 439             $conn->current_task(0);
 440             $conn->next_task(0);
 441             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 442                 my $address = $conn->option('current_test_address');
 443                 ($address, my $n) = $this->_last_sibling_test($address);
 444                 if (defined $address) {
 445                     $conn->log("irspy_test", "skipped $n tests");
 446                     $conn->option(current_test_address => $address);
 447                     $nskipped += $n;
 448                 }
 449             }
 450         } else {
 451             die "unknown callback return-value '$res'";
 452         }
 453     }
 454
 455     $this->log("irspy", "exiting main loop");
 456     return $nskipped;
 457 }
 458
 459
 460 sub _gather_tests {
 461     my $this = shift();
 462     my($tname, @ancestors) = @_;
 463
 464     die("$0: test-hierarchy loop detected: " .
 465         join(" -> ", @ancestors, $tname))
 466         if grep { $_ eq $tname } @ancestors;
 467
 468     my $slashSeperatedTname = $tname;
 469     $slashSeperatedTname =~ s/::/\//g;
 470     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 471
 472     eval {
 473         require $fullName;
 474         $this->log("irspy", "successfully required '$fullName'");
 475     }; if ($@) {
 476         $this->log("irspy", "couldn't require '$fullName': $@");
 477         $this->log("warn", "can't load test '$tname': skipping",
 478                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 479         return undef;
 480     }
 481
 482     $this->log("irspy", "adding test '$tname'");
 483     my @subnodes;
 484     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 485         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 486         push @subnodes, $subtest if defined $subtest;
 487     }
 488
 489     return new ZOOM::IRSpy::Node($tname, @subnodes);
 490 }
 491
 492
 493 # These next three should arguably be Node methods
 494 sub _next_test {
 495     my $this = shift();
 496     my($address, $omit_child) = @_;
 497
 498     # Try first child
 499     if (!$omit_child) {
 500         my $maybe = $address eq "" ? "0" : "$address:0";
 501         return $maybe if $this->{tree}->select($maybe);
 502     }
 503
 504     # The top-level node has no successor or parent
 505     return undef if $address eq "";
 506
 507     # Try next sibling child
 508     my @components = split /:/, $address;
 509     my $last = pop @components;
 510     my $maybe = join(":", @components, $last+1);
 511     return $maybe if $this->{tree}->select($maybe);
 512
 513     # This node is exhausted: try the parent's successor
 514     return $this->_next_test(join(":", @components), 1)
 515 }
 516
 517
 518 sub _last_sibling_test {
 519     my $this = shift();
 520     my($address) = @_;
 521
 522     return undef
 523         if !defined $this->_next_sibling_test($address);
 524
 525     my $nskipped = 0;
 526     while (1) {
 527         my $maybe = $this->_next_sibling_test($address);
 528         last if !defined $maybe;
 529         $nskipped++;
 530         $this->log("irspy", "skipping $nskipped tests to '$address'");
 531         $address = $maybe;
 532     }
 533
 534     return ($address, $nskipped);
 535 }
 536
 537
 538 sub _next_sibling_test {
 539     my $this = shift();
 540     my($address) = @_;
 541
 542     my @components = split /:/, $address;
 543     my $last = pop @components;
 544     my $maybe = join(":", @components, $last+1);
 545     return $maybe if $this->{tree}->select($maybe);
 546     return undef;
 547 }
 548
 549
 550 =head1 SEE ALSO
 551
 552 ZOOM::IRSpy::Record,
 553 ZOOM::IRSpy::Web,
 554 ZOOM::IRSpy::Test,
 555 ZOOM::IRSpy::Maintenance.
 556
 557 The ZOOM-Perl module,
 558 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 559
 560 The Zebra Database,
 561 http://indexdata.com/zebra/
 562
 563 =head1 AUTHOR
 564
 565 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 566
 567 =head1 COPYRIGHT AND LICENSE
 568
 569 Copyright (C) 2006 by Index Data ApS.
 570
 571 This library is free software; you can redistribute it and/or modify
 572 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 573 at your option, any later version of Perl 5 you may have available.
 574
 575 =cut
 576
 577
 578 1;