lib/ZOOM/IRSpy.pm

   1 # $Id: IRSpy.pm,v 1.67 2007-02-23 15:01:48 mike Exp $
   2
   3 package ZOOM::IRSpy;
   4
   5 use 5.008;
   6 use strict;
   7 use warnings;
   8
   9 use Data::Dumper;               # For debugging only
  10 use File::Basename;
  11 use XML::LibXSLT;
  12 use XML::LibXML;
  13 use XML::LibXML::XPathContext;
  14 use ZOOM;
  15 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  16 use ZOOM::IRSpy::Node;
  17 use ZOOM::IRSpy::Connection;
  18 use ZOOM::IRSpy::Record;
  19 use ZOOM::IRSpy::Stats;
  20 use ZOOM::IRSpy::Utils qw(cql_target);
  21
  22 our @ISA = qw();
  23 our $VERSION = '0.02';
  24 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  25
  26
  27 # Enumeration for callback functions to return
  28 package ZOOM::IRSpy::Status;
  29 sub OK { 29 }                   # No problems, task is still progressing
  30 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  31 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  32 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  33 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  34 package ZOOM::IRSpy;
  35
  36
  37 =head1 NAME
  38
  39 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  40
  41 =head1 SYNOPSIS
  42
  43  use ZOOM::IRSpy;
  44  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  45  $spy->targets(@targets);
  46  $spy->initialise();
  47  $res = $spy->check("Main");
  48
  49 =head1 DESCRIPTION
  50
  51 This module exists to implement the IRspy program, which discovers,
  52 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  53 protocols.  It is a successor to the ZSpy program.
  54
  55 =cut
  56
  57 BEGIN {
  58     ZOOM::Log::mask_str("irspy");
  59     ZOOM::Log::mask_str("irspy_debug");
  60     ZOOM::Log::mask_str("irspy_event");
  61     ZOOM::Log::mask_str("irspy_unhandled");
  62     ZOOM::Log::mask_str("irspy_test");
  63     ZOOM::Log::mask_str("irspy_task");
  64 }
  65
  66 sub new {
  67     my $class = shift();
  68     my($dbname, $user, $password) = @_;
  69
  70     my @options;
  71     push @options, (user => $user, password => $password)
  72         if defined $user;
  73
  74     my $conn = new ZOOM::Connection($dbname, 0, @options)
  75         or die "$0: can't connection to IRSpy database 'dbname'";
  76
  77     my $xslt = new XML::LibXSLT;
  78
  79     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  80                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  81
  82     my $libxml = new XML::LibXML;
  83     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  84     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  85
  86     my $this = bless {
  87         conn => $conn,
  88         allrecords => 1,        # unless overridden by targets()
  89         query => undef,         # filled in later
  90         targets => undef,       # filled in later
  91         connections => undef,   # filled in later
  92         libxml => $libxml,
  93         irspy_to_zeerex_style => $irspy_to_zeerex_style,
  94         tests => [],            # stack of tests currently being executed
  95     }, $class;
  96     $this->log("irspy", "starting up with database '$dbname'");
  97
  98     return $this;
  99 }
 100
 101
 102 sub log {
 103     my $this = shift();
 104     ZOOM::Log::log(@_);
 105 }
 106
 107
 108 # Explicitly nominate a set of targets to check, overriding the
 109 # default which is to re-check everything in the database.  Each
 110 # target already in the database results in the existing record being
 111 # updated; each new target causes a new record to be added.
 112 #
 113 sub targets {
 114     my $this = shift();
 115     my(@targets) = @_;
 116
 117     $this->log("irspy", "setting explicit list of targets ",
 118                join(", ", map { "'$_'" } @targets));
 119     $this->{allrecords} = 0;
 120     my @qlist;
 121     foreach my $target (@targets) {
 122         my($host, $port, $db, $newtarget) = _parse_target_string($target);
 123         if ($newtarget ne $target) {
 124             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 125             $target = $newtarget; # This is written through the ref
 126         }
 127         push @qlist, cql_target($host, $port, $db);
 128     }
 129
 130     $this->{targets} = \@targets;
 131     $this->{query} = join(" or ", @qlist);
 132 }
 133
 134
 135 # Also used by ZOOM::IRSpy::Record
 136 sub _parse_target_string {
 137     my($target) = @_;
 138
 139     my($host, $port, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 140     if (!defined $host) {
 141         $port = 210;
 142         ($host, $db) = ($target =~ /(.*?)\/(.*)/);
 143         $target = "$host:$port/$db";
 144     }
 145     die "$0: invalid target string '$target'"
 146         if !defined $host;
 147
 148     return ($host, $port, $db, $target);
 149 }
 150
 151
 152 # There are two cases.
 153 #
 154 # 1. A specific set of targets is nominated on the command line.
 155 #       - Records must be fetched for those targets that are in the DB
 156 #       - New, empty records must be made for those that are not.
 157 #       - Updated records written to the DB may or may not be new.
 158 #
 159 # 2. All records in the database are to be checked.
 160 #       - Records must be fetched for all targets in the DB
 161 #       - Updated records written to the DB may not be new.
 162 #
 163 # That's all -- what could be simpler?
 164 #
 165 sub initialise {
 166     my $this = shift();
 167
 168     my %target2record;
 169     if ($this->{allrecords}) {
 170         # We need to check on every target in the database, which
 171         # means we need to do a "find all".  According to the BIB-1
 172         # semantics document at
 173         #       http://www.loc.gov/z3950/agency/bib1.html
 174         # the query
 175         #       @attr 2=103 @attr 1=1035 x
 176         # should find all records, but it seems that Zebra doesn't
 177         # support this.  Furthermore, when using the "alvis" filter
 178         # (as we do for IRSpy) it doesn't support the use of any BIB-1
 179         # access point -- not even 1035 "everywhere" -- so instead we
 180         # hack together a search that we know will find all records.
 181         $this->{query} = "port=?*";
 182     } else {
 183         # Prepopulate the target map with nulls so that after we fill
 184         # in what we can from the database query, we know which target
 185         # IDs we need new records for.
 186         foreach my $target (@{ $this->{targets} }) {
 187             $target2record{lc($target)} = undef;
 188         }
 189     }
 190
 191     $this->log("irspy_debug", "query '", $this->{query}, "'");
 192     my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 193     delete $this->{query};      # No longer needed at all
 194     $this->log("irspy_debug", "found ", $rs->size(), " target records");
 195     foreach my $i (1 .. $rs->size()) {
 196         my $target = _render_record($rs, $i-1, "id");
 197         my $zeerex = _render_record($rs, $i-1, "zeerex");
 198         #print STDERR "making '$target' record with '$zeerex'\n";
 199         $target2record{lc($target)} =
 200             new ZOOM::IRSpy::Record($this, $target, $zeerex);
 201         push @{ $this->{targets} }, $target
 202             if $this->{allrecords};
 203     }
 204
 205     # Make records for targets not previously in the database
 206     foreach my $target (keys %target2record) {
 207         my $record = $target2record{$target};
 208         if (!defined $record) {
 209             $this->log("irspy_debug", "made new record for '$target'");
 210             $target2record{$target} = new ZOOM::IRSpy::Record($this, $target);
 211         } else {
 212             $this->log("irspy_debug", "using existing record for '$target'");
 213         }
 214     }
 215
 216     my @connections;
 217     foreach my $target (@{ $this->{targets} }) {
 218         my $conn = create ZOOM::IRSpy::Connection($this, async => 1);
 219         $conn->option(host => $target);
 220         my $record = delete $target2record{lc($target)};
 221         $conn->record($record);
 222         push @connections, $conn;
 223     }
 224     die("remaining target2record = { " .
 225         join(", ", map { "$_ ->'" . $target2record{$_}. "'" }
 226              sort keys %target2record) . " }")
 227         if %target2record;
 228
 229     $this->{connections} = \@connections;
 230     delete $this->{targets};    # The information is now in {connections}
 231 }
 232
 233
 234 sub _render_record {
 235     my($rs, $which, $elementSetName) = @_;
 236
 237     # There is a slight race condition here on the element-set name,
 238     # but it shouldn't be a problem as this is (currently) only called
 239     # from parts of the program that run single-threaded.
 240     my $old = $rs->option(elementSetName => $elementSetName);
 241     my $rec = $rs->record($which);
 242     $rs->option(elementSetName => $old);
 243
 244     return $rec->render();
 245 }
 246
 247
 248 sub _irspy_to_zeerex {
 249     my $this = shift();
 250     my($conn, $save_xml) = @_;
 251     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 252
 253     if ($save_xml) {
 254         unlink('/tmp/irspy_orig.xml');
 255         open FH, '>/tmp/irspy_orig.xml';
 256         print FH $irspy_doc->toString();
 257         close FH;
 258     }
 259     my %params = ();
 260     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 261     if ($save_xml) {
 262         unlink('/tmp/irspy_transformed.xml');
 263         open FH, '>/tmp/irspy_transformed.xml';
 264         print FH $result->toString();
 265         close FH;
 266     }
 267
 268     return $result->documentElement();
 269 }
 270
 271
 272 sub _rewrite_record {
 273     my $this = shift();
 274     my($conn) = @_;
 275
 276     $conn->log("irspy", "rewriting XML record");
 277     my $rec = $this->_irspy_to_zeerex($conn, $ENV{IRSPY_SAVE_XML});
 278     _really_rewrite_record($this->{conn}, $rec);
 279 }
 280
 281
 282 sub _really_rewrite_record {
 283     my($conn, $rec) = @_;
 284
 285     my $p = $conn->package();
 286     $p->option(action => "specialUpdate");
 287     my $xml = $rec->toString();
 288     $p->option(record => $xml);
 289     $p->send("update");
 290     $p->destroy();
 291
 292     $p = $conn->package();
 293     $p->send("commit");
 294     $p->destroy();
 295     if (0) {
 296         $xml =~ s/&/&amp/g;
 297         $xml =~ s/</&lt;/g;
 298         $xml =~ s/>/&gt;/g;
 299         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 300     }
 301 }
 302
 303
 304 # The approach: gather declarative information about test hierarchy,
 305 # then go into a loop.  In the loop, we ensure that each connection is
 306 # running a test, and within that test a task, until its list of tests
 307 # is exhausted.  No individual test ever calls wait(): tests just queue
 308 # up tasks and return immediately.  When the tasks are run (one at a
 309 # time on each connection) they generate events, and it is these that
 310 # are harvested by ZOOM::event().  Since each connection knows what
 311 # task it is running, it can invoke the appropriate callbacks.
 312 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 313 # loop how to continue.
 314 #
 315 # Invariants:
 316 #       While a connection is running a task, its current_task()
 317 #       points at the task structure.  When it finishes its task,
 318 #       next_task() is pointed at the next task to execute (if there
 319 #       is one), and its current_task() is set to zero.  When the next
 320 #       task is executed, the connection's next_task() is set to zero
 321 #       and its current_task() pointed to the task structure.
 322 #       current_task() and next_task() are both zero only when there
 323 #       are no more queued tasks, which is when a new test is
 324 #       started.
 325 #
 326 #       Each connection's current test is stored in its
 327 #       "current_test_address" option.  The next test to execute is
 328 #       calculated by walking the declarative tree of tests.  This
 329 #       option begins empty; the "next test" after this is of course
 330 #       the root test.
 331 #
 332 sub check {
 333     my $this = shift();
 334     my($tname) = @_;
 335
 336     $tname = "Main" if !defined $tname;
 337     $this->{tree} = $this->_gather_tests($tname)
 338         or die "No tests defined for '$tname'";
 339     #$this->{tree}->print(0);
 340     my $nskipped = 0;
 341
 342     my @conn = @{ $this->{connections} };
 343
 344     my $nruns = 0;
 345   ROUND_AND_ROUND_WE_GO:
 346     while (1) {
 347         my @copy_conn = @conn;  # avoid alias problems after splice()
 348         my $nconn = scalar(@copy_conn);
 349         foreach my $i0 (0 .. $#copy_conn) {
 350             my $conn = $copy_conn[$i0];
 351             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 352             if (!$conn->current_task()) {
 353                 if (!$conn->next_task()) {
 354                     # Out of tasks: we need a new test
 355                   NEXT_TEST:
 356                     my $address = $conn->option("current_test_address");
 357                     my $nextaddr;
 358                     if (!defined $address) {
 359                         $nextaddr = "";
 360                     } else {
 361                         $this->log("irspy_test",
 362                                    "checking for next test after '$address'");
 363                         $nextaddr = $this->_next_test($address);
 364                     }
 365                     if (!defined $nextaddr) {
 366                         $conn->log("irspy", "has no more tests: removing");
 367                         ### Does this go wrong if two connections are exhausted?
 368                         splice @conn, $i0, 1;
 369                         $this->_rewrite_record($conn);
 370                         $conn->option(rewrote_record => 1);
 371                         next;
 372                     }
 373
 374                     my $node = $this->{tree}->select($nextaddr)
 375                         or die "invalid nextaddr '$nextaddr'";
 376                     $conn->option(current_test_address => $nextaddr);
 377                     my $tname = $node->name();
 378                     $conn->log("irspy_test",
 379                                "starting test '$nextaddr' = $tname");
 380                     my $tasks = $conn->tasks();
 381                     my $oldcount = @$tasks;
 382                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 383                     $tasks = $conn->tasks();
 384                     if (@$tasks > $oldcount) {
 385                         # Prepare to start the first of the newly added tasks
 386                         $conn->next_task($tasks->[$oldcount]);
 387                     } else {
 388                         $conn->log("irspy_task",
 389                                    "no tasks added by new test $tname");
 390                         goto NEXT_TEST;
 391                     }
 392                 }
 393
 394                 my $task = $conn->next_task();
 395                 die "no next task queued for $conn" if !defined $task;
 396                 $conn->log("irspy_task", "preparing task $task");
 397                 $conn->next_task(0);
 398                 $conn->current_task($task);
 399                 $task->run();
 400             }
 401         }
 402
 403       NEXT_EVENT:
 404         my $i0 = ZOOM::event(\@conn);
 405         $this->log("irspy_event",
 406                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 407         if ($i0 < 1) {
 408             my %messages = (
 409                             0 => "no events remain",
 410                             -1 => "ZOOM::event() argument not a reference",
 411                             -2 => "ZOOM::event() reference not an array",
 412                             -3 => "no connections remain",
 413                             -4 => "too many connections for ZOOM::event()",
 414                             );
 415             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 416             $this->log("irspy", $message);
 417             last;
 418         }
 419
 420         my $conn = $conn[$i0-1];
 421         my $ev = $conn->last_event();
 422         my $evstr = ZOOM::event_str($ev);
 423         $conn->log("irspy_event", "event $ev ($evstr)");
 424         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 425
 426         my $task = $conn->current_task();
 427         die "$conn has no current task for event $ev ($evstr)" if !$task;
 428
 429         my $res;
 430         eval { $conn->_check() };
 431         if ($@) {
 432             my $sub = $task->{cb}->{exception};
 433             die $@ if !defined $sub;
 434             $res = &$sub($conn, $task, $task->udata(), $@);
 435         } else {
 436             my $sub = $task->{cb}->{$ev};
 437             if (!defined $sub) {
 438                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 439                 next;
 440             }
 441
 442             $res = &$sub($conn, $task, $task->udata(), $ev);
 443         }
 444
 445         if ($res == ZOOM::IRSpy::Status::OK) {
 446             # Nothing to do -- life continues
 447
 448         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 449             my $task = $conn->current_task();
 450             die "no task for TASK_DONE on $conn" if !$task;
 451             die "next task already defined for $conn" if $conn->next_task();
 452             $conn->log("irspy_task", "completed task $task");
 453             $conn->next_task($task->{next});
 454             $conn->current_task(0);
 455
 456         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 457                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 458             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 459             $conn->log("irspy_task", "test ended during task $task ($x)");
 460             $conn->log("irspy_test", "test completed ($x)");
 461             $conn->current_task(0);
 462             $conn->next_task(0);
 463             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 464                 my $address = $conn->option('current_test_address');
 465                 ($address, my $n) = $this->_last_sibling_test($address);
 466                 if (defined $address) {
 467                     $conn->log("irspy_test", "skipped $n tests");
 468                     $conn->option(current_test_address => $address);
 469                     $nskipped += $n;
 470                 }
 471             }
 472
 473         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 474             $conn->log("irspy_test", "test skipped during task $task");
 475             $conn->current_task(0);
 476             $conn->next_task(0);
 477             $nskipped++;
 478
 479         } else {
 480             die "unknown callback return-value '$res'";
 481         }
 482     }
 483
 484     $this->log("irspy", "exiting main loop");
 485     # Sanity checks: none of the following should ever happen
 486     my $finished = 1;
 487     @conn = @{ $this->{connections} };
 488     foreach my $conn (@conn) {
 489         my $test = $conn->option("current_test_address");
 490         my $next = $this->_next_test($test);
 491         if (defined $next) {
 492             $this->log("irspy",
 493                        "$conn (in test '$test') has queued test '$next'");
 494             $finished = 0;
 495         }
 496         if (my $task = $conn->current_task()) {
 497             $this->log("irspy", "$conn still has an active task $task");
 498             $finished = 0;
 499         }
 500         if (my $task = $conn->next_task()) {
 501             $this->log("irspy", "$conn still has a queued task $task");
 502             $finished = 0;
 503         }
 504         if (!$conn->is_idle()) {
 505             $this->log("irspy",
 506                        "$conn still has ZOOM-C level tasks queued: see below");
 507             $finished = 0;
 508         }
 509         my $ev = $conn->peek_event();
 510         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 511             my $evstr = ZOOM::event_str($ev);
 512             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 513             $finished = 0;
 514         }
 515         if (!$conn->option("rewrote_record")) {
 516             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 517             $finished = 0;
 518         }
 519     }
 520
 521     # This really shouldn't be necessary, and in practice it rarely
 522     # helps, but it's belt and braces.  (For now, we don't do this
 523     # hence the zero in the $nruns check).
 524     if (!$finished) {
 525         if (++$nruns < 0) {
 526             $this->log("irspy", "back into main loop, ${nruns}th time");
 527             goto ROUND_AND_ROUND_WE_GO;
 528         } else {
 529             $this->log("irspy", "bailing after $nruns main-loop runs");
 530         }
 531     }
 532
 533     # This shouldn't happen emit anything either:
 534     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 535         my $conn = $conn[$i1-1];
 536         my $ev = $conn->last_event();
 537         my $evstr = ZOOM::event_str($ev);
 538         $this->log("irspy",
 539                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 540             if $ev != ZOOM::Event::ZEND;
 541     }
 542
 543     return $nskipped;
 544 }
 545
 546
 547 sub _gather_tests {
 548     my $this = shift();
 549     my($tname, @ancestors) = @_;
 550
 551     die("$0: test-hierarchy loop detected: " .
 552         join(" -> ", @ancestors, $tname))
 553         if grep { $_ eq $tname } @ancestors;
 554
 555     my $slashSeperatedTname = $tname;
 556     $slashSeperatedTname =~ s/::/\//g;
 557     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 558
 559     eval {
 560         require $fullName;
 561         $this->log("irspy", "successfully required '$fullName'");
 562     }; if ($@) {
 563         $this->log("irspy", "couldn't require '$fullName': $@");
 564         $this->log("warn", "can't load test '$tname': skipping",
 565                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 566         return undef;
 567     }
 568
 569     $this->log("irspy", "adding test '$tname'");
 570     my @subnodes;
 571     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 572         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 573         push @subnodes, $subtest if defined $subtest;
 574     }
 575
 576     return new ZOOM::IRSpy::Node($tname, @subnodes);
 577 }
 578
 579
 580 # These next three should arguably be Node methods
 581 sub _next_test {
 582     my $this = shift();
 583     my($address, $omit_child) = @_;
 584
 585     # Try first child
 586     if (!$omit_child) {
 587         my $maybe = $address eq "" ? "0" : "$address:0";
 588         return $maybe if $this->{tree}->select($maybe);
 589     }
 590
 591     # The top-level node has no successor or parent
 592     return undef if $address eq "";
 593
 594     # Try next sibling child
 595     my @components = split /:/, $address;
 596     my $last = pop @components;
 597     my $maybe = join(":", @components, $last+1);
 598     return $maybe if $this->{tree}->select($maybe);
 599
 600     # This node is exhausted: try the parent's successor
 601     return $this->_next_test(join(":", @components), 1)
 602 }
 603
 604
 605 sub _last_sibling_test {
 606     my $this = shift();
 607     my($address) = @_;
 608
 609     return undef
 610         if !defined $this->_next_sibling_test($address);
 611
 612     my $nskipped = 0;
 613     while (1) {
 614         my $maybe = $this->_next_sibling_test($address);
 615         last if !defined $maybe;
 616         $nskipped++;
 617         $address = $maybe;
 618         $this->log("irspy", "skipping $nskipped tests to '$address'");
 619     }
 620
 621     return ($address, $nskipped);
 622 }
 623
 624
 625 sub _next_sibling_test {
 626     my $this = shift();
 627     my($address) = @_;
 628
 629     my @components = split /:/, $address;
 630     my $last = pop @components;
 631     my $maybe = join(":", @components, $last+1);
 632     return $maybe if $this->{tree}->select($maybe);
 633     return undef;
 634 }
 635
 636
 637 =head1 SEE ALSO
 638
 639 ZOOM::IRSpy::Record,
 640 ZOOM::IRSpy::Web,
 641 ZOOM::IRSpy::Test,
 642 ZOOM::IRSpy::Maintenance.
 643
 644 The ZOOM-Perl module,
 645 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 646
 647 The Zebra Database,
 648 http://indexdata.com/zebra/
 649
 650 =head1 AUTHOR
 651
 652 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 653
 654 =head1 COPYRIGHT AND LICENSE
 655
 656 Copyright (C) 2006 by Index Data ApS.
 657
 658 This library is free software; you can redistribute it and/or modify
 659 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 660 at your option, any later version of Perl 5 you may have available.
 661
 662 =cut
 663
 664
 665 1;