lib/ZOOM/IRSpy.pm

   1
   2 package ZOOM::IRSpy;
   3
   4 use 5.008;
   5 use strict;
   6 use warnings;
   7
   8 use Data::Dumper;               # For debugging only
   9 use File::Basename;
  10 use XML::LibXSLT;
  11 use XML::LibXML;
  12 use XML::LibXML::XPathContext;
  13 use ZOOM;
  14 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  15 use ZOOM::IRSpy::Node;
  16 use ZOOM::IRSpy::Connection;
  17 use ZOOM::IRSpy::Stats;
  18 use ZOOM::IRSpy::Utils qw(cql_target render_record
  19                           irspy_xpath_context irspy_make_identifier
  20                           irspy_record2identifier calc_reliability_stats
  21                           modify_xml_document);
  22
  23 our @ISA = qw();
  24 our $VERSION = '1.02';
  25 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  26 our $debug = 0;
  27 our $xslt_max_depth = 250;
  28 our $max_timeout_errors = 3;
  29
  30
  31 # Enumeration for callback functions to return
  32 package ZOOM::IRSpy::Status;
  33 sub OK { 29 }                   # No problems, task is still progressing
  34 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  35 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  36 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  37 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  38 package ZOOM::IRSpy;
  39
  40
  41 =head1 NAME
  42
  43 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  44
  45 =head1 SYNOPSIS
  46
  47  use ZOOM::IRSpy;
  48  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  49  $spy->targets(@targets);
  50  $spy->initialise("Main");
  51  $res = $spy->check();
  52
  53 =head1 DESCRIPTION
  54
  55 This module exists to implement the IRspy program, which discovers,
  56 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  57 protocols.  It is a successor to the ZSpy program.
  58
  59 =cut
  60
  61 BEGIN {
  62     ZOOM::Log::mask_str("irspy");
  63     ZOOM::Log::mask_str("irspy_debug");
  64     ZOOM::Log::mask_str("irspy_event");
  65     ZOOM::Log::mask_str("irspy_unhandled");
  66     ZOOM::Log::mask_str("irspy_test");
  67     ZOOM::Log::mask_str("irspy_task");
  68 }
  69
  70 sub new {
  71     my $class = shift();
  72     my($dbname, $user, $password, $activeSetSize) = @_;
  73
  74
  75     my @options;
  76     push @options, (user => $user, password => $password)
  77         if defined $user;
  78
  79     my $conn = new ZOOM::Connection($dbname, 0, @options)
  80         or die "$0: can't connection to IRSpy database 'dbname'";
  81
  82     my $xslt = new XML::LibXSLT;
  83
  84     # raise the maximum number of nested template calls and variables/params (default 250)
  85     warn "raise the maximum number of nested template calls: $xslt_max_depth\n" if $debug;
  86     $xslt->max_depth($xslt_max_depth);
  87
  88     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  89                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  90
  91     my $libxml = new XML::LibXML;
  92     warn "use irspy_to_zeerex_xsl xslt sheet: $irspy_to_zeerex_xsl\n" if $debug;
  93     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  94     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  95
  96     my $this = bless {
  97         conn => $conn,
  98         query => "cql.allRecords=1", # unless overridden
  99         modn => undef,          # Filled in by restrict_modulo()
 100         modi => undef,          # Filled in by restrict_modulo()
 101         targets => undef,       # Filled in later if targets() is
 102                                 # called; used only to keep state from
 103                                 # targets() until initialise() is
 104                                 # called.
 105         connections => undef,   # Filled in by initialise()
 106         queue => undef,         # Filled in by initialise()
 107         libxml => $libxml,
 108         irspy_to_zeerex_style => $irspy_to_zeerex_style,
 109         test => undef,          # Filled in by initialise()
 110         timeout => undef,       # Filled in by initialise()
 111         tests => undef,         # Tree of tests to be executed
 112         activeSetSize => defined $activeSetSize ? $activeSetSize : 10,
 113     }, $class;
 114     $this->log("irspy", "starting up with database '$dbname'");
 115
 116     return $this;
 117 }
 118
 119 # wrapper to read the IRSpy database name from environment variable / apache config
 120 sub connect_to_registry {
 121     my %args = @_;
 122
 123     # XXX: we could also handle her: user, password, elementSetName
 124
 125     my $database = $ENV{IRSpyDbName} || "localhost:8018/IR-Explain---1";
 126
 127     return $database;
 128 }
 129
 130 sub log {
 131     my $this = shift();
 132     ZOOM::Log::log(@_);
 133 }
 134
 135
 136 sub find_targets {
 137     my $this = shift();
 138     my($query) = @_;
 139
 140     $this->{query} = $query;
 141 }
 142
 143
 144 # Explicitly nominate a set of targets to check, overriding the
 145 # default which is to re-check everything in the database.  Each
 146 # target already in the database results in the existing record being
 147 # updated; each new target causes a new record to be added.
 148 #
 149 sub targets {
 150     my $this = shift();
 151     my(@targets) = @_;
 152
 153     $this->log("irspy", "setting explicit list of targets ",
 154                join(", ", map { "'$_'" } @targets));
 155     my @qlist;
 156     foreach my $target (@targets) {
 157         my($protocol, $host, $port, $db, $newtarget) =
 158             _parse_target_string($target);
 159         if ($newtarget ne $target) {
 160             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 161             $target = $newtarget; # This is written through the ref
 162         }
 163         push @qlist, cql_target($protocol, $host, $port, $db);
 164     }
 165
 166     $this->{targets} = \@targets;
 167     $this->{query} = join(" or ", @qlist);
 168 }
 169
 170
 171 # Also used by ZOOM::IRSpy::Record
 172 sub _parse_target_string {
 173     my($target) = @_;
 174
 175     my($protocol, $host, $port, $db) = ($target =~ /(.*?):(.*?):(.*?)\/(.*)/);
 176     if (!defined $host) {
 177         $port = 210;
 178         ($protocol, $host, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 179         $target = irspy_make_identifier($protocol, $host, $port, $db);
 180     }
 181     die "$0: invalid target string '$target'"
 182         if !defined $host;
 183
 184     return ($protocol, $host, $port, $db, $target);
 185 }
 186
 187
 188 sub restrict_modulo {
 189     my $this = shift();
 190     my($n, $i) = @_;
 191
 192     $this->{modn} = $n;
 193     $this->{modi} = $i;
 194 }
 195
 196
 197 # Records must be fetched for all records satisfying $this->{query} If
 198 # $this->{targets} is already set (i.e. a specific list of targets to
 199 # check was specified by a call to targets()), then new, empty records
 200 # will be made for any targets that are not already in the database.
 201 #
 202 sub initialise {
 203     my $this = shift();
 204     my($tname) = @_;
 205
 206     $tname = "Main" if !defined $tname;
 207     $this->{test} = $tname;
 208     $this->{tree} = $this->_gather_tests($tname)
 209         or die "No tests defined for '$tname'";
 210     $this->{tree}->resolve();
 211     #$this->{tree}->print(0);
 212
 213     $this->{timeout} = "ZOOM::IRSpy::Test::$tname"->timeout();
 214
 215     my @targets;
 216     my $targets = $this->{targets};
 217     if (defined $targets) {
 218         @targets = @$targets;
 219         delete $this->{targets};
 220     } else {
 221         my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 222         $this->log("irspy", "'", $this->{query}, "' found ",
 223                    $rs->size(), " target records");
 224         delete $this->{query};
 225
 226         foreach my $i (1 .. $rs->size()) {
 227             push @targets, render_record($rs, $i-1, "id");
 228         }
 229     }
 230
 231     my $n = $this->{activeSetSize};
 232     $n = @targets if $n == 0 || $n > @targets;
 233
 234     $this->{queue} = \@targets;
 235     $this->{connections} = [];
 236     while (@{ $this->{connections} } < $n) {
 237         my $conn = $this->_next_connection();
 238         last if !defined $conn;
 239         push @{ $this->{connections} }, $conn;
 240     }
 241 }
 242
 243
 244 sub _next_connection {
 245     my $this = shift();
 246
 247     my $target;
 248     my $n = $this->{modn};
 249     my $i = $this->{modi};
 250     if (!defined $n) {
 251         $target = shift @{ $this->{queue} };
 252         return undef if !defined $target;
 253     } else {
 254         while (1) {
 255             $target = shift @{ $this->{queue} };
 256             return undef if !defined $target;
 257             my $h = _hash($target);
 258             my $hmodn = $h % $n;
 259             last if $hmodn == $i;
 260             #$this->log("irspy", "'$target' hash $h % $n = $hmodn != $i");
 261         }
 262     }
 263
 264     die "oops -- target is undefined" if !defined $target;
 265     return create ZOOM::IRSpy::Connection($this, $target, async => 1,
 266                                           timeout => $this->{timeout});
 267 }
 268
 269
 270 sub _hash {
 271     my($target) = @_;
 272
 273     my $n = 0;
 274     foreach my $s (split //, $target) {
 275         $n += ord($s);
 276     }
 277
 278     return $n;
 279 }
 280
 281
 282 sub _irspy_to_zeerex {
 283     my $this = shift();
 284     my($conn) = @_;
 285
 286     my $save_xml = $ENV{IRSPY_SAVE_XML};
 287     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 288
 289     if ($save_xml) {
 290         unlink('/tmp/irspy_orig.xml');
 291         open FH, '>/tmp/irspy_orig.xml'
 292             or die "can't write irspy_orig.xml: $!";
 293         print FH $irspy_doc->toString();
 294         close FH;
 295     }
 296     my %params = ();
 297     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 298     if ($save_xml) {
 299         unlink('/tmp/irspy_transformed.xml');
 300         open FH, '>/tmp/irspy_transformed.xml'
 301             or die "can't write irspy_transformed.xml: $!";
 302         print FH $result->toString();
 303         close FH;
 304     }
 305
 306     return $result->documentElement();
 307 }
 308
 309
 310 sub _rewrite_irspy_record {
 311     my $this = shift();
 312     my($conn) = @_;
 313
 314     $conn->log("irspy", "rewriting XML record");
 315     my $rec = $this->_irspy_to_zeerex($conn);
 316
 317     # Since IRSpy can run for a long time between writes back to the
 318     # database, it's quite possible for the server to have closed the
 319     # connection as idle.  So re-establish it if necessary.
 320     $this->{conn}->connect($conn->option("host"));
 321
 322     _rewrite_zeerex_record($this->{conn}, $rec);
 323     $conn->log("irspy", "rewrote XML record");
 324 }
 325
 326
 327 my $_reliabilityField = {
 328     reliability => [ reliability => 0,
 329                       "Calculated reliability of server",
 330                       "e:serverInfo/e:reliability" ],
 331 };
 332
 333 sub _rewrite_zeerex_record {
 334     my($conn, $rec, $oldid) = @_;
 335
 336     # Add reliability score
 337     my $xc = irspy_xpath_context($rec);
 338     my($nok, $nall, $percent) = calc_reliability_stats($xc);
 339     modify_xml_document($xc, $_reliabilityField, { reliability => $percent });
 340
 341     my $p = $conn->package();
 342     $p->option(action => "specialUpdate");
 343     my $xml = $rec->toString();
 344     $p->option(record => $xml);
 345     $p->send("update");
 346     $p->destroy();
 347
 348     # This is the expression in the ID-making stylesheet
 349     # ../../zebra/zeerex2id.xsl
 350     my $id = irspy_record2identifier($xc);
 351     if (defined $oldid && $id ne $oldid) {
 352         warn "IDs differ (old='$oldid' new='$id')";
 353         _delete_record($conn, $oldid);
 354     }
 355
 356     $p = $conn->package();
 357     $p->send("commit");
 358     $p->destroy();
 359     if (0) {
 360         $xml =~ s/&/&amp/g;
 361         $xml =~ s/</&lt;/g;
 362         $xml =~ s/>/&gt;/g;
 363         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 364     }
 365 }
 366
 367
 368 sub _delete_record {
 369     my($conn, $id) = @_;
 370
 371     # We can't delete records using recordIdOpaque, since character
 372     # sets are handled differently here in extended services from how
 373     # they are used in the Alvis filter's record-parsing, and so
 374     # non-ASCII characters come out differently in the two contexts.
 375     # Instead, we must send a record whose contents indicate the ID of
 376     # that which we wish to delete.  There are two ways, both
 377     # unsatisfactory: we could either fetch the actual record them
 378     # resubmit it in the deletion request (which wastes a search and a
 379     # fetch) or we could build a record by hand from the parsed-out
 380     # components (which is error-prone and which I am not 100% certain
 381     # will work since the other contents of the record will be
 382     # different).  The former evil seems to be the lesser.
 383
 384     warn "$conn deleting record '$id'";
 385
 386     my $rs = $conn->search(new ZOOM::Query::CQL(cql_target($id)));
 387     die "no such ID '$id'" if $rs->size() == 0;
 388     my $rec = $rs->record(0);
 389     my $xml = $rec->render();
 390
 391     my $p = $conn->package();
 392     $p->option(action => "recordDelete");
 393     $p->option(record => $xml);
 394     $p->send("update");
 395     $p->destroy();
 396
 397     $p = $conn->package();
 398     $p->send("commit");
 399     $p->destroy();
 400 }
 401
 402
 403 # The approach: gather declarative information about test hierarchy,
 404 # then go into a loop.  In the loop, we ensure that each connection is
 405 # running a test, and within that test a task, until its list of tests
 406 # is exhausted.  No individual test ever calls wait(): tests just queue
 407 # up tasks and return immediately.  When the tasks are run (one at a
 408 # time on each connection) they generate events, and it is these that
 409 # are harvested by ZOOM::event().  Since each connection knows what
 410 # task it is running, it can invoke the appropriate callbacks.
 411 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 412 # loop how to continue.
 413 #
 414 # Invariants:
 415 #       While a connection is running a task, its current_task()
 416 #       points at the task structure.  When it finishes its task,
 417 #       next_task() is pointed at the next task to execute (if there
 418 #       is one), and its current_task() is set to zero.  When the next
 419 #       task is executed, the connection's next_task() is set to zero
 420 #       and its current_task() pointed to the task structure.
 421 #       current_task() and next_task() are both zero only when there
 422 #       are no more queued tasks, which is when a new test is
 423 #       started.
 424 #
 425 #       Each connection's current test is stored in its
 426 #       "current_test_address" option.  The next test to execute is
 427 #       calculated by walking the declarative tree of tests.  This
 428 #       option begins empty; the "next test" after this is of course
 429 #       the root test.
 430 #
 431 sub check {
 432     my $this = shift();
 433
 434     my $topname = $this->{tree}->name();
 435     my $timeout = $this->{timeout};
 436     $this->log("irspy", "beginnning with test '$topname' (timeout $timeout)");
 437
 438     my $nskipped = 0;
 439     my @conn = @{ $this->{connections} };
 440
 441     my $nruns = 0;
 442   ROUND_AND_ROUND_WE_GO:
 443     while (1) {
 444         my @copy_conn = @conn;  # avoid alias problems after splice()
 445         my $nconn = scalar(@copy_conn);
 446
 447         foreach my $i0 (0 .. $#copy_conn) {
 448             my $conn = $copy_conn[$i0];
 449             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 450             next if !defined $conn;
 451
 452             if (!$conn->current_task()) {
 453                 if (!$conn->next_task()) {
 454                     # Out of tasks: we need a new test
 455                   NEXT_TEST:
 456                     my $address = $conn->option("current_test_address");
 457                     my $nextaddr;
 458                     if (!defined $address) {
 459                         $nextaddr = "";
 460                     } else {
 461                         $conn->log("irspy_test",
 462                                    "checking for next test after '$address'");
 463                         $nextaddr = $this->_next_test($address);
 464                     }
 465
 466                     if (ZOOM::IRSpy::Test::zoom_error_timeout_check($conn)) {
 467                         $conn->log("irspy", "Got to many timeouts, stop testing");
 468                         undef $nextaddr;
 469                     }
 470
 471                     if (!defined $nextaddr) {
 472                         $conn->log("irspy", "has no more tests: removing");
 473                         $this->_rewrite_irspy_record($conn);
 474                         $conn->option(rewrote_record => 1);
 475                         my $newconn = $this->_next_connection();
 476                         if (!defined $newconn) {
 477                             # Do not destroy: needed for later sanity checks
 478                             splice @conn, $i0, 1;
 479                         } else {
 480                             $conn->destroy();
 481                             $conn[$i0] = $newconn;
 482                             $conn[$i0]->option(current_test_address => "");
 483                             $conn[$i0]->log("irspy", "entering active pool - ",
 484                                             scalar(@{ $this->{queue} }),
 485                                             " targets remain in queue");
 486                         }
 487                         next;
 488                     }
 489
 490                     my $node = $this->{tree}->select($nextaddr)
 491                         or die "invalid nextaddr '$nextaddr'";
 492                     $conn->option(current_test_address => $nextaddr);
 493                     my $tname = $node->name();
 494                     $conn->log("irspy_test",
 495                                "starting test '$nextaddr' = $tname");
 496                     my $tasks = $conn->tasks();
 497                     my $oldcount = @$tasks;
 498                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 499                     $tasks = $conn->tasks();
 500                     if (@$tasks > $oldcount) {
 501                         # Prepare to start the first of the newly added tasks
 502                         $conn->next_task($tasks->[$oldcount]);
 503                     } else {
 504                         $conn->log("irspy_task",
 505                                    "no tasks added by new test $tname");
 506                         goto NEXT_TEST;
 507                     }
 508                 }
 509
 510                 my $task = $conn->next_task();
 511                 die "no next task queued for $conn" if !defined $task;
 512
 513                 # do not run the next task if we got too many timeouts
 514                 if (ZOOM::IRSpy::Test::zoom_error_timeout_check($conn)) {
 515                     $conn->log("irspy_task", "Got to many timeouts for this target, do not start a new task");
 516                     next;
 517                 }
 518
 519                 $conn->log("irspy_task", "preparing task $task");
 520                 $conn->next_task(0);
 521                 $conn->current_task($task);
 522                 $task->run();
 523             }
 524         }
 525
 526       NEXT_EVENT:
 527         my $i0 = ZOOM::event(\@conn);
 528         $this->log("irspy_event",
 529                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 530         if ($i0 < 1) {
 531             my %messages = (
 532                             0 => "no events remain",
 533                             -1 => "ZOOM::event() argument not a reference",
 534                             -2 => "ZOOM::event() reference not an array",
 535                             -3 => "no connections remain",
 536                             -4 => "too many connections for ZOOM::event()",
 537                             );
 538             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 539             $this->log("irspy", $message);
 540             last;
 541         }
 542
 543         my $conn = $conn[$i0-1];
 544         my $ev = $conn->last_event();
 545         my $evstr = ZOOM::event_str($ev);
 546         $conn->log("irspy_event", "event $ev ($evstr)");
 547         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 548
 549         my $task = $conn->current_task();
 550         die "$conn has no current task for event $ev ($evstr)" if !$task;
 551
 552         my $res;
 553         eval { $conn->check() };
 554         if ($@ && ref $@ && $@->isa("ZOOM::Exception")) {
 555             my $sub = $task->{cb}->{exception};
 556             die $@ if !defined $sub;
 557             $res = &$sub($conn, $task, $task->udata(), $@);
 558         } elsif ($@) {
 559             die "Unexpected non-ZOOM exception: " . ref($@) . " ($@)";
 560         } else {
 561             my $sub = $task->{cb}->{$ev};
 562             if (!defined $sub) {
 563                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 564                 next;
 565             }
 566
 567             $res = &$sub($conn, $task, $task->udata(), $ev);
 568         }
 569
 570         if ($res == ZOOM::IRSpy::Status::OK) {
 571             # Nothing to do -- life continues
 572
 573         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 574             my $task = $conn->current_task();
 575             die "no task for TASK_DONE on $conn" if !$task;
 576             die "next task already defined for $conn" if $conn->next_task();
 577             $conn->log("irspy_task", "completed task $task");
 578             $conn->next_task($task->{next});
 579             $conn->current_task(0);
 580
 581         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 582                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 583             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 584             $conn->log("irspy_task", "test ended during task $task ($x)");
 585             $conn->log("irspy_test", "test completed ($x)");
 586             $conn->current_task(0);
 587             $conn->next_task(0);
 588             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 589                 my $address = $conn->option('current_test_address');
 590                 $conn->log("irspy", "top-level test failed!")
 591                     if $address eq "";
 592                 my $node = $this->{tree}->select($address);
 593                 my $skipcount = 0;
 594                 while (defined $node->next() &&
 595                        length($node->next()->address()) >= length($address)) {
 596                     $conn->log("irspy_debug", "skipping from '",
 597                                $node->address(), "' to '",
 598                                $node->next()->address(), "'");
 599                     $node = $node->next();
 600                     $skipcount++;
 601                 }
 602
 603                 $conn->option(current_test_address => $node->address());
 604                 $conn->log("irspy_test", "skipped $skipcount tests");
 605                 $nskipped += $skipcount;
 606             }
 607
 608         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 609             $conn->log("irspy_test", "test skipped during task $task");
 610             $conn->current_task(0);
 611             $conn->next_task(0);
 612             $nskipped++;
 613
 614         } else {
 615             die "unknown callback return-value '$res'";
 616         }
 617     }
 618
 619     $this->log("irspy", "exiting main loop");
 620
 621     # Sanity checks: none of the following should ever happen
 622     my $finished = 1;
 623     $this->log("irspy", "performing end-of-run sanity-checks");
 624     foreach my $conn (@conn) {
 625         my $test = $conn->option("current_test_address");
 626         my $next = $this->_next_test($test);
 627         if (defined $next) {
 628             $this->log("irspy",
 629                        "$conn (in test '$test') has queued test '$next'");
 630             $finished = 0;
 631         }
 632         if (my $task = $conn->current_task()) {
 633             $this->log("irspy", "$conn still has an active task $task");
 634             $finished = 0;
 635         }
 636         if (my $task = $conn->next_task()) {
 637             $this->log("irspy", "$conn still has a queued task $task");
 638             $finished = 0;
 639         }
 640         if (!$conn->is_idle()) {
 641             $this->log("irspy",
 642                        "$conn still has ZOOM-C level tasks queued: see below");
 643             $finished = 0;
 644         }
 645         my $ev = $conn->peek_event();
 646         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 647             my $evstr = ZOOM::event_str($ev);
 648             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 649             $finished = 0;
 650         }
 651         if (!$conn->option("rewrote_record")) {
 652             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 653             $finished = 0;
 654         }
 655     }
 656
 657     # This really shouldn't be necessary, and in practice it rarely
 658     # helps, but it's belt and braces.  (For now, we don't do this
 659     # hence the zero in the $nruns check).
 660     if (!$finished) {
 661         if (++$nruns < 0) {
 662             $this->log("irspy", "back into main loop, ${nruns}th time");
 663             goto ROUND_AND_ROUND_WE_GO;
 664         } else {
 665             $this->log("irspy", "bailing after $nruns main-loop runs");
 666         }
 667     }
 668
 669     # This shouldn't happen emit anything either:
 670     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 671         my $conn = $conn[$i1-1];
 672         my $ev = $conn->last_event();
 673         my $evstr = ZOOM::event_str($ev);
 674         $this->log("irspy",
 675                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 676             if $ev != ZOOM::Event::ZEND;
 677     }
 678
 679     return $nskipped;
 680 }
 681
 682
 683 # Exactly equivalent to ZOOM::event() except that it is tolerant to
 684 # undefined values in the array being passed in.
 685 #
 686 sub __UNUSED_tolerant_ZOOM_event {
 687     my($connref) = @_;
 688
 689     my(@conn, @map);
 690     foreach my $i (0 .. @$connref-1) {
 691         my $conn = $connref->[$i];
 692         if (defined $conn) {
 693             push @conn, $conn;
 694             push @map, $i;
 695         }
 696     }
 697
 698     my $res = ZOOM::event(\@conn);
 699     return $res if $res <= 0;
 700     my $res2 = $map[$res-1] + 1;
 701     print STDERR "*** tolerant_ZOOM_event() returns $res->$res2\n";
 702     return $res2;
 703 }
 704
 705
 706 sub _gather_tests {
 707     my $this = shift();
 708     my($tname, @ancestors) = @_;
 709
 710     die("$0: test-hierarchy loop detected: " .
 711         join(" -> ", @ancestors, $tname))
 712         if grep { $_ eq $tname } @ancestors;
 713
 714     my $slashSeperatedTname = $tname;
 715     $slashSeperatedTname =~ s/::/\//g;
 716     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 717
 718     eval {
 719         require $fullName;
 720     }; if ($@) {
 721         $this->log("irspy", "couldn't require '$fullName': $@");
 722         $this->log("warn", "can't load test '$tname': skipping",
 723                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 724         return undef;
 725     }
 726
 727     $this->log("irspy", "adding test '$tname'");
 728     my @subnodes;
 729     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 730         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 731         push @subnodes, $subtest if defined $subtest;
 732     }
 733
 734     return new ZOOM::IRSpy::Node($tname, @subnodes);
 735 }
 736
 737
 738 # These next three should arguably be Node methods
 739 sub _next_test {
 740     my $this = shift();
 741     my($address, $omit_child) = @_;
 742
 743     # Try first child
 744     if (!$omit_child) {
 745         my $maybe = $address eq "" ? "0" : "$address:0";
 746         return $maybe if $this->{tree}->select($maybe);
 747     }
 748
 749     # The top-level node has no successor or parent
 750     return undef if $address eq "";
 751
 752     # Try next sibling child
 753     my @components = split /:/, $address;
 754     my $last = pop @components;
 755     my $maybe = join(":", @components, $last+1);
 756     return $maybe if $this->{tree}->select($maybe);
 757
 758     # This node is exhausted: try the parent's successor
 759     return $this->_next_test(join(":", @components), 1)
 760 }
 761
 762
 763 sub _last_sibling_test {
 764     my $this = shift();
 765     my($address) = @_;
 766
 767     return undef
 768         if !defined $this->_next_sibling_test($address);
 769
 770     my $nskipped = 0;
 771     while (1) {
 772         my $maybe = $this->_next_sibling_test($address);
 773         last if !defined $maybe;
 774         $nskipped++;
 775         $address = $maybe;
 776         $this->log("irspy", "skipping $nskipped tests to '$address'");
 777     }
 778
 779     return ($address, $nskipped);
 780 }
 781
 782
 783 sub _next_sibling_test {
 784     my $this = shift();
 785     my($address) = @_;
 786
 787     my @components = split /:/, $address;
 788     my $last = pop @components;
 789     my $maybe = join(":", @components, $last+1);
 790     return $maybe if $this->{tree}->select($maybe);
 791     return undef;
 792 }
 793
 794
 795 =head1 SEE ALSO
 796
 797 ZOOM::IRSpy::Record,
 798 ZOOM::IRSpy::Web,
 799 ZOOM::IRSpy::Test,
 800 ZOOM::IRSpy::Maintenance.
 801
 802 The ZOOM-Perl module,
 803 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 804
 805 The Zebra Database,
 806 http://indexdata.com/zebra/
 807
 808 =head1 AUTHOR
 809
 810 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 811
 812 =head1 COPYRIGHT AND LICENSE
 813
 814 Copyright (C) 2006 by Index Data ApS.
 815
 816 This library is free software; you can redistribute it and/or modify
 817 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 818 at your option, any later version of Perl 5 you may have available.
 819
 820 =cut
 821
 822
 823 1;