lib/ZOOM/IRSpy.pm

   1
   2 package ZOOM::IRSpy;
   3
   4 use 5.008;
   5 use strict;
   6 use warnings;
   7
   8 use Data::Dumper;               # For debugging only
   9 use File::Basename;
  10 use XML::LibXSLT;
  11 use XML::LibXML;
  12 use XML::LibXML::XPathContext;
  13 use ZOOM;
  14 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  15 use ZOOM::IRSpy::Node;
  16 use ZOOM::IRSpy::Connection;
  17 use ZOOM::IRSpy::Stats;
  18 use ZOOM::IRSpy::Utils qw(cql_target render_record
  19                           irspy_xpath_context irspy_make_identifier
  20                           irspy_record2identifier calc_reliability_stats
  21                           modify_xml_document);
  22
  23 our @ISA = qw();
  24 our $VERSION = '1.02';
  25 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  26 our $debug = 0;
  27 our $xslt_max_depth = 250;
  28 our $max_timeout_errors = 3;
  29
  30
  31 # Enumeration for callback functions to return
  32 package ZOOM::IRSpy::Status;
  33 sub OK { 29 }                   # No problems, task is still progressing
  34 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  35 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  36 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  37 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  38 package ZOOM::IRSpy;
  39
  40
  41 =head1 NAME
  42
  43 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  44
  45 =head1 SYNOPSIS
  46
  47  use ZOOM::IRSpy;
  48  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  49  $spy->targets(@targets);
  50  $spy->initialise("Main");
  51  $res = $spy->check();
  52
  53 =head1 DESCRIPTION
  54
  55 This module exists to implement the IRspy program, which discovers,
  56 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  57 protocols.  It is a successor to the ZSpy program.
  58
  59 =cut
  60
  61 BEGIN {
  62     ZOOM::Log::mask_str("irspy");
  63     ZOOM::Log::mask_str("irspy_debug");
  64     ZOOM::Log::mask_str("irspy_event");
  65     ZOOM::Log::mask_str("irspy_unhandled");
  66     ZOOM::Log::mask_str("irspy_test");
  67     ZOOM::Log::mask_str("irspy_task");
  68 }
  69
  70 sub new {
  71     my $class = shift();
  72     my($dbname, $user, $password, $activeSetSize) = @_;
  73
  74
  75     my @options;
  76     push @options, (user => $user, password => $password)
  77         if defined $user;
  78
  79     my $conn = new ZOOM::Connection($dbname, 0, @options)
  80         or die "$0: can't connection to IRSpy database 'dbname'";
  81
  82     my $xslt = new XML::LibXSLT;
  83
  84     # raise the maximum number of nested template calls and variables/params (default 250)
  85     warn "raise the maximum number of nested template calls: $xslt_max_depth\n" if $debug;
  86     $xslt->max_depth($xslt_max_depth);
  87
  88     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  89                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  90
  91     my $libxml = new XML::LibXML;
  92     warn "use irspy_to_zeerex_xsl xslt sheet: $irspy_to_zeerex_xsl\n" if $debug;
  93     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  94     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  95
  96     my $this = bless {
  97         conn => $conn,
  98         query => "cql.allRecords=1", # unless overridden
  99         modn => undef,          # Filled in by restrict_modulo()
 100         modi => undef,          # Filled in by restrict_modulo()
 101         targets => undef,       # Filled in later if targets() is
 102                                 # called; used only to keep state from
 103                                 # targets() until initialise() is
 104                                 # called.
 105         connections => undef,   # Filled in by initialise()
 106         queue => undef,         # Filled in by initialise()
 107         libxml => $libxml,
 108         irspy_to_zeerex_style => $irspy_to_zeerex_style,
 109         test => undef,          # Filled in by initialise()
 110         timeout => undef,       # Filled in by initialise()
 111         tests => undef,         # Tree of tests to be executed
 112         activeSetSize => defined $activeSetSize ? $activeSetSize : 10,
 113     }, $class;
 114     $this->log("irspy", "starting up with database '$dbname'");
 115
 116     return $this;
 117 }
 118
 119 # wrapper to read the IRSpy database name from environment variable / apache config
 120 sub connect_to_registry {
 121     my %args = @_;
 122
 123     # XXX: we could also handle her: user, password, elementSetName
 124
 125     my $database = $ENV{IRSpyDbName} || "localhost:8018/IR-Explain---1";
 126
 127     return $database;
 128 }
 129
 130 sub log {
 131     my $this = shift();
 132     ZOOM::Log::log(@_);
 133 }
 134
 135
 136 sub find_targets {
 137     my $this = shift();
 138     my($query) = @_;
 139
 140     $this->{query} = $query;
 141 }
 142
 143
 144 # Explicitly nominate a set of targets to check, overriding the
 145 # default which is to re-check everything in the database.  Each
 146 # target already in the database results in the existing record being
 147 # updated; each new target causes a new record to be added.
 148 #
 149 sub targets {
 150     my $this = shift();
 151     my(@targets) = @_;
 152
 153     $this->log("irspy", "setting explicit list of targets ",
 154                join(", ", map { "'$_'" } @targets));
 155     my @qlist;
 156     foreach my $target (@targets) {
 157         my($protocol, $host, $port, $db, $newtarget) =
 158             _parse_target_string($target);
 159         if ($newtarget ne $target) {
 160             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 161             $target = $newtarget; # This is written through the ref
 162         }
 163         push @qlist, cql_target($protocol, $host, $port, $db);
 164     }
 165
 166     $this->{targets} = \@targets;
 167     $this->{query} = join(" or ", @qlist);
 168 }
 169
 170
 171 # Also used by ZOOM::IRSpy::Record
 172 sub _parse_target_string {
 173     my($target) = @_;
 174
 175     my($protocol, $host, $port, $db) = ($target =~ /(.*?):(.*?):(.*?)\/(.*)/);
 176     if (!defined $host) {
 177         $port = 210;
 178         ($protocol, $host, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 179         $target = irspy_make_identifier($protocol, $host, $port, $db);
 180     }
 181     die "$0: invalid target string '$target'"
 182         if !defined $host;
 183
 184     return ($protocol, $host, $port, $db, $target);
 185 }
 186
 187
 188 sub restrict_modulo {
 189     my $this = shift();
 190     my($n, $i) = @_;
 191
 192     $this->{modn} = $n;
 193     $this->{modi} = $i;
 194 }
 195
 196
 197 # Records must be fetched for all records satisfying $this->{query} If
 198 # $this->{targets} is already set (i.e. a specific list of targets to
 199 # check was specified by a call to targets()), then new, empty records
 200 # will be made for any targets that are not already in the database.
 201 #
 202 sub initialise {
 203     my $this = shift();
 204     my($tname) = @_;
 205
 206     $tname = "Main" if !defined $tname;
 207     $this->{test} = $tname;
 208     $this->{tree} = $this->_gather_tests($tname)
 209         or die "No tests defined for '$tname'";
 210     $this->{tree}->resolve();
 211     #$this->{tree}->print(0);
 212
 213     $this->{timeout} = "ZOOM::IRSpy::Test::$tname"->timeout();
 214
 215     my @targets;
 216     my $targets = $this->{targets};
 217     if (defined $targets) {
 218         @targets = @$targets;
 219         delete $this->{targets};
 220     } else {
 221         my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 222         $this->log("irspy", "'", $this->{query}, "' found ",
 223                    $rs->size(), " target records");
 224         delete $this->{query};
 225
 226         foreach my $i (1 .. $rs->size()) {
 227             push @targets, render_record($rs, $i-1, "id");
 228         }
 229     }
 230
 231     my $n = $this->{activeSetSize};
 232     $n = @targets if $n == 0 || $n > @targets;
 233
 234     $this->{queue} = \@targets;
 235     $this->{connections} = [];
 236     while (@{ $this->{connections} } < $n) {
 237         my $conn = $this->_next_connection();
 238         last if !defined $conn;
 239         push @{ $this->{connections} }, $conn;
 240     }
 241 }
 242
 243
 244 sub _next_connection {
 245     my $this = shift();
 246
 247     my $target;
 248     my $n = $this->{modn};
 249     my $i = $this->{modi};
 250     if (!defined $n) {
 251         $target = shift @{ $this->{queue} };
 252         return undef if !defined $target;
 253     } else {
 254         while (1) {
 255             $target = shift @{ $this->{queue} };
 256             return undef if !defined $target;
 257             my $h = _hash($target);
 258             my $hmodn = $h % $n;
 259             last if $hmodn == $i;
 260             #$this->log("irspy", "'$target' hash $h % $n = $hmodn != $i");
 261         }
 262     }
 263
 264     die "oops -- target is undefined" if !defined $target;
 265     return create ZOOM::IRSpy::Connection($this, $target, async => 1,
 266                                           timeout => $this->{timeout});
 267 }
 268
 269
 270 sub _hash {
 271     my($target) = @_;
 272
 273     my $n = 0;
 274     foreach my $s (split //, $target) {
 275         $n += ord($s);
 276     }
 277
 278     return $n;
 279 }
 280
 281
 282 sub _irspy_to_zeerex {
 283     my $this = shift();
 284     my($conn) = @_;
 285
 286     my $save_xml = $ENV{IRSPY_SAVE_XML};
 287     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 288
 289     if ($save_xml) {
 290         unlink('/tmp/irspy_orig.xml');
 291         open FH, '>/tmp/irspy_orig.xml'
 292             or die "can't write irspy_orig.xml: $!";
 293         print FH $irspy_doc->toString();
 294         close FH;
 295     }
 296     my %params = ();
 297     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 298     if ($save_xml) {
 299         unlink('/tmp/irspy_transformed.xml');
 300         open FH, '>/tmp/irspy_transformed.xml'
 301             or die "can't write irspy_transformed.xml: $!";
 302         print FH $result->toString();
 303         close FH;
 304     }
 305
 306     return $result->documentElement();
 307 }
 308
 309
 310 sub _rewrite_irspy_record {
 311     my $this = shift();
 312     my($conn) = @_;
 313
 314     $conn->log("irspy", "rewriting XML record");
 315     my $rec = $this->_irspy_to_zeerex($conn);
 316
 317     # Since IRSpy can run for a long time between writes back to the
 318     # database, it's quite possible for the server to have closed the
 319     # connection as idle.  So re-establish it if necessary.
 320     $this->{conn}->connect($conn->option("host"));
 321
 322     _rewrite_zeerex_record($this->{conn}, $rec);
 323     $conn->log("irspy", "rewrote XML record");
 324 }
 325
 326
 327 my $_reliabilityField = {
 328     reliability => [ reliability => 0,
 329                       "Calculated reliability of server",
 330                       "e:serverInfo/e:reliability" ],
 331 };
 332
 333 sub _rewrite_zeerex_record {
 334     my($conn, $rec, $oldid) = @_;
 335
 336     # Add reliability score
 337     my $xc = irspy_xpath_context($rec);
 338     my($nok, $nall, $percent) = calc_reliability_stats($xc);
 339     modify_xml_document($xc, $_reliabilityField, { reliability => $percent });
 340
 341     my $p = $conn->package();
 342     $p->option(action => "specialUpdate");
 343     my $xml = $rec->toString();
 344     $p->option(record => $xml);
 345     $p->send("update");
 346     $p->destroy();
 347
 348     # This is the expression in the ID-making stylesheet
 349     # ../../zebra/zeerex2id.xsl
 350     my $id = irspy_record2identifier($xc);
 351     if (defined $oldid && $id ne $oldid) {
 352         warn "IDs differ (old='$oldid' new='$id')";
 353         _delete_record($conn, $oldid);
 354     }
 355
 356     $p = $conn->package();
 357     $p->send("commit");
 358     $p->destroy();
 359     if (0) {
 360         $xml =~ s/&/&amp/g;
 361         $xml =~ s/</&lt;/g;
 362         $xml =~ s/>/&gt;/g;
 363         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 364     }
 365 }
 366
 367
 368 sub _delete_record {
 369     my($conn, $id) = @_;
 370
 371     # We can't delete records using recordIdOpaque, since character
 372     # sets are handled differently here in extended services from how
 373     # they are used in the Alvis filter's record-parsing, and so
 374     # non-ASCII characters come out differently in the two contexts.
 375     # Instead, we must send a record whose contents indicate the ID of
 376     # that which we wish to delete.  There are two ways, both
 377     # unsatisfactory: we could either fetch the actual record them
 378     # resubmit it in the deletion request (which wastes a search and a
 379     # fetch) or we could build a record by hand from the parsed-out
 380     # components (which is error-prone and which I am not 100% certain
 381     # will work since the other contents of the record will be
 382     # different).  The former evil seems to be the lesser.
 383
 384     warn "$conn deleting record '$id'";
 385
 386     my $rs = $conn->search(new ZOOM::Query::CQL(cql_target($id)));
 387     die "no such ID '$id'" if $rs->size() == 0;
 388     my $rec = $rs->record(0);
 389     my $xml = $rec->render();
 390
 391     my $p = $conn->package();
 392     $p->option(action => "recordDelete");
 393     $p->option(record => $xml);
 394     $p->send("update");
 395     $p->destroy();
 396
 397     $p = $conn->package();
 398     $p->send("commit");
 399     $p->destroy();
 400 }
 401
 402
 403 # The approach: gather declarative information about test hierarchy,
 404 # then go into a loop.  In the loop, we ensure that each connection is
 405 # running a test, and within that test a task, until its list of tests
 406 # is exhausted.  No individual test ever calls wait(): tests just queue
 407 # up tasks and return immediately.  When the tasks are run (one at a
 408 # time on each connection) they generate events, and it is these that
 409 # are harvested by ZOOM::event().  Since each connection knows what
 410 # task it is running, it can invoke the appropriate callbacks.
 411 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 412 # loop how to continue.
 413 #
 414 # Invariants:
 415 #       While a connection is running a task, its current_task()
 416 #       points at the task structure.  When it finishes its task,
 417 #       next_task() is pointed at the next task to execute (if there
 418 #       is one), and its current_task() is set to zero.  When the next
 419 #       task is executed, the connection's next_task() is set to zero
 420 #       and its current_task() pointed to the task structure.
 421 #       current_task() and next_task() are both zero only when there
 422 #       are no more queued tasks, which is when a new test is
 423 #       started.
 424 #
 425 #       Each connection's current test is stored in its
 426 #       "current_test_address" option.  The next test to execute is
 427 #       calculated by walking the declarative tree of tests.  This
 428 #       option begins empty; the "next test" after this is of course
 429 #       the root test.
 430 #
 431 sub check {
 432     my $this = shift();
 433
 434     my $topname = $this->{tree}->name();
 435     my $timeout = $this->{timeout};
 436     $this->log("irspy", "beginnning with test '$topname' (timeout $timeout)");
 437
 438     my $nskipped = 0;
 439     my @conn = @{ $this->{connections} };
 440
 441     my $nruns = 0;
 442   ROUND_AND_ROUND_WE_GO:
 443     while (1) {
 444         my @copy_conn = @conn;  # avoid alias problems after splice()
 445         my $nconn = scalar(@copy_conn);
 446
 447         foreach my $i0 (0 .. $#copy_conn) {
 448             my $conn = $copy_conn[$i0];
 449             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 450             next if !defined $conn;
 451             if (!$conn->current_task()) {
 452                 if (!$conn->next_task()) {
 453                     # Out of tasks: we need a new test
 454                   NEXT_TEST:
 455                     my $address = $conn->option("current_test_address");
 456                     my $nextaddr;
 457                     if (!defined $address) {
 458                         $nextaddr = "";
 459                     } else {
 460                         $conn->log("irspy_test",
 461                                    "checking for next test after '$address'");
 462                         $nextaddr = $this->_next_test($address);
 463                         if ($nextaddr && $conn->record->zoom_error->{TIMEOUT} >= $max_timeout_errors) {
 464                             $conn->log("irspy", "Got to many timeouts, stop testing: " . $conn->record->zoom_error->{TIMEOUT});
 465                             $nextaddr = "";
 466                         }
 467                     }
 468                     if (!defined $nextaddr) {
 469                         $conn->log("irspy", "has no more tests: removing");
 470                         $this->_rewrite_irspy_record($conn);
 471                         $conn->option(rewrote_record => 1);
 472                         my $newconn = $this->_next_connection();
 473                         if (!defined $newconn) {
 474                             # Do not destroy: needed for later sanity checks
 475                             splice @conn, $i0, 1;
 476                         } else {
 477                             $conn->destroy();
 478                             $conn[$i0] = $newconn;
 479                             $conn[$i0]->option(current_test_address => "");
 480                             $conn[$i0]->log("irspy", "entering active pool - ",
 481                                             scalar(@{ $this->{queue} }),
 482                                             " targets remain in queue");
 483                         }
 484                         next;
 485                     }
 486
 487                     my $node = $this->{tree}->select($nextaddr)
 488                         or die "invalid nextaddr '$nextaddr'";
 489                     $conn->option(current_test_address => $nextaddr);
 490                     my $tname = $node->name();
 491                     $conn->log("irspy_test",
 492                                "starting test '$nextaddr' = $tname");
 493                     my $tasks = $conn->tasks();
 494                     my $oldcount = @$tasks;
 495                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 496                     $tasks = $conn->tasks();
 497                     if (@$tasks > $oldcount) {
 498                         # Prepare to start the first of the newly added tasks
 499                         $conn->next_task($tasks->[$oldcount]);
 500                     } else {
 501                         $conn->log("irspy_task",
 502                                    "no tasks added by new test $tname");
 503                         goto NEXT_TEST;
 504                     }
 505                 }
 506
 507                 my $task = $conn->next_task();
 508                 die "no next task queued for $conn" if !defined $task;
 509                 $conn->log("irspy_task", "preparing task $task");
 510                 $conn->next_task(0);
 511                 $conn->current_task($task);
 512                 $task->run();
 513             }
 514         }
 515
 516       NEXT_EVENT:
 517         my $i0 = ZOOM::event(\@conn);
 518         $this->log("irspy_event",
 519                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 520         if ($i0 < 1) {
 521             my %messages = (
 522                             0 => "no events remain",
 523                             -1 => "ZOOM::event() argument not a reference",
 524                             -2 => "ZOOM::event() reference not an array",
 525                             -3 => "no connections remain",
 526                             -4 => "too many connections for ZOOM::event()",
 527                             );
 528             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 529             $this->log("irspy", $message);
 530             last;
 531         }
 532
 533         my $conn = $conn[$i0-1];
 534         my $ev = $conn->last_event();
 535         my $evstr = ZOOM::event_str($ev);
 536         $conn->log("irspy_event", "event $ev ($evstr)");
 537         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 538
 539         my $task = $conn->current_task();
 540         die "$conn has no current task for event $ev ($evstr)" if !$task;
 541
 542         my $res;
 543         eval { $conn->check() };
 544         if ($@ && ref $@ && $@->isa("ZOOM::Exception")) {
 545             my $sub = $task->{cb}->{exception};
 546             die $@ if !defined $sub;
 547             $res = &$sub($conn, $task, $task->udata(), $@);
 548         } elsif ($@) {
 549             die "Unexpected non-ZOOM exception: " . ref($@) . " ($@)";
 550         } else {
 551             my $sub = $task->{cb}->{$ev};
 552             if (!defined $sub) {
 553                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 554                 next;
 555             }
 556
 557             $res = &$sub($conn, $task, $task->udata(), $ev);
 558         }
 559
 560         if ($res == ZOOM::IRSpy::Status::OK) {
 561             # Nothing to do -- life continues
 562
 563         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 564             my $task = $conn->current_task();
 565             die "no task for TASK_DONE on $conn" if !$task;
 566             die "next task already defined for $conn" if $conn->next_task();
 567             $conn->log("irspy_task", "completed task $task");
 568             $conn->next_task($task->{next});
 569             $conn->current_task(0);
 570
 571         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 572                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 573             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 574             $conn->log("irspy_task", "test ended during task $task ($x)");
 575             $conn->log("irspy_test", "test completed ($x)");
 576             $conn->current_task(0);
 577             $conn->next_task(0);
 578             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 579                 my $address = $conn->option('current_test_address');
 580                 $conn->log("irspy", "top-level test failed!")
 581                     if $address eq "";
 582                 my $node = $this->{tree}->select($address);
 583                 my $skipcount = 0;
 584                 while (defined $node->next() &&
 585                        length($node->next()->address()) >= length($address)) {
 586                     $conn->log("irspy_debug", "skipping from '",
 587                                $node->address(), "' to '",
 588                                $node->next()->address(), "'");
 589                     $node = $node->next();
 590                     $skipcount++;
 591                 }
 592
 593                 $conn->option(current_test_address => $node->address());
 594                 $conn->log("irspy_test", "skipped $skipcount tests");
 595                 $nskipped += $skipcount;
 596             }
 597
 598         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 599             $conn->log("irspy_test", "test skipped during task $task");
 600             $conn->current_task(0);
 601             $conn->next_task(0);
 602             $nskipped++;
 603
 604         } else {
 605             die "unknown callback return-value '$res'";
 606         }
 607     }
 608
 609     $this->log("irspy", "exiting main loop");
 610
 611     # Sanity checks: none of the following should ever happen
 612     my $finished = 1;
 613     $this->log("irspy", "performing end-of-run sanity-checks");
 614     foreach my $conn (@conn) {
 615         my $test = $conn->option("current_test_address");
 616         my $next = $this->_next_test($test);
 617         if (defined $next) {
 618             $this->log("irspy",
 619                        "$conn (in test '$test') has queued test '$next'");
 620             $finished = 0;
 621         }
 622         if (my $task = $conn->current_task()) {
 623             $this->log("irspy", "$conn still has an active task $task");
 624             $finished = 0;
 625         }
 626         if (my $task = $conn->next_task()) {
 627             $this->log("irspy", "$conn still has a queued task $task");
 628             $finished = 0;
 629         }
 630         if (!$conn->is_idle()) {
 631             $this->log("irspy",
 632                        "$conn still has ZOOM-C level tasks queued: see below");
 633             $finished = 0;
 634         }
 635         my $ev = $conn->peek_event();
 636         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 637             my $evstr = ZOOM::event_str($ev);
 638             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 639             $finished = 0;
 640         }
 641         if (!$conn->option("rewrote_record")) {
 642             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 643             $finished = 0;
 644         }
 645     }
 646
 647     # This really shouldn't be necessary, and in practice it rarely
 648     # helps, but it's belt and braces.  (For now, we don't do this
 649     # hence the zero in the $nruns check).
 650     if (!$finished) {
 651         if (++$nruns < 0) {
 652             $this->log("irspy", "back into main loop, ${nruns}th time");
 653             goto ROUND_AND_ROUND_WE_GO;
 654         } else {
 655             $this->log("irspy", "bailing after $nruns main-loop runs");
 656         }
 657     }
 658
 659     # This shouldn't happen emit anything either:
 660     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 661         my $conn = $conn[$i1-1];
 662         my $ev = $conn->last_event();
 663         my $evstr = ZOOM::event_str($ev);
 664         $this->log("irspy",
 665                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 666             if $ev != ZOOM::Event::ZEND;
 667     }
 668
 669     return $nskipped;
 670 }
 671
 672
 673 # Exactly equivalent to ZOOM::event() except that it is tolerant to
 674 # undefined values in the array being passed in.
 675 #
 676 sub __UNUSED_tolerant_ZOOM_event {
 677     my($connref) = @_;
 678
 679     my(@conn, @map);
 680     foreach my $i (0 .. @$connref-1) {
 681         my $conn = $connref->[$i];
 682         if (defined $conn) {
 683             push @conn, $conn;
 684             push @map, $i;
 685         }
 686     }
 687
 688     my $res = ZOOM::event(\@conn);
 689     return $res if $res <= 0;
 690     my $res2 = $map[$res-1] + 1;
 691     print STDERR "*** tolerant_ZOOM_event() returns $res->$res2\n";
 692     return $res2;
 693 }
 694
 695
 696 sub _gather_tests {
 697     my $this = shift();
 698     my($tname, @ancestors) = @_;
 699
 700     die("$0: test-hierarchy loop detected: " .
 701         join(" -> ", @ancestors, $tname))
 702         if grep { $_ eq $tname } @ancestors;
 703
 704     my $slashSeperatedTname = $tname;
 705     $slashSeperatedTname =~ s/::/\//g;
 706     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 707
 708     eval {
 709         require $fullName;
 710     }; if ($@) {
 711         $this->log("irspy", "couldn't require '$fullName': $@");
 712         $this->log("warn", "can't load test '$tname': skipping",
 713                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 714         return undef;
 715     }
 716
 717     $this->log("irspy", "adding test '$tname'");
 718     my @subnodes;
 719     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 720         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 721         push @subnodes, $subtest if defined $subtest;
 722     }
 723
 724     return new ZOOM::IRSpy::Node($tname, @subnodes);
 725 }
 726
 727
 728 # These next three should arguably be Node methods
 729 sub _next_test {
 730     my $this = shift();
 731     my($address, $omit_child) = @_;
 732
 733     # Try first child
 734     if (!$omit_child) {
 735         my $maybe = $address eq "" ? "0" : "$address:0";
 736         return $maybe if $this->{tree}->select($maybe);
 737     }
 738
 739     # The top-level node has no successor or parent
 740     return undef if $address eq "";
 741
 742     # Try next sibling child
 743     my @components = split /:/, $address;
 744     my $last = pop @components;
 745     my $maybe = join(":", @components, $last+1);
 746     return $maybe if $this->{tree}->select($maybe);
 747
 748     # This node is exhausted: try the parent's successor
 749     return $this->_next_test(join(":", @components), 1)
 750 }
 751
 752
 753 sub _last_sibling_test {
 754     my $this = shift();
 755     my($address) = @_;
 756
 757     return undef
 758         if !defined $this->_next_sibling_test($address);
 759
 760     my $nskipped = 0;
 761     while (1) {
 762         my $maybe = $this->_next_sibling_test($address);
 763         last if !defined $maybe;
 764         $nskipped++;
 765         $address = $maybe;
 766         $this->log("irspy", "skipping $nskipped tests to '$address'");
 767     }
 768
 769     return ($address, $nskipped);
 770 }
 771
 772
 773 sub _next_sibling_test {
 774     my $this = shift();
 775     my($address) = @_;
 776
 777     my @components = split /:/, $address;
 778     my $last = pop @components;
 779     my $maybe = join(":", @components, $last+1);
 780     return $maybe if $this->{tree}->select($maybe);
 781     return undef;
 782 }
 783
 784
 785 =head1 SEE ALSO
 786
 787 ZOOM::IRSpy::Record,
 788 ZOOM::IRSpy::Web,
 789 ZOOM::IRSpy::Test,
 790 ZOOM::IRSpy::Maintenance.
 791
 792 The ZOOM-Perl module,
 793 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 794
 795 The Zebra Database,
 796 http://indexdata.com/zebra/
 797
 798 =head1 AUTHOR
 799
 800 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 801
 802 =head1 COPYRIGHT AND LICENSE
 803
 804 Copyright (C) 2006 by Index Data ApS.
 805
 806 This library is free software; you can redistribute it and/or modify
 807 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 808 at your option, any later version of Perl 5 you may have available.
 809
 810 =cut
 811
 812
 813 1;