lib/ZOOM/IRSpy.pm

   1 # $Id: IRSpy.pm,v 1.30 2006-10-13 13:41:56 sondberg Exp $
   2
   3 package ZOOM::IRSpy;
   4
   5 use 5.008;
   6 use strict;
   7 use warnings;
   8
   9 use Data::Dumper; # For debugging only
  10 use ZOOM;
  11 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  12 use ZOOM::IRSpy::Node;
  13 use ZOOM::IRSpy::Connection;
  14 use ZOOM::IRSpy::Record;
  15
  16 our @ISA = qw();
  17 our $VERSION = '0.02';
  18 our $irspy_ns = 'http://indexdata.com/irspy/1.0';
  19
  20
  21 # Enumeration for callback functions to return
  22 package ZOOM::IRSpy::Status;
  23 sub OK { 29 }                   # No problems, task is still progressing
  24 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  25 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  26 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  27 package ZOOM::IRSpy;
  28
  29
  30 =head1 NAME
  31
  32 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  33
  34 =head1 SYNOPSIS
  35
  36  use ZOOM::IRSpy;
  37  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  38  print $spy->report_status();
  39
  40 =head1 DESCRIPTION
  41
  42 This module exists to implement the IRspy program, which discovers,
  43 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  44 protocols.  It is a successor to the ZSpy program.
  45
  46 =cut
  47
  48 BEGIN {
  49     ZOOM::Log::mask_str("irspy");
  50     ZOOM::Log::mask_str("irspy_debug");
  51     ZOOM::Log::mask_str("irspy_event");
  52     ZOOM::Log::mask_str("irspy_unhandled");
  53     ZOOM::Log::mask_str("irspy_test");
  54     ZOOM::Log::mask_str("irspy_task");
  55 }
  56
  57 sub new {
  58     my $class = shift();
  59     my($dbname, $user, $password) = @_;
  60
  61     my @options;
  62     push @options, (user => $user, password => $password)
  63         if defined $user;
  64
  65     my $conn = new ZOOM::Connection($dbname, 0, @options)
  66         or die "$0: can't connection to IRSpy database 'dbname'";
  67
  68     my $this = bless {
  69         conn => $conn,
  70         allrecords => 1,        # unless overridden by targets()
  71         query => undef,         # filled in later
  72         targets => undef,       # filled in later
  73         connections => undef,   # filled in later
  74         tests => [],            # stack of tests currently being executed
  75     }, $class;
  76     $this->log("irspy", "starting up with database '$dbname'");
  77
  78     return $this;
  79 }
  80
  81
  82 sub log {
  83     my $this = shift();
  84     ZOOM::Log::log(@_);
  85 }
  86
  87
  88 # Explicitly nominate a set of targets to check, overriding the
  89 # default which is to re-check everything in the database.  Each
  90 # target already in the database results in the existing record being
  91 # updated; each new target causes a new record to be added.
  92 #
  93 sub targets {
  94     my $this = shift();
  95     my(@targets) = @_;
  96
  97     $this->log("irspy", "setting explicit list of targets ",
  98                join(", ", map { "'$_'" } @targets));
  99     $this->{allrecords} = 0;
 100     my @qlist;
 101     foreach my $target (@targets) {
 102         my($host, $port, $db, $newtarget) = _parse_target_string($target);
 103         if ($newtarget ne $target) {
 104             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 105             $target = $newtarget; # This is written through the ref
 106         }
 107         push @qlist, (qq[(host="$host" and port="$port" and path="$db")]);
 108     }
 109
 110     $this->{targets} = \@targets;
 111     $this->{query} = join(" or ", @qlist);
 112 }
 113
 114
 115 # Also used by ZOOM::IRSpy::Record
 116 sub _parse_target_string {
 117     my($target) = @_;
 118
 119     my($host, $port, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 120     if (!defined $host) {
 121         $port = 210;
 122         ($host, $db) = ($target =~ /(.*?)\/(.*)/);
 123         $target = "$host:$port/$db";
 124     }
 125     die "$0: invalid target string '$target'"
 126         if !defined $host;
 127
 128     return ($host, $port, $db, $target);
 129 }
 130
 131
 132 # There are two cases.
 133 #
 134 # 1. A specific set of targets is nominated on the command line.
 135 #       - Records must be fetched for those targets that are in the DB
 136 #       - New, empty records must be made for those that are not.
 137 #       - Updated records written to the DB may or may not be new.
 138 #
 139 # 2. All records in the database are to be checked.
 140 #       - Records must be fetched for all targets in the DB
 141 #       - Updated records written to the DB may not be new.
 142 #
 143 # That's all -- what could be simpler?
 144 #
 145 sub initialise {
 146     my $this = shift();
 147
 148     my %target2record;
 149     if ($this->{allrecords}) {
 150         # We need to check on every target in the database, which
 151         # means we need to do a "find all".  According to the BIB-1
 152         # semantics document at
 153         #       http://www.loc.gov/z3950/agency/bib1.html
 154         # the query
 155         #       @attr 2=103 @attr 1=1035 x
 156         # should find all records, but it seems that Zebra doesn't
 157         # support this.  Furthermore, when using the "alvis" filter
 158         # (as we do for IRSpy) it doesn't support the use of any BIB-1
 159         # access point -- not even 1035 "everywhere" -- so instead we
 160         # hack together a search that we know will find all records.
 161         $this->{query} = "port=?*";
 162     } else {
 163         # Prepopulate the target map with nulls so that after we fill
 164         # in what we can from the database query, we know which target
 165         # IDs we need new records for.
 166         foreach my $target (@{ $this->{targets} }) {
 167             $target2record{lc($target)} = undef;
 168         }
 169     }
 170
 171     $this->log("irspy_debug", "query '", $this->{query}, "'");
 172     my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 173     delete $this->{query};      # No longer needed at all
 174     $this->log("irspy_debug", "found ", $rs->size(), " target records");
 175     foreach my $i (1 .. $rs->size()) {
 176         my $target = _render_record($rs, $i-1, "id");
 177         my $zeerex = _render_record($rs, $i-1, "zeerex");
 178         #print STDERR "making '$target' record with '$zeerex'\n";
 179         $target2record{lc($target)} =
 180             new ZOOM::IRSpy::Record($this, $target, $zeerex);
 181         push @{ $this->{targets} }, $target
 182             if $this->{allrecords};
 183     }
 184
 185     # Make records for targets not previously in the database
 186     foreach my $target (keys %target2record) {
 187         my $record = $target2record{$target};
 188         if (!defined $record) {
 189             $this->log("irspy_debug", "made new record for '$target'");
 190             $target2record{$target} = new ZOOM::IRSpy::Record($this, $target);
 191         } else {
 192             $this->log("irspy_debug", "using existing record for '$target'");
 193         }
 194     }
 195
 196     my @connections;
 197     foreach my $target (@{ $this->{targets} }) {
 198         my $conn = create ZOOM::IRSpy::Connection($this, async => 1);
 199         $conn->option(host => $target);
 200         my $record = delete $target2record{lc($target)};
 201         $conn->record($record);
 202         push @connections, $conn;
 203     }
 204     die("remaining target2record = { " .
 205         join(", ", map { "$_ ->'" . $target2record{$_}. "'" }
 206              sort keys %target2record) . " }")
 207         if %target2record;
 208
 209     $this->{connections} = \@connections;
 210     delete $this->{targets};    # The information is now in {connections}
 211 }
 212
 213
 214 sub _render_record {
 215     my($rs, $which, $elementSetName) = @_;
 216
 217     # There is a slight race condition here on the element-set name,
 218     # but it shouldn't be a problem as this is (currently) only called
 219     # from parts of the program that run single-threaded.
 220     my $old = $rs->option(elementSetName => $elementSetName);
 221     my $rec = $rs->record($which);
 222     $rs->option(elementSetName => $old);
 223
 224     return $rec->render();
 225 }
 226
 227
 228 sub _rewrite_records {
 229     my $this = shift();
 230
 231     # Write modified records back to database
 232     foreach my $conn (@{ $this->{connections} }) {
 233         my $rec = $conn->record();
 234         my $p = $this->{conn}->package();
 235         $p->option(action => "specialUpdate");
 236         my $xml = $rec->{zeerex}->toString();
 237         $p->option(record => $xml);
 238         $p->send("update");
 239         $p->destroy();
 240
 241         $p = $this->{conn}->package();
 242         $p->send("commit");
 243         $p->destroy();
 244         if (0) {
 245             $xml =~ s/&/&amp/g;
 246             $xml =~ s/</&lt;/g;
 247             $xml =~ s/>/&gt;/g;
 248             print "Updated with xml=<br/>\n<pre>$xml</pre>\n";
 249         }
 250     }
 251 }
 252
 253
 254 # The approach: gather declarative information about test hierarchy,
 255 # then go into a loop.  In the loop, we ensure that each connection is
 256 # running a test, and within that test a task, until its list of tests
 257 # is exhausted.  No individual test ever calls wait(): tests just queue
 258 # up tasks and return immediately.  When the tasks are run (one at a
 259 # time on each connection) they generate events, and it is these that
 260 # are harvested by ZOOM::event().  Since each connection knows what
 261 # task it is running, it can invoke the appropriate callbacks.
 262 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 263 # loop how to continue.
 264 #
 265 # Invariants:
 266 #       While a connection is running a task, its current_task()
 267 #       points at the task structure.  When it finishes its task,
 268 #       next_task() is pointed at the next task to execute (if there
 269 #       is one), and its current_task() is set to zero.  When the next
 270 #       task is executed, the connection's next_task() is set to zero
 271 #       and its current_task() pointed to the task structure.
 272 #       current_task() and next_task() are both zero only when there
 273 #       are no more queued tasks, which is when a new test is
 274 #       started.
 275 #
 276 #       Each connection's current test is stored in its
 277 #       "current_test_address" option.  The next test to execute is
 278 #       calculated by walking the declarative tree of tests.  This
 279 #       option begins empty; the "next test" after this is of course
 280 #       the root test.
 281 #
 282 sub check {
 283     my $this = shift();
 284     my($tname) = @_;
 285
 286     $tname = "Main" if !defined $tname;
 287     $this->{tree} = $this->_gather_tests($tname)
 288         or die "No tests defined";
 289     #$this->{tree}->print(0);
 290     my $nskipped = 0;
 291
 292     my @conn = @{ $this->{connections} };
 293
 294     while (1) {
 295         my @copy_conn = @conn;  # avoid alias problems after splice()
 296         foreach my $i0 (0 .. $#copy_conn) {
 297             my $conn = $copy_conn[$i0];
 298             #print "connection $i0 of ", scalar(@copy_conn), " from ", scalar(@conn), " is $conn\n";
 299             if (!$conn->current_task()) {
 300                 if (!$conn->next_task()) {
 301                     # Out of tasks: we need a new test
 302                   NEXT_TEST:
 303                     my $address = $conn->option("current_test_address");
 304                     my $nextaddr;
 305                     if (!defined $address) {
 306                         $nextaddr = "";
 307                     } else {
 308                         $this->log("irspy_test", "checking for next test after '$address'");
 309                         $nextaddr = $this->_next_test($address);
 310                     }
 311                     if (!defined $nextaddr) {
 312                         $conn->log("irspy", "has no more tests: removing");
 313                         splice @conn, $i0, 1;
 314                         next;
 315                     }
 316
 317                     my $node = $this->{tree}->select($nextaddr)
 318                         or die "invalid nextaddr '$nextaddr'";
 319                     $conn->option(current_test_address => $nextaddr);
 320                     my $tname = $node->name();
 321                     $conn->log("irspy_test", "starting test '$nextaddr' = $tname");
 322                     my $tasks = $conn->tasks();
 323                     my $oldcount = @$tasks;
 324                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 325                     $tasks = $conn->tasks();
 326                     if (@$tasks > $oldcount) {
 327                         # Prepare to start the first of the newly added tasks
 328                         $conn->next_task($tasks->[$oldcount]);
 329                     } else {
 330                         $conn->log("irspy_task", "no tasks added by new test $tname");
 331                         goto NEXT_TEST;
 332                     }
 333                 }
 334
 335                 my $task = $conn->next_task();
 336                 die "no next task queued for $conn" if !defined $task;
 337                 $conn->log("irspy_task", "starting task $task");
 338                 $conn->next_task(0);
 339                 $conn->current_task($task);
 340                 $task->run();
 341             }
 342
 343             # Do we need to test $conn->is_idle()?  I don't think so!
 344         }
 345
 346         my $i0 = ZOOM::event(\@conn);
 347         $this->log("irspy_event", "ZOOM_event(", scalar(@conn), " connections) = $i0");
 348         last if $i0 == 0 || $i0 == -3; # no events or no connections
 349         my $conn = $conn[$i0-1];
 350         my $ev = $conn->last_event();
 351         my $evstr = ZOOM::event_str($ev);
 352         $conn->log("irspy_event", "event $ev ($evstr)");
 353
 354         my $task = $conn->current_task();
 355         die "$conn has no current task for event $ev ($evstr)" if !$task;
 356         eval { $conn->_check() };
 357         if ($@ &&
 358             ($ev == ZOOM::Event::RECV_DATA ||
 359              $ev == ZOOM::Event::RECV_APDU ||
 360              $ev == ZOOM::Event::ZEND)) {
 361             # An error in, say, a search response, becomes visible to
 362             # ZOOM before the Receive Data event is sent and persists
 363             # until after the End, which means that successive events
 364             # each report the same error.  So we just ignore errors on
 365             # "unimportant" events.  ### But this doesn't work for,
 366             # say, a Connection Refused, as the only event that shows
 367             # us this error is the End.
 368             $conn->log("irspy_event", "ignoring error ",
 369                        "on event $ev ($evstr): $@");
 370             next;
 371         }
 372
 373         my $res;
 374         if ($@) {
 375             my $sub = $task->{cb}->{exception};
 376             die $@ if !defined $sub;
 377             $res = &$sub($conn, $task, $task->udata(), $@);
 378         } else {
 379             my $sub = $task->{cb}->{$ev};
 380             if (!defined $sub) {
 381                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 382                 next;
 383             }
 384
 385             $res = &$sub($conn, $task, $task->udata(), $ev);
 386         }
 387
 388         if ($res == ZOOM::IRSpy::Status::OK) {
 389             # Nothing to do -- life continues
 390
 391         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 392             my $task = $conn->current_task();
 393             die "no task for TASK_DONE on $conn" if !$task;
 394             die "next task already defined for $conn" if $conn->next_task();
 395             $conn->log("irspy_task", "completed task $task");
 396             $conn->next_task($task->{next});
 397             $conn->current_task(0);
 398
 399         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 400                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 401             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 402             $conn->log("irspy_test", "test completed ($x)");
 403             $conn->current_task(0);
 404             $conn->next_task(0);
 405             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 406                 ### Should skip over remaining sibling tests if TEST_BAD
 407                 ### Should count the number of skipped siblings
 408                 $nskipped += 1;
 409             }
 410         }
 411     }
 412
 413     $this->log("irspy", "exiting main loop");
 414
 415     #$this->_rewrite_records();
 416     return $nskipped;
 417 }
 418
 419
 420 sub _gather_tests {
 421     my $this = shift();
 422     my($tname, @ancestors) = @_;
 423
 424     die("$0: test-hierarchy loop detected: " .
 425         join(" -> ", @ancestors, $tname))
 426         if grep { $_ eq $tname } @ancestors;
 427
 428     eval {
 429         my $slashSeperatedTname = $tname;
 430         $slashSeperatedTname =~ s/::/\//g;
 431         require "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 432     }; if ($@) {
 433         $this->log("warn", "can't load test '$tname': skipping",
 434                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 435         return undef;
 436     }
 437
 438     $this->log("irspy", "adding test '$tname'");
 439     my @subnodes;
 440     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 441         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 442         push @subnodes, $subtest if defined $subtest;
 443     }
 444
 445     return new ZOOM::IRSpy::Node($tname, @subnodes);
 446 }
 447
 448
 449 sub _next_test {
 450     my $this = shift();
 451     my($address, $omit_child) = @_;
 452
 453     # Try first child
 454     if (!$omit_child) {
 455         my $maybe = $address eq "" ? "0" : "$address:0";
 456         return $maybe if $this->{tree}->select($maybe);
 457     }
 458
 459     # The top-level node has no successor or parent
 460     return undef if $address eq "";
 461
 462     # Try next sibling child
 463     my @components = split /:/, $address;
 464     my $last = pop @components;
 465     my $maybe = join(":", @components, $last+1);
 466     return $maybe if $this->{tree}->select($maybe);
 467
 468     # This node is exhausted: try the parent's successor
 469     return $this->_next_test(join(":", @components), 1)
 470 }
 471
 472
 473 =head1 SEE ALSO
 474
 475 ZOOM::IRSpy::Record,
 476 ZOOM::IRSpy::Web,
 477 ZOOM::IRSpy::Test,
 478 ZOOM::IRSpy::Maintenance.
 479
 480 The ZOOM-Perl module,
 481 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 482
 483 The Zebra Database,
 484 http://indexdata.com/zebra/
 485
 486 =head1 AUTHOR
 487
 488 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 489
 490 =head1 COPYRIGHT AND LICENSE
 491
 492 Copyright (C) 2006 by Index Data ApS.
 493
 494 This library is free software; you can redistribute it and/or modify
 495 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 496 at your option, any later version of Perl 5 you may have available.
 497
 498 =cut
 499
 500
 501 1;