lib/ZOOM/IRSpy.pm

   1 # $Id: IRSpy.pm,v 1.86 2007-07-09 09:41:44 mike Exp $
   2
   3 package ZOOM::IRSpy;
   4
   5 use 5.008;
   6 use strict;
   7 use warnings;
   8
   9 use Data::Dumper;               # For debugging only
  10 use File::Basename;
  11 use XML::LibXSLT;
  12 use XML::LibXML;
  13 use XML::LibXML::XPathContext;
  14 use ZOOM;
  15 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  16 use ZOOM::IRSpy::Node;
  17 use ZOOM::IRSpy::Connection;
  18 use ZOOM::IRSpy::Stats;
  19 use ZOOM::IRSpy::Utils qw(cql_target render_record
  20                           irspy_xpath_context irspy_make_identifier
  21                           irspy_record2identifier);
  22
  23 our @ISA = qw();
  24 our $VERSION = '1.00';
  25 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  26
  27
  28 # Enumeration for callback functions to return
  29 package ZOOM::IRSpy::Status;
  30 sub OK { 29 }                   # No problems, task is still progressing
  31 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  32 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  33 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  34 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  35 package ZOOM::IRSpy;
  36
  37
  38 =head1 NAME
  39
  40 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  41
  42 =head1 SYNOPSIS
  43
  44  use ZOOM::IRSpy;
  45  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  46  $spy->targets(@targets);
  47  $spy->initialise("Main");
  48  $res = $spy->check();
  49
  50 =head1 DESCRIPTION
  51
  52 This module exists to implement the IRspy program, which discovers,
  53 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  54 protocols.  It is a successor to the ZSpy program.
  55
  56 =cut
  57
  58 BEGIN {
  59     ZOOM::Log::mask_str("irspy");
  60     ZOOM::Log::mask_str("irspy_debug");
  61     ZOOM::Log::mask_str("irspy_event");
  62     ZOOM::Log::mask_str("irspy_unhandled");
  63     ZOOM::Log::mask_str("irspy_test");
  64     ZOOM::Log::mask_str("irspy_task");
  65 }
  66
  67 sub new {
  68     my $class = shift();
  69     my($dbname, $user, $password, $activeSetSize) = @_;
  70
  71     my @options;
  72     push @options, (user => $user, password => $password)
  73         if defined $user;
  74
  75     my $conn = new ZOOM::Connection($dbname, 0, @options)
  76         or die "$0: can't connection to IRSpy database 'dbname'";
  77
  78     my $xslt = new XML::LibXSLT;
  79
  80     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  81                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  82
  83     my $libxml = new XML::LibXML;
  84     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  85     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  86
  87     my $this = bless {
  88         conn => $conn,
  89         query => "cql.allRecords=1", # unless overridden
  90         targets => undef,       # Filled in later if targets() is
  91                                 # called; used only to keep state from
  92                                 # targets() until initialise() is
  93                                 # called.
  94         connections => undef,   # Filled in by initialise()
  95         queue => undef,         # Filled in by initialise()
  96         libxml => $libxml,
  97         irspy_to_zeerex_style => $irspy_to_zeerex_style,
  98         test => undef,          # Filled in by initialise()
  99         tests => undef,         # Tree of tests to be executed
 100         activeSetSize => defined $activeSetSize ? $activeSetSize : 10,
 101     }, $class;
 102     $this->log("irspy", "starting up with database '$dbname'");
 103
 104     return $this;
 105 }
 106
 107
 108 sub log {
 109     my $this = shift();
 110     ZOOM::Log::log(@_);
 111 }
 112
 113
 114 sub find_targets {
 115     my $this = shift();
 116     my($query) = @_;
 117
 118     $this->{query} = $query;
 119 }
 120
 121
 122 # Explicitly nominate a set of targets to check, overriding the
 123 # default which is to re-check everything in the database.  Each
 124 # target already in the database results in the existing record being
 125 # updated; each new target causes a new record to be added.
 126 #
 127 sub targets {
 128     my $this = shift();
 129     my(@targets) = @_;
 130
 131     $this->log("irspy", "setting explicit list of targets ",
 132                join(", ", map { "'$_'" } @targets));
 133     my @qlist;
 134     foreach my $target (@targets) {
 135         my($protocol, $host, $port, $db, $newtarget) =
 136             _parse_target_string($target);
 137         if ($newtarget ne $target) {
 138             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 139             $target = $newtarget; # This is written through the ref
 140         }
 141         push @qlist, cql_target($protocol, $host, $port, $db);
 142     }
 143
 144     $this->{targets} = \@targets;
 145     $this->{query} = join(" or ", @qlist);
 146 }
 147
 148
 149 # Also used by ZOOM::IRSpy::Record
 150 sub _parse_target_string {
 151     my($target) = @_;
 152
 153     my($protocol, $host, $port, $db) = ($target =~ /(.*?):(.*?):(.*?)\/(.*)/);
 154     if (!defined $host) {
 155         $port = 210;
 156         ($protocol, $host, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 157         $target = irspy_make_identifier($protocol, $host, $port, $db);
 158     }
 159     die "$0: invalid target string '$target'"
 160         if !defined $host;
 161
 162     return ($protocol, $host, $port, $db, $target);
 163 }
 164
 165
 166 # Records must be fetched for all records satisfying $this->{query} If
 167 # $this->{targets} is already set (i.e. a specific list of targets to
 168 # check was specified by a call to targets()), then new, empty records
 169 # will be made for any targets that are not already in the database.
 170 #
 171 sub initialise {
 172     my $this = shift();
 173     my($tname) = @_;
 174
 175     $tname = "Main" if !defined $tname;
 176     $this->{test} = $tname;
 177     $this->{tree} = $this->_gather_tests($tname)
 178         or die "No tests defined for '$tname'";
 179     $this->{tree}->resolve();
 180     #$this->{tree}->print(0);
 181
 182     my $timeout = "ZOOM::IRSpy::Test::$tname"->timeout();
 183
 184     my @targets;
 185     my $targets = $this->{targets};
 186     if (defined $targets) {
 187         @targets = @$targets;
 188         delete $this->{targets};
 189     } else {
 190         my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 191         $this->log("irspy", "'", $this->{query}, "' found ",
 192                    $rs->size(), " target records");
 193         delete $this->{query};
 194
 195         foreach my $i (1 .. $rs->size()) {
 196             push @targets, render_record($rs, $i-1, "id");
 197         }
 198     }
 199
 200     my $n = $this->{activeSetSize};
 201     $n = @targets if $n == 0 || $n > @targets;
 202
 203     my @connections;
 204     foreach my $i (1..$n) {
 205         push @connections, create ZOOM::IRSpy::Connection($this,
 206                                                           shift @targets,
 207                                                           async => 1,
 208                                                           timeout => $timeout);
 209     }
 210
 211     $this->{connections} = \@connections;
 212     $this->{queue} = \@targets;
 213 }
 214
 215
 216 sub _irspy_to_zeerex {
 217     my $this = shift();
 218     my($conn, $save_xml) = @_;
 219     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 220
 221     if ($save_xml) {
 222         unlink('/tmp/irspy_orig.xml');
 223         open FH, '>/tmp/irspy_orig.xml'
 224             or die "can't write irspy_orig.xml: $!";
 225         print FH $irspy_doc->toString();
 226         close FH;
 227     }
 228     my %params = ();
 229     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 230     if ($save_xml) {
 231         unlink('/tmp/irspy_transformed.xml');
 232         open FH, '>/tmp/irspy_transformed.xml'
 233             or die "can't write irspy_transformed.xml: $!";
 234         print FH $result->toString();
 235         close FH;
 236     }
 237
 238     return $result->documentElement();
 239 }
 240
 241
 242 sub _rewrite_record {
 243     my $this = shift();
 244     my($conn) = @_;
 245
 246     $conn->log("irspy", "rewriting XML record");
 247     my $rec = $this->_irspy_to_zeerex($conn, $ENV{IRSPY_SAVE_XML});
 248
 249     # Since IRSpy can run for a long time between writes back to the
 250     # database, it's quite possible for the server to have closed the
 251     # connection as idle.  So re-establish it if necessary.
 252     $this->{conn}->connect($conn->option("host"));
 253
 254     _really_rewrite_record($this->{conn}, $rec);
 255     $conn->log("irspy", "rewrote XML record");
 256 }
 257
 258
 259 sub _really_rewrite_record {
 260     my($conn, $rec, $oldid) = @_;
 261
 262     my $p = $conn->package();
 263     $p->option(action => "specialUpdate");
 264     my $xml = $rec->toString();
 265     $p->option(record => $xml);
 266     $p->send("update");
 267     $p->destroy();
 268
 269     # This is the expression in the ID-making stylesheet
 270     # ../../zebra/zeerex2id.xsl
 271     my $xc = irspy_xpath_context($rec);
 272     my $id = irspy_record2identifier($xc);
 273     if (defined $oldid && $id ne $oldid) {
 274         warn "IDs differ (old='$oldid' new='$id')";
 275         _delete_record($conn, $oldid);
 276     }
 277
 278     $p = $conn->package();
 279     $p->send("commit");
 280     $p->destroy();
 281     if (0) {
 282         $xml =~ s/&/&amp/g;
 283         $xml =~ s/</&lt;/g;
 284         $xml =~ s/>/&gt;/g;
 285         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 286     }
 287 }
 288
 289
 290 sub _delete_record {
 291     my($conn, $id) = @_;
 292
 293     # We can't delete records using recordIdOpaque, since character
 294     # sets are handled differently here in extended services from how
 295     # they are used in the Alvis filter's record-parsing, and so
 296     # non-ASCII characters come out differently in the two contexts.
 297     # Instead, we must send a record whose contents indicate the ID of
 298     # that which we wish to delete.  There are two ways, both
 299     # unsatisfactory: we could either fetch the actual record them
 300     # resubmit it in the deletion request (which wastes a search and a
 301     # fetch) or we could build a record by hand from the parsed-out
 302     # components (which is error-prone and which I am not 100% certain
 303     # will work since the other contents of the record will be
 304     # different).  The former evil seems to be the lesser.
 305
 306     warn "$conn deleting record '$id'";
 307
 308     my $rs = $conn->search(new ZOOM::Query::CQL(cql_target($id)));
 309     die "no such ID '$id'" if $rs->size() == 0;
 310     my $rec = $rs->record(0);
 311     my $xml = $rec->render();
 312
 313     my $p = $conn->package();
 314     $p->option(action => "recordDelete");
 315     $p->option(record => $xml);
 316     $p->send("update");
 317     $p->destroy();
 318
 319     $p = $conn->package();
 320     $p->send("commit");
 321     $p->destroy();
 322 }
 323
 324
 325 # The approach: gather declarative information about test hierarchy,
 326 # then go into a loop.  In the loop, we ensure that each connection is
 327 # running a test, and within that test a task, until its list of tests
 328 # is exhausted.  No individual test ever calls wait(): tests just queue
 329 # up tasks and return immediately.  When the tasks are run (one at a
 330 # time on each connection) they generate events, and it is these that
 331 # are harvested by ZOOM::event().  Since each connection knows what
 332 # task it is running, it can invoke the appropriate callbacks.
 333 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 334 # loop how to continue.
 335 #
 336 # Invariants:
 337 #       While a connection is running a task, its current_task()
 338 #       points at the task structure.  When it finishes its task,
 339 #       next_task() is pointed at the next task to execute (if there
 340 #       is one), and its current_task() is set to zero.  When the next
 341 #       task is executed, the connection's next_task() is set to zero
 342 #       and its current_task() pointed to the task structure.
 343 #       current_task() and next_task() are both zero only when there
 344 #       are no more queued tasks, which is when a new test is
 345 #       started.
 346 #
 347 #       Each connection's current test is stored in its
 348 #       "current_test_address" option.  The next test to execute is
 349 #       calculated by walking the declarative tree of tests.  This
 350 #       option begins empty; the "next test" after this is of course
 351 #       the root test.
 352 #
 353 sub check {
 354     my $this = shift();
 355
 356     my $topname = $this->{tree}->name();
 357     my $timeout = "ZOOM::IRSpy::Test::$topname"->timeout();
 358     $this->log("irspy", "beginnning with test '$topname' (timeout $timeout)");
 359
 360     my $nskipped = 0;
 361     my @conn = @{ $this->{connections} };
 362
 363     my $nruns = 0;
 364   ROUND_AND_ROUND_WE_GO:
 365     while (1) {
 366         my @copy_conn = @conn;  # avoid alias problems after splice()
 367         my $nconn = scalar(@copy_conn);
 368         foreach my $i0 (0 .. $#copy_conn) {
 369             my $conn = $copy_conn[$i0];
 370             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 371             next if !defined $conn;
 372             if (!$conn->current_task()) {
 373                 if (!$conn->next_task()) {
 374                     # Out of tasks: we need a new test
 375                   NEXT_TEST:
 376                     my $address = $conn->option("current_test_address");
 377                     my $nextaddr;
 378                     if (!defined $address) {
 379                         $nextaddr = "";
 380                     } else {
 381                         $conn->log("irspy_test",
 382                                    "checking for next test after '$address'");
 383                         $nextaddr = $this->_next_test($address);
 384                     }
 385                     if (!defined $nextaddr) {
 386                         $conn->log("irspy", "has no more tests: removing");
 387                         $this->_rewrite_record($conn);
 388                         $conn->option(rewrote_record => 1);
 389                         if (@{ $this->{queue} } == 0) {
 390                             # Do not destroy: we need this for later sanity checks
 391                             splice @conn, $i0, 1;
 392                         } else {
 393                             $conn->destroy();
 394                             $conn[$i0] = create
 395                                 ZOOM::IRSpy::Connection($this,
 396                                         shift @{ $this->{queue} }, async => 1,
 397                                                         timeout => $timeout);
 398                             $conn[$i0]->option(current_test_address => "");
 399                             $conn[$i0]->log("irspy", "entering active pool - ",
 400                                             scalar(@{ $this->{queue} }),
 401                                             " targets remain in queue");
 402                         }
 403                         next;
 404                     }
 405
 406                     my $node = $this->{tree}->select($nextaddr)
 407                         or die "invalid nextaddr '$nextaddr'";
 408                     $conn->option(current_test_address => $nextaddr);
 409                     my $tname = $node->name();
 410                     $conn->log("irspy_test",
 411                                "starting test '$nextaddr' = $tname");
 412                     my $tasks = $conn->tasks();
 413                     my $oldcount = @$tasks;
 414                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 415                     $tasks = $conn->tasks();
 416                     if (@$tasks > $oldcount) {
 417                         # Prepare to start the first of the newly added tasks
 418                         $conn->next_task($tasks->[$oldcount]);
 419                     } else {
 420                         $conn->log("irspy_task",
 421                                    "no tasks added by new test $tname");
 422                         goto NEXT_TEST;
 423                     }
 424                 }
 425
 426                 my $task = $conn->next_task();
 427                 die "no next task queued for $conn" if !defined $task;
 428                 $conn->log("irspy_task", "preparing task $task");
 429                 $conn->next_task(0);
 430                 $conn->current_task($task);
 431                 $task->run();
 432             }
 433         }
 434
 435       NEXT_EVENT:
 436         my $i0 = ZOOM::event(\@conn);
 437         $this->log("irspy_event",
 438                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 439         if ($i0 < 1) {
 440             my %messages = (
 441                             0 => "no events remain",
 442                             -1 => "ZOOM::event() argument not a reference",
 443                             -2 => "ZOOM::event() reference not an array",
 444                             -3 => "no connections remain",
 445                             -4 => "too many connections for ZOOM::event()",
 446                             );
 447             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 448             $this->log("irspy", $message);
 449             last;
 450         }
 451
 452         my $conn = $conn[$i0-1];
 453         my $ev = $conn->last_event();
 454         my $evstr = ZOOM::event_str($ev);
 455         $conn->log("irspy_event", "event $ev ($evstr)");
 456         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 457
 458         my $task = $conn->current_task();
 459         die "$conn has no current task for event $ev ($evstr)" if !$task;
 460
 461         my $res;
 462         eval { $conn->check() };
 463         if ($@ && ref $@ && $@->isa("ZOOM::Exception")) {
 464             my $sub = $task->{cb}->{exception};
 465             die $@ if !defined $sub;
 466             $res = &$sub($conn, $task, $task->udata(), $@);
 467         } elsif ($@) {
 468             die "Unexpected non-ZOOM exception: " . ref($@) . " ($@)";
 469         } else {
 470             my $sub = $task->{cb}->{$ev};
 471             if (!defined $sub) {
 472                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 473                 next;
 474             }
 475
 476             $res = &$sub($conn, $task, $task->udata(), $ev);
 477         }
 478
 479         if ($res == ZOOM::IRSpy::Status::OK) {
 480             # Nothing to do -- life continues
 481
 482         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 483             my $task = $conn->current_task();
 484             die "no task for TASK_DONE on $conn" if !$task;
 485             die "next task already defined for $conn" if $conn->next_task();
 486             $conn->log("irspy_task", "completed task $task");
 487             $conn->next_task($task->{next});
 488             $conn->current_task(0);
 489
 490         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 491                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 492             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 493             $conn->log("irspy_task", "test ended during task $task ($x)");
 494             $conn->log("irspy_test", "test completed ($x)");
 495             $conn->current_task(0);
 496             $conn->next_task(0);
 497             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 498                 my $address = $conn->option('current_test_address');
 499                 $conn->log("irspy", "top-level test failed!")
 500                     if $address eq "";
 501                 my $node = $this->{tree}->select($address);
 502                 my $skipcount = 0;
 503                 while (defined $node->next() &&
 504                        length($node->next()->address()) >= length($address)) {
 505                     $conn->log("irspy_debug", "skipping from '",
 506                                $node->address(), "' to '",
 507                                $node->next()->address(), "'");
 508                     $node = $node->next();
 509                     $skipcount++;
 510                 }
 511
 512                 $conn->option(current_test_address => $node->address());
 513                 $conn->log("irspy_test", "skipped $skipcount tests");
 514                 $nskipped += $skipcount;
 515             }
 516
 517         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 518             $conn->log("irspy_test", "test skipped during task $task");
 519             $conn->current_task(0);
 520             $conn->next_task(0);
 521             $nskipped++;
 522
 523         } else {
 524             die "unknown callback return-value '$res'";
 525         }
 526     }
 527
 528     $this->log("irspy", "exiting main loop");
 529
 530     # Sanity checks: none of the following should ever happen
 531     my $finished = 1;
 532     $this->log("irspy", "performing end-of-run sanity-checks");
 533     foreach my $conn (@conn) {
 534         my $test = $conn->option("current_test_address");
 535         my $next = $this->_next_test($test);
 536         if (defined $next) {
 537             $this->log("irspy",
 538                        "$conn (in test '$test') has queued test '$next'");
 539             $finished = 0;
 540         }
 541         if (my $task = $conn->current_task()) {
 542             $this->log("irspy", "$conn still has an active task $task");
 543             $finished = 0;
 544         }
 545         if (my $task = $conn->next_task()) {
 546             $this->log("irspy", "$conn still has a queued task $task");
 547             $finished = 0;
 548         }
 549         if (!$conn->is_idle()) {
 550             $this->log("irspy",
 551                        "$conn still has ZOOM-C level tasks queued: see below");
 552             $finished = 0;
 553         }
 554         my $ev = $conn->peek_event();
 555         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 556             my $evstr = ZOOM::event_str($ev);
 557             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 558             $finished = 0;
 559         }
 560         if (!$conn->option("rewrote_record")) {
 561             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 562             $finished = 0;
 563         }
 564     }
 565
 566     # This really shouldn't be necessary, and in practice it rarely
 567     # helps, but it's belt and braces.  (For now, we don't do this
 568     # hence the zero in the $nruns check).
 569     if (!$finished) {
 570         if (++$nruns < 0) {
 571             $this->log("irspy", "back into main loop, ${nruns}th time");
 572             goto ROUND_AND_ROUND_WE_GO;
 573         } else {
 574             $this->log("irspy", "bailing after $nruns main-loop runs");
 575         }
 576     }
 577
 578     # This shouldn't happen emit anything either:
 579     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 580         my $conn = $conn[$i1-1];
 581         my $ev = $conn->last_event();
 582         my $evstr = ZOOM::event_str($ev);
 583         $this->log("irspy",
 584                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 585             if $ev != ZOOM::Event::ZEND;
 586     }
 587
 588     return $nskipped;
 589 }
 590
 591
 592 # Exactly equivalent to ZOOM::event() except that it is tolerant to
 593 # undefined values in the array being passed in.
 594 #
 595 sub __UNUSED_tolerant_ZOOM_event {
 596     my($connref) = @_;
 597
 598     my(@conn, @map);
 599     foreach my $i (0 .. @$connref-1) {
 600         my $conn = $connref->[$i];
 601         if (defined $conn) {
 602             push @conn, $conn;
 603             push @map, $i;
 604         }
 605     }
 606
 607     my $res = ZOOM::event(\@conn);
 608     return $res if $res <= 0;
 609     my $res2 = $map[$res-1] + 1;
 610     print STDERR "*** tolerant_ZOOM_event() returns $res->$res2\n";
 611     return $res2;
 612 }
 613
 614
 615 sub _gather_tests {
 616     my $this = shift();
 617     my($tname, @ancestors) = @_;
 618
 619     die("$0: test-hierarchy loop detected: " .
 620         join(" -> ", @ancestors, $tname))
 621         if grep { $_ eq $tname } @ancestors;
 622
 623     my $slashSeperatedTname = $tname;
 624     $slashSeperatedTname =~ s/::/\//g;
 625     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 626
 627     eval {
 628         require $fullName;
 629     }; if ($@) {
 630         $this->log("irspy", "couldn't require '$fullName': $@");
 631         $this->log("warn", "can't load test '$tname': skipping",
 632                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 633         return undef;
 634     }
 635
 636     $this->log("irspy", "adding test '$tname'");
 637     my @subnodes;
 638     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 639         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 640         push @subnodes, $subtest if defined $subtest;
 641     }
 642
 643     return new ZOOM::IRSpy::Node($tname, @subnodes);
 644 }
 645
 646
 647 # These next three should arguably be Node methods
 648 sub _next_test {
 649     my $this = shift();
 650     my($address, $omit_child) = @_;
 651
 652     # Try first child
 653     if (!$omit_child) {
 654         my $maybe = $address eq "" ? "0" : "$address:0";
 655         return $maybe if $this->{tree}->select($maybe);
 656     }
 657
 658     # The top-level node has no successor or parent
 659     return undef if $address eq "";
 660
 661     # Try next sibling child
 662     my @components = split /:/, $address;
 663     my $last = pop @components;
 664     my $maybe = join(":", @components, $last+1);
 665     return $maybe if $this->{tree}->select($maybe);
 666
 667     # This node is exhausted: try the parent's successor
 668     return $this->_next_test(join(":", @components), 1)
 669 }
 670
 671
 672 sub _last_sibling_test {
 673     my $this = shift();
 674     my($address) = @_;
 675
 676     return undef
 677         if !defined $this->_next_sibling_test($address);
 678
 679     my $nskipped = 0;
 680     while (1) {
 681         my $maybe = $this->_next_sibling_test($address);
 682         last if !defined $maybe;
 683         $nskipped++;
 684         $address = $maybe;
 685         $this->log("irspy", "skipping $nskipped tests to '$address'");
 686     }
 687
 688     return ($address, $nskipped);
 689 }
 690
 691
 692 sub _next_sibling_test {
 693     my $this = shift();
 694     my($address) = @_;
 695
 696     my @components = split /:/, $address;
 697     my $last = pop @components;
 698     my $maybe = join(":", @components, $last+1);
 699     return $maybe if $this->{tree}->select($maybe);
 700     return undef;
 701 }
 702
 703
 704 =head1 SEE ALSO
 705
 706 ZOOM::IRSpy::Record,
 707 ZOOM::IRSpy::Web,
 708 ZOOM::IRSpy::Test,
 709 ZOOM::IRSpy::Maintenance.
 710
 711 The ZOOM-Perl module,
 712 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 713
 714 The Zebra Database,
 715 http://indexdata.com/zebra/
 716
 717 =head1 AUTHOR
 718
 719 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 720
 721 =head1 COPYRIGHT AND LICENSE
 722
 723 Copyright (C) 2006 by Index Data ApS.
 724
 725 This library is free software; you can redistribute it and/or modify
 726 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 727 at your option, any later version of Perl 5 you may have available.
 728
 729 =cut
 730
 731
 732 1;