lib/ZOOM/IRSpy.pm

   1 # $Id: IRSpy.pm,v 1.76 2007-03-10 13:02:36 mike Exp $
   2
   3 package ZOOM::IRSpy;
   4
   5 use 5.008;
   6 use strict;
   7 use warnings;
   8
   9 use Data::Dumper;               # For debugging only
  10 use File::Basename;
  11 use XML::LibXSLT;
  12 use XML::LibXML;
  13 use XML::LibXML::XPathContext;
  14 use ZOOM;
  15 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  16 use ZOOM::IRSpy::Node;
  17 use ZOOM::IRSpy::Connection;
  18 use ZOOM::IRSpy::Stats;
  19 use ZOOM::IRSpy::Utils qw(cql_target render_record);
  20
  21 our @ISA = qw();
  22 our $VERSION = '0.02';
  23 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  24
  25
  26 # Enumeration for callback functions to return
  27 package ZOOM::IRSpy::Status;
  28 sub OK { 29 }                   # No problems, task is still progressing
  29 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  30 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  31 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  32 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  33 package ZOOM::IRSpy;
  34
  35
  36 =head1 NAME
  37
  38 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  39
  40 =head1 SYNOPSIS
  41
  42  use ZOOM::IRSpy;
  43  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  44  $spy->targets(@targets);
  45  $spy->initialise();
  46  $res = $spy->check("Main");
  47
  48 =head1 DESCRIPTION
  49
  50 This module exists to implement the IRspy program, which discovers,
  51 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  52 protocols.  It is a successor to the ZSpy program.
  53
  54 =cut
  55
  56 BEGIN {
  57     ZOOM::Log::mask_str("irspy");
  58     ZOOM::Log::mask_str("irspy_debug");
  59     ZOOM::Log::mask_str("irspy_event");
  60     ZOOM::Log::mask_str("irspy_unhandled");
  61     ZOOM::Log::mask_str("irspy_test");
  62     ZOOM::Log::mask_str("irspy_task");
  63 }
  64
  65 sub new {
  66     my $class = shift();
  67     my($dbname, $user, $password, $activeSetSize) = @_;
  68
  69     my @options;
  70     push @options, (user => $user, password => $password)
  71         if defined $user;
  72
  73     my $conn = new ZOOM::Connection($dbname, 0, @options)
  74         or die "$0: can't connection to IRSpy database 'dbname'";
  75
  76     my $xslt = new XML::LibXSLT;
  77
  78     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  79                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  80
  81     my $libxml = new XML::LibXML;
  82     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  83     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  84
  85     my $this = bless {
  86         conn => $conn,
  87         query => "cql.allRecords=1", # unless overridden
  88         targets => undef,       # Filled in later if targets() is
  89                                 # called; used only to keep state from
  90                                 # targets() until initialise() is
  91                                 # called.
  92         connections => undef,   # Filled in by initialise()
  93         queue => undef,         # Filled in by initialise()
  94         libxml => $libxml,
  95         irspy_to_zeerex_style => $irspy_to_zeerex_style,
  96         tests => undef,         # Tree of tests to be executed
  97         activeSetSize => defined $activeSetSize ? $activeSetSize : 10,
  98     }, $class;
  99     $this->log("irspy", "starting up with database '$dbname'");
 100
 101     return $this;
 102 }
 103
 104
 105 sub log {
 106     my $this = shift();
 107     ZOOM::Log::log(@_);
 108 }
 109
 110
 111 sub find_targets {
 112     my $this = shift();
 113     my($query) = @_;
 114
 115     $this->{query} = $query;
 116 }
 117
 118
 119 # Explicitly nominate a set of targets to check, overriding the
 120 # default which is to re-check everything in the database.  Each
 121 # target already in the database results in the existing record being
 122 # updated; each new target causes a new record to be added.
 123 #
 124 sub targets {
 125     my $this = shift();
 126     my(@targets) = @_;
 127
 128     $this->log("irspy", "setting explicit list of targets ",
 129                join(", ", map { "'$_'" } @targets));
 130     my @qlist;
 131     foreach my $target (@targets) {
 132         my($host, $port, $db, $newtarget) = _parse_target_string($target);
 133         if ($newtarget ne $target) {
 134             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 135             $target = $newtarget; # This is written through the ref
 136         }
 137         push @qlist, cql_target($host, $port, $db);
 138     }
 139
 140     $this->{targets} = \@targets;
 141     $this->{query} = join(" or ", @qlist);
 142 }
 143
 144
 145 # Also used by ZOOM::IRSpy::Record
 146 sub _parse_target_string {
 147     my($target) = @_;
 148
 149     my($host, $port, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 150     if (!defined $host) {
 151         $port = 210;
 152         ($host, $db) = ($target =~ /(.*?)\/(.*)/);
 153         $target = "$host:$port/$db";
 154     }
 155     die "$0: invalid target string '$target'"
 156         if !defined $host;
 157
 158     return ($host, $port, $db, $target);
 159 }
 160
 161
 162 # Records must be fetched for all records satisfying $this->{query} If
 163 # $this->{targets} is already set (i.e. a specific list of targets to
 164 # check was specified by a call to targets()), then new, empty records
 165 # will be made for any targets that are not already in the database.
 166 #
 167 sub initialise {
 168     my $this = shift();
 169
 170     my @targets;
 171     my $targets = $this->{targets};
 172     if (defined $targets) {
 173         @targets = @$targets;
 174         delete $this->{targets};
 175     } else {
 176         my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 177         $this->log("irspy", "'", $this->{query}, "' found ",
 178                    $rs->size(), " target records");
 179         delete $this->{query};
 180
 181         foreach my $i (1 .. $rs->size()) {
 182             push @targets, render_record($rs, $i-1, "id");
 183         }
 184     }
 185
 186     my $n = $this->{activeSetSize};
 187     $n = @targets if $n == 0 || $n > @targets;
 188
 189     my @connections;
 190     foreach my $i (1..$n) {
 191         push @connections, create ZOOM::IRSpy::Connection($this,
 192                                                           shift @targets,
 193                                                           async => 1);
 194     }
 195
 196     $this->{connections} = \@connections;
 197     $this->{queue} = \@targets;
 198 }
 199
 200
 201 sub _irspy_to_zeerex {
 202     my $this = shift();
 203     my($conn, $save_xml) = @_;
 204     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 205
 206     if ($save_xml) {
 207         unlink('/tmp/irspy_orig.xml');
 208         open FH, '>/tmp/irspy_orig.xml'
 209             or die "can't write irspy_orig.xml: $!";
 210         print FH $irspy_doc->toString();
 211         close FH;
 212     }
 213     my %params = ();
 214     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 215     if ($save_xml) {
 216         unlink('/tmp/irspy_transformed.xml');
 217         open FH, '>/tmp/irspy_transformed.xml'
 218             or die "can't write irspy_transformed.xml: $!";
 219         print FH $result->toString();
 220         close FH;
 221     }
 222
 223     return $result->documentElement();
 224 }
 225
 226
 227 sub _rewrite_record {
 228     my $this = shift();
 229     my($conn) = @_;
 230
 231     $conn->log("irspy", "rewriting XML record");
 232     my $rec = $this->_irspy_to_zeerex($conn, $ENV{IRSPY_SAVE_XML});
 233
 234     # Since IRSpy can run for a long time between writes back to the
 235     # database, it's quite possible for the server to have closed the
 236     # connection as idle.  So re-establish it if necessary.
 237     $conn->connect($conn->option("host"));
 238
 239     _really_rewrite_record($this->{conn}, $rec);
 240     $conn->log("irspy", "rewrote XML record");
 241 }
 242
 243
 244 sub _really_rewrite_record {
 245     my($conn, $rec) = @_;
 246
 247     my $p = $conn->package();
 248     $p->option(action => "specialUpdate");
 249     my $xml = $rec->toString();
 250     $p->option(record => $xml);
 251     $p->send("update");
 252     $p->destroy();
 253
 254     $p = $conn->package();
 255     $p->send("commit");
 256     $p->destroy();
 257     if (0) {
 258         $xml =~ s/&/&amp/g;
 259         $xml =~ s/</&lt;/g;
 260         $xml =~ s/>/&gt;/g;
 261         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 262     }
 263 }
 264
 265
 266 # The approach: gather declarative information about test hierarchy,
 267 # then go into a loop.  In the loop, we ensure that each connection is
 268 # running a test, and within that test a task, until its list of tests
 269 # is exhausted.  No individual test ever calls wait(): tests just queue
 270 # up tasks and return immediately.  When the tasks are run (one at a
 271 # time on each connection) they generate events, and it is these that
 272 # are harvested by ZOOM::event().  Since each connection knows what
 273 # task it is running, it can invoke the appropriate callbacks.
 274 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 275 # loop how to continue.
 276 #
 277 # Invariants:
 278 #       While a connection is running a task, its current_task()
 279 #       points at the task structure.  When it finishes its task,
 280 #       next_task() is pointed at the next task to execute (if there
 281 #       is one), and its current_task() is set to zero.  When the next
 282 #       task is executed, the connection's next_task() is set to zero
 283 #       and its current_task() pointed to the task structure.
 284 #       current_task() and next_task() are both zero only when there
 285 #       are no more queued tasks, which is when a new test is
 286 #       started.
 287 #
 288 #       Each connection's current test is stored in its
 289 #       "current_test_address" option.  The next test to execute is
 290 #       calculated by walking the declarative tree of tests.  This
 291 #       option begins empty; the "next test" after this is of course
 292 #       the root test.
 293 #
 294 sub check {
 295     my $this = shift();
 296     my($tname) = @_;
 297
 298     $tname = "Main" if !defined $tname;
 299     $this->{tree} = $this->_gather_tests($tname)
 300         or die "No tests defined for '$tname'";
 301     $this->{tree}->resolve();
 302     #$this->{tree}->print(0);
 303     my $nskipped = 0;
 304
 305     my @conn = @{ $this->{connections} };
 306
 307     my $nruns = 0;
 308   ROUND_AND_ROUND_WE_GO:
 309     while (1) {
 310         my @copy_conn = @conn;  # avoid alias problems after splice()
 311         my $nconn = scalar(@copy_conn);
 312         foreach my $i0 (0 .. $#copy_conn) {
 313             my $conn = $copy_conn[$i0];
 314             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 315             next if !defined $conn;
 316             if (!$conn->current_task()) {
 317                 if (!$conn->next_task()) {
 318                     # Out of tasks: we need a new test
 319                   NEXT_TEST:
 320                     my $address = $conn->option("current_test_address");
 321                     my $nextaddr;
 322                     if (!defined $address) {
 323                         $nextaddr = "";
 324                     } else {
 325                         $conn->log("irspy_test",
 326                                    "checking for next test after '$address'");
 327                         $nextaddr = $this->_next_test($address);
 328                     }
 329                     if (!defined $nextaddr) {
 330                         $conn->log("irspy", "has no more tests: removing");
 331                         $this->_rewrite_record($conn);
 332                         $conn->option(rewrote_record => 1);
 333                         if (@{ $this->{queue} } == 0) {
 334                             # Do not destroy: we need this for later sanity checks
 335                             splice @conn, $i0, 1;
 336                         } else {
 337                             $conn->destroy();
 338                             $conn[$i0] = create
 339                                 ZOOM::IRSpy::Connection($this,
 340                                         shift @{ $this->{queue} }, async => 1);
 341                             $conn[$i0]->option(current_test_address => "");
 342                             $conn[$i0]->log("irspy", "entering active pool - ",
 343                                             scalar(@{ $this->{queue} }),
 344                                             " targets remain in queue");
 345                         }
 346                         next;
 347                     }
 348
 349                     my $node = $this->{tree}->select($nextaddr)
 350                         or die "invalid nextaddr '$nextaddr'";
 351                     $conn->option(current_test_address => $nextaddr);
 352                     my $tname = $node->name();
 353                     $conn->log("irspy_test",
 354                                "starting test '$nextaddr' = $tname");
 355                     my $tasks = $conn->tasks();
 356                     my $oldcount = @$tasks;
 357                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 358                     $tasks = $conn->tasks();
 359                     if (@$tasks > $oldcount) {
 360                         # Prepare to start the first of the newly added tasks
 361                         $conn->next_task($tasks->[$oldcount]);
 362                     } else {
 363                         $conn->log("irspy_task",
 364                                    "no tasks added by new test $tname");
 365                         goto NEXT_TEST;
 366                     }
 367                 }
 368
 369                 my $task = $conn->next_task();
 370                 die "no next task queued for $conn" if !defined $task;
 371                 $conn->log("irspy_task", "preparing task $task");
 372                 $conn->next_task(0);
 373                 $conn->current_task($task);
 374                 $task->run();
 375             }
 376         }
 377
 378       NEXT_EVENT:
 379         my $i0 = ZOOM::event(\@conn);
 380         $this->log("irspy_event",
 381                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 382         if ($i0 < 1) {
 383             my %messages = (
 384                             0 => "no events remain",
 385                             -1 => "ZOOM::event() argument not a reference",
 386                             -2 => "ZOOM::event() reference not an array",
 387                             -3 => "no connections remain",
 388                             -4 => "too many connections for ZOOM::event()",
 389                             );
 390             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 391             $this->log("irspy", $message);
 392             last;
 393         }
 394
 395         my $conn = $conn[$i0-1];
 396         my $ev = $conn->last_event();
 397         my $evstr = ZOOM::event_str($ev);
 398         $conn->log("irspy_event", "event $ev ($evstr)");
 399         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 400
 401         my $task = $conn->current_task();
 402         die "$conn has no current task for event $ev ($evstr)" if !$task;
 403
 404         my $res;
 405         eval { $conn->check() };
 406         if ($@ && ref $@ && $@->isa("ZOOM::Exception")) {
 407             my $sub = $task->{cb}->{exception};
 408             die $@ if !defined $sub;
 409             $res = &$sub($conn, $task, $task->udata(), $@);
 410         } elsif ($@) {
 411             die "Unexpected non-ZOOM exception: " . ref($@) . " ($@)";
 412         } else {
 413             my $sub = $task->{cb}->{$ev};
 414             if (!defined $sub) {
 415                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 416                 next;
 417             }
 418
 419             $res = &$sub($conn, $task, $task->udata(), $ev);
 420         }
 421
 422         if ($res == ZOOM::IRSpy::Status::OK) {
 423             # Nothing to do -- life continues
 424
 425         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 426             my $task = $conn->current_task();
 427             die "no task for TASK_DONE on $conn" if !$task;
 428             die "next task already defined for $conn" if $conn->next_task();
 429             $conn->log("irspy_task", "completed task $task");
 430             $conn->next_task($task->{next});
 431             $conn->current_task(0);
 432
 433         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 434                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 435             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 436             $conn->log("irspy_task", "test ended during task $task ($x)");
 437             $conn->log("irspy_test", "test completed ($x)");
 438             $conn->current_task(0);
 439             $conn->next_task(0);
 440             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 441                 my $address = $conn->option('current_test_address');
 442                 $conn->log("irspy", "top-level test failed!")
 443                     if $address eq "";
 444                 my $node = $this->{tree}->select($address);
 445                 my $skipcount = 0;
 446                 while (defined $node->next() &&
 447                        length($node->next()->address()) >= length($address)) {
 448                     $conn->log("irspy_debug", "skipping from '",
 449                                $node->address(), "' to '",
 450                                $node->next()->address(), "'");
 451                     $node = $node->next();
 452                     $skipcount++;
 453                 }
 454
 455                 $conn->option(current_test_address => $node->address());
 456                 $conn->log("irspy_test", "skipped $skipcount tests");
 457                 $nskipped += $skipcount;
 458             }
 459
 460         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 461             $conn->log("irspy_test", "test skipped during task $task");
 462             $conn->current_task(0);
 463             $conn->next_task(0);
 464             $nskipped++;
 465
 466         } else {
 467             die "unknown callback return-value '$res'";
 468         }
 469     }
 470
 471     $this->log("irspy", "exiting main loop");
 472     return $nskipped;           # Sanity-checks don't work if conns are closed
 473
 474     # Sanity checks: none of the following should ever happen
 475     my $finished = 1;
 476     @conn = @{ $this->{connections} };
 477     foreach my $conn (@conn) {
 478         my $test = $conn->option("current_test_address");
 479         my $next = $this->_next_test($test);
 480         if (defined $next) {
 481             $this->log("irspy",
 482                        "$conn (in test '$test') has queued test '$next'");
 483             $finished = 0;
 484         }
 485         if (my $task = $conn->current_task()) {
 486             $this->log("irspy", "$conn still has an active task $task");
 487             $finished = 0;
 488         }
 489         if (my $task = $conn->next_task()) {
 490             $this->log("irspy", "$conn still has a queued task $task");
 491             $finished = 0;
 492         }
 493         if (!$conn->is_idle()) {
 494             $this->log("irspy",
 495                        "$conn still has ZOOM-C level tasks queued: see below");
 496             $finished = 0;
 497         }
 498         my $ev = $conn->peek_event();
 499         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 500             my $evstr = ZOOM::event_str($ev);
 501             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 502             $finished = 0;
 503         }
 504         if (!$conn->option("rewrote_record")) {
 505             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 506             $finished = 0;
 507         }
 508     }
 509
 510     # This really shouldn't be necessary, and in practice it rarely
 511     # helps, but it's belt and braces.  (For now, we don't do this
 512     # hence the zero in the $nruns check).
 513     if (!$finished) {
 514         if (++$nruns < 0) {
 515             $this->log("irspy", "back into main loop, ${nruns}th time");
 516             goto ROUND_AND_ROUND_WE_GO;
 517         } else {
 518             $this->log("irspy", "bailing after $nruns main-loop runs");
 519         }
 520     }
 521
 522     # This shouldn't happen emit anything either:
 523     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 524         my $conn = $conn[$i1-1];
 525         my $ev = $conn->last_event();
 526         my $evstr = ZOOM::event_str($ev);
 527         $this->log("irspy",
 528                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 529             if $ev != ZOOM::Event::ZEND;
 530     }
 531
 532     return $nskipped;
 533 }
 534
 535
 536 # Exactly equivalent to ZOOM::event() except that it is tolerant to
 537 # undefined values in the array being passed in.
 538 #
 539 sub __UNUSED_tolerant_ZOOM_event {
 540     my($connref) = @_;
 541
 542     my(@conn, @map);
 543     foreach my $i (0 .. @$connref-1) {
 544         my $conn = $connref->[$i];
 545         if (defined $conn) {
 546             push @conn, $conn;
 547             push @map, $i;
 548         }
 549     }
 550
 551     my $res = ZOOM::event(\@conn);
 552     return $res if $res <= 0;
 553     my $res2 = $map[$res-1] + 1;
 554     print STDERR "*** tolerant_ZOOM_event() returns $res->$res2\n";
 555     return $res2;
 556 }
 557
 558
 559 sub _gather_tests {
 560     my $this = shift();
 561     my($tname, @ancestors) = @_;
 562
 563     die("$0: test-hierarchy loop detected: " .
 564         join(" -> ", @ancestors, $tname))
 565         if grep { $_ eq $tname } @ancestors;
 566
 567     my $slashSeperatedTname = $tname;
 568     $slashSeperatedTname =~ s/::/\//g;
 569     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 570
 571     eval {
 572         require $fullName;
 573         $this->log("irspy", "successfully required '$fullName'");
 574     }; if ($@) {
 575         $this->log("irspy", "couldn't require '$fullName': $@");
 576         $this->log("warn", "can't load test '$tname': skipping",
 577                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 578         return undef;
 579     }
 580
 581     $this->log("irspy", "adding test '$tname'");
 582     my @subnodes;
 583     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 584         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 585         push @subnodes, $subtest if defined $subtest;
 586     }
 587
 588     return new ZOOM::IRSpy::Node($tname, @subnodes);
 589 }
 590
 591
 592 # These next three should arguably be Node methods
 593 sub _next_test {
 594     my $this = shift();
 595     my($address, $omit_child) = @_;
 596
 597     # Try first child
 598     if (!$omit_child) {
 599         my $maybe = $address eq "" ? "0" : "$address:0";
 600         return $maybe if $this->{tree}->select($maybe);
 601     }
 602
 603     # The top-level node has no successor or parent
 604     return undef if $address eq "";
 605
 606     # Try next sibling child
 607     my @components = split /:/, $address;
 608     my $last = pop @components;
 609     my $maybe = join(":", @components, $last+1);
 610     return $maybe if $this->{tree}->select($maybe);
 611
 612     # This node is exhausted: try the parent's successor
 613     return $this->_next_test(join(":", @components), 1)
 614 }
 615
 616
 617 sub _last_sibling_test {
 618     my $this = shift();
 619     my($address) = @_;
 620
 621     return undef
 622         if !defined $this->_next_sibling_test($address);
 623
 624     my $nskipped = 0;
 625     while (1) {
 626         my $maybe = $this->_next_sibling_test($address);
 627         last if !defined $maybe;
 628         $nskipped++;
 629         $address = $maybe;
 630         $this->log("irspy", "skipping $nskipped tests to '$address'");
 631     }
 632
 633     return ($address, $nskipped);
 634 }
 635
 636
 637 sub _next_sibling_test {
 638     my $this = shift();
 639     my($address) = @_;
 640
 641     my @components = split /:/, $address;
 642     my $last = pop @components;
 643     my $maybe = join(":", @components, $last+1);
 644     return $maybe if $this->{tree}->select($maybe);
 645     return undef;
 646 }
 647
 648
 649 =head1 SEE ALSO
 650
 651 ZOOM::IRSpy::Record,
 652 ZOOM::IRSpy::Web,
 653 ZOOM::IRSpy::Test,
 654 ZOOM::IRSpy::Maintenance.
 655
 656 The ZOOM-Perl module,
 657 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 658
 659 The Zebra Database,
 660 http://indexdata.com/zebra/
 661
 662 =head1 AUTHOR
 663
 664 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 665
 666 =head1 COPYRIGHT AND LICENSE
 667
 668 Copyright (C) 2006 by Index Data ApS.
 669
 670 This library is free software; you can redistribute it and/or modify
 671 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 672 at your option, any later version of Perl 5 you may have available.
 673
 674 =cut
 675
 676
 677 1;