lib/ZOOM/IRSpy.pm

   1 # $Id: IRSpy.pm,v 1.80 2007-03-30 09:50:55 mike Exp $
   2
   3 package ZOOM::IRSpy;
   4
   5 use 5.008;
   6 use strict;
   7 use warnings;
   8
   9 use Data::Dumper;               # For debugging only
  10 use File::Basename;
  11 use XML::LibXSLT;
  12 use XML::LibXML;
  13 use XML::LibXML::XPathContext;
  14 use ZOOM;
  15 use Net::Z3950::ZOOM 1.13;      # For the ZOOM version-check only
  16 use ZOOM::IRSpy::Node;
  17 use ZOOM::IRSpy::Connection;
  18 use ZOOM::IRSpy::Stats;
  19 use ZOOM::IRSpy::Utils qw(cql_target render_record irspy_xpath_context);
  20
  21 our @ISA = qw();
  22 our $VERSION = '0.02';
  23 our $irspy_to_zeerex_xsl = dirname(__FILE__) . '/../../xsl/irspy2zeerex.xsl';
  24
  25
  26 # Enumeration for callback functions to return
  27 package ZOOM::IRSpy::Status;
  28 sub OK { 29 }                   # No problems, task is still progressing
  29 sub TASK_DONE { 18 }            # Task is complete, next task should begin
  30 sub TEST_GOOD { 8 }             # Whole test is complete, and succeeded
  31 sub TEST_BAD { 31 }             # Whole test is complete, and failed
  32 sub TEST_SKIPPED { 12 }         # Test couldn't be run
  33 package ZOOM::IRSpy;
  34
  35
  36 =head1 NAME
  37
  38 ZOOM::IRSpy - Perl extension for discovering and analysing IR services
  39
  40 =head1 SYNOPSIS
  41
  42  use ZOOM::IRSpy;
  43  $spy = new ZOOM::IRSpy("target/string/for/irspy/database");
  44  $spy->targets(@targets);
  45  $spy->initialise();
  46  $res = $spy->check("Main");
  47
  48 =head1 DESCRIPTION
  49
  50 This module exists to implement the IRspy program, which discovers,
  51 analyses and monitors IR servers implementing the Z39.50 and SRU/W
  52 protocols.  It is a successor to the ZSpy program.
  53
  54 =cut
  55
  56 BEGIN {
  57     ZOOM::Log::mask_str("irspy");
  58     ZOOM::Log::mask_str("irspy_debug");
  59     ZOOM::Log::mask_str("irspy_event");
  60     ZOOM::Log::mask_str("irspy_unhandled");
  61     ZOOM::Log::mask_str("irspy_test");
  62     ZOOM::Log::mask_str("irspy_task");
  63 }
  64
  65 sub new {
  66     my $class = shift();
  67     my($dbname, $user, $password, $activeSetSize) = @_;
  68
  69     my @options;
  70     push @options, (user => $user, password => $password)
  71         if defined $user;
  72
  73     my $conn = new ZOOM::Connection($dbname, 0, @options)
  74         or die "$0: can't connection to IRSpy database 'dbname'";
  75
  76     my $xslt = new XML::LibXSLT;
  77
  78     $xslt->register_function($ZOOM::IRSpy::Utils::IRSPY_NS, 'strcmp',
  79                              \&ZOOM::IRSpy::Utils::xslt_strcmp);
  80
  81     my $libxml = new XML::LibXML;
  82     my $xsl_doc = $libxml->parse_file($irspy_to_zeerex_xsl);
  83     my $irspy_to_zeerex_style = $xslt->parse_stylesheet($xsl_doc);
  84
  85     my $this = bless {
  86         conn => $conn,
  87         query => "cql.allRecords=1", # unless overridden
  88         targets => undef,       # Filled in later if targets() is
  89                                 # called; used only to keep state from
  90                                 # targets() until initialise() is
  91                                 # called.
  92         connections => undef,   # Filled in by initialise()
  93         queue => undef,         # Filled in by initialise()
  94         libxml => $libxml,
  95         irspy_to_zeerex_style => $irspy_to_zeerex_style,
  96         tests => undef,         # Tree of tests to be executed
  97         activeSetSize => defined $activeSetSize ? $activeSetSize : 10,
  98     }, $class;
  99     $this->log("irspy", "starting up with database '$dbname'");
 100
 101     return $this;
 102 }
 103
 104
 105 sub log {
 106     my $this = shift();
 107     ZOOM::Log::log(@_);
 108 }
 109
 110
 111 sub find_targets {
 112     my $this = shift();
 113     my($query) = @_;
 114
 115     $this->{query} = $query;
 116 }
 117
 118
 119 # Explicitly nominate a set of targets to check, overriding the
 120 # default which is to re-check everything in the database.  Each
 121 # target already in the database results in the existing record being
 122 # updated; each new target causes a new record to be added.
 123 #
 124 sub targets {
 125     my $this = shift();
 126     my(@targets) = @_;
 127
 128     $this->log("irspy", "setting explicit list of targets ",
 129                join(", ", map { "'$_'" } @targets));
 130     my @qlist;
 131     foreach my $target (@targets) {
 132         my($host, $port, $db, $newtarget) = _parse_target_string($target);
 133         if ($newtarget ne $target) {
 134             $this->log("irspy_debug", "rewriting '$target' to '$newtarget'");
 135             $target = $newtarget; # This is written through the ref
 136         }
 137         push @qlist, cql_target($host, $port, $db);
 138     }
 139
 140     $this->{targets} = \@targets;
 141     $this->{query} = join(" or ", @qlist);
 142 }
 143
 144
 145 # Also used by ZOOM::IRSpy::Record
 146 sub _parse_target_string {
 147     my($target) = @_;
 148
 149     my($host, $port, $db) = ($target =~ /(.*?):(.*?)\/(.*)/);
 150     if (!defined $host) {
 151         $port = 210;
 152         ($host, $db) = ($target =~ /(.*?)\/(.*)/);
 153         $target = "$host:$port/$db";
 154     }
 155     die "$0: invalid target string '$target'"
 156         if !defined $host;
 157
 158     return ($host, $port, $db, $target);
 159 }
 160
 161
 162 # Records must be fetched for all records satisfying $this->{query} If
 163 # $this->{targets} is already set (i.e. a specific list of targets to
 164 # check was specified by a call to targets()), then new, empty records
 165 # will be made for any targets that are not already in the database.
 166 #
 167 sub initialise {
 168     my $this = shift();
 169
 170     my @targets;
 171     my $targets = $this->{targets};
 172     if (defined $targets) {
 173         @targets = @$targets;
 174         delete $this->{targets};
 175     } else {
 176         my $rs = $this->{conn}->search(new ZOOM::Query::CQL($this->{query}));
 177         $this->log("irspy", "'", $this->{query}, "' found ",
 178                    $rs->size(), " target records");
 179         delete $this->{query};
 180
 181         foreach my $i (1 .. $rs->size()) {
 182             push @targets, render_record($rs, $i-1, "id");
 183         }
 184     }
 185
 186     my $n = $this->{activeSetSize};
 187     $n = @targets if $n == 0 || $n > @targets;
 188
 189     my @connections;
 190     foreach my $i (1..$n) {
 191         push @connections, create ZOOM::IRSpy::Connection($this,
 192                                                           shift @targets,
 193                                                           async => 1);
 194     }
 195
 196     $this->{connections} = \@connections;
 197     $this->{queue} = \@targets;
 198 }
 199
 200
 201 sub _irspy_to_zeerex {
 202     my $this = shift();
 203     my($conn, $save_xml) = @_;
 204     my $irspy_doc = $conn->record()->{zeerex}->ownerDocument;
 205
 206     if ($save_xml) {
 207         unlink('/tmp/irspy_orig.xml');
 208         open FH, '>/tmp/irspy_orig.xml'
 209             or die "can't write irspy_orig.xml: $!";
 210         print FH $irspy_doc->toString();
 211         close FH;
 212     }
 213     my %params = ();
 214     my $result = $this->{irspy_to_zeerex_style}->transform($irspy_doc, %params);
 215     if ($save_xml) {
 216         unlink('/tmp/irspy_transformed.xml');
 217         open FH, '>/tmp/irspy_transformed.xml'
 218             or die "can't write irspy_transformed.xml: $!";
 219         print FH $result->toString();
 220         close FH;
 221     }
 222
 223     return $result->documentElement();
 224 }
 225
 226
 227 sub _rewrite_record {
 228     my $this = shift();
 229     my($conn) = @_;
 230
 231     $conn->log("irspy", "rewriting XML record");
 232     my $rec = $this->_irspy_to_zeerex($conn, $ENV{IRSPY_SAVE_XML});
 233
 234     # Since IRSpy can run for a long time between writes back to the
 235     # database, it's quite possible for the server to have closed the
 236     # connection as idle.  So re-establish it if necessary.
 237     $this->{conn}->connect($conn->option("host"));
 238
 239     _really_rewrite_record($this->{conn}, $rec);
 240     $conn->log("irspy", "rewrote XML record");
 241 }
 242
 243
 244 sub _really_rewrite_record {
 245     my($conn, $rec, $oldid) = @_;
 246
 247     my $p = $conn->package();
 248     $p->option(action => "specialUpdate");
 249     my $xml = $rec->toString();
 250     $p->option(record => $xml);
 251     $p->send("update");
 252     $p->destroy();
 253
 254     # This is the expression in the ID-making stylesheet
 255     # ../../zebra/zeerex2id.xsl
 256     my $xc = irspy_xpath_context($rec);
 257     my $id = $xc->find("concat(e:serverInfo/e:host, ':',
 258                                e:serverInfo/e:port, '/',
 259                                e:serverInfo/e:database)");
 260     if (defined $oldid && $id ne $oldid) {
 261         # Delete old record;
 262         warn "IDs differ (old='$oldid' new='$id')";
 263         my $p = $conn->package();
 264         $p->option(action => "recordDelete");
 265         $p->option(recordIdOpaque => $oldid);
 266         $p->option(record => "<dummy/>"); # Work around Zebra bug
 267         $p->send("update");
 268         $p->destroy();
 269     }
 270
 271     $p = $conn->package();
 272     $p->send("commit");
 273     $p->destroy();
 274     if (0) {
 275         $xml =~ s/&/&amp/g;
 276         $xml =~ s/</&lt;/g;
 277         $xml =~ s/>/&gt;/g;
 278         print "Updated $conn with xml=<br/>\n<pre>$xml</pre>\n";
 279     }
 280 }
 281
 282
 283 # The approach: gather declarative information about test hierarchy,
 284 # then go into a loop.  In the loop, we ensure that each connection is
 285 # running a test, and within that test a task, until its list of tests
 286 # is exhausted.  No individual test ever calls wait(): tests just queue
 287 # up tasks and return immediately.  When the tasks are run (one at a
 288 # time on each connection) they generate events, and it is these that
 289 # are harvested by ZOOM::event().  Since each connection knows what
 290 # task it is running, it can invoke the appropriate callbacks.
 291 # Callbacks return a ZOOM::IRSpy::Status value which tells the main
 292 # loop how to continue.
 293 #
 294 # Invariants:
 295 #       While a connection is running a task, its current_task()
 296 #       points at the task structure.  When it finishes its task,
 297 #       next_task() is pointed at the next task to execute (if there
 298 #       is one), and its current_task() is set to zero.  When the next
 299 #       task is executed, the connection's next_task() is set to zero
 300 #       and its current_task() pointed to the task structure.
 301 #       current_task() and next_task() are both zero only when there
 302 #       are no more queued tasks, which is when a new test is
 303 #       started.
 304 #
 305 #       Each connection's current test is stored in its
 306 #       "current_test_address" option.  The next test to execute is
 307 #       calculated by walking the declarative tree of tests.  This
 308 #       option begins empty; the "next test" after this is of course
 309 #       the root test.
 310 #
 311 sub check {
 312     my $this = shift();
 313     my($tname) = @_;
 314
 315     $tname = "Main" if !defined $tname;
 316     $this->{tree} = $this->_gather_tests($tname)
 317         or die "No tests defined for '$tname'";
 318     $this->{tree}->resolve();
 319     #$this->{tree}->print(0);
 320     my $nskipped = 0;
 321
 322     my @conn = @{ $this->{connections} };
 323
 324     my $nruns = 0;
 325   ROUND_AND_ROUND_WE_GO:
 326     while (1) {
 327         my @copy_conn = @conn;  # avoid alias problems after splice()
 328         my $nconn = scalar(@copy_conn);
 329         foreach my $i0 (0 .. $#copy_conn) {
 330             my $conn = $copy_conn[$i0];
 331             #print "connection $i0 of $nconn/", scalar(@conn), " is $conn\n";
 332             next if !defined $conn;
 333             if (!$conn->current_task()) {
 334                 if (!$conn->next_task()) {
 335                     # Out of tasks: we need a new test
 336                   NEXT_TEST:
 337                     my $address = $conn->option("current_test_address");
 338                     my $nextaddr;
 339                     if (!defined $address) {
 340                         $nextaddr = "";
 341                     } else {
 342                         $conn->log("irspy_test",
 343                                    "checking for next test after '$address'");
 344                         $nextaddr = $this->_next_test($address);
 345                     }
 346                     if (!defined $nextaddr) {
 347                         $conn->log("irspy", "has no more tests: removing");
 348                         $this->_rewrite_record($conn);
 349                         $conn->option(rewrote_record => 1);
 350                         if (@{ $this->{queue} } == 0) {
 351                             # Do not destroy: we need this for later sanity checks
 352                             splice @conn, $i0, 1;
 353                         } else {
 354                             $conn->destroy();
 355                             $conn[$i0] = create
 356                                 ZOOM::IRSpy::Connection($this,
 357                                         shift @{ $this->{queue} }, async => 1);
 358                             $conn[$i0]->option(current_test_address => "");
 359                             $conn[$i0]->log("irspy", "entering active pool - ",
 360                                             scalar(@{ $this->{queue} }),
 361                                             " targets remain in queue");
 362                         }
 363                         next;
 364                     }
 365
 366                     my $node = $this->{tree}->select($nextaddr)
 367                         or die "invalid nextaddr '$nextaddr'";
 368                     $conn->option(current_test_address => $nextaddr);
 369                     my $tname = $node->name();
 370                     $conn->log("irspy_test",
 371                                "starting test '$nextaddr' = $tname");
 372                     my $tasks = $conn->tasks();
 373                     my $oldcount = @$tasks;
 374                     "ZOOM::IRSpy::Test::$tname"->start($conn);
 375                     $tasks = $conn->tasks();
 376                     if (@$tasks > $oldcount) {
 377                         # Prepare to start the first of the newly added tasks
 378                         $conn->next_task($tasks->[$oldcount]);
 379                     } else {
 380                         $conn->log("irspy_task",
 381                                    "no tasks added by new test $tname");
 382                         goto NEXT_TEST;
 383                     }
 384                 }
 385
 386                 my $task = $conn->next_task();
 387                 die "no next task queued for $conn" if !defined $task;
 388                 $conn->log("irspy_task", "preparing task $task");
 389                 $conn->next_task(0);
 390                 $conn->current_task($task);
 391                 $task->run();
 392             }
 393         }
 394
 395       NEXT_EVENT:
 396         my $i0 = ZOOM::event(\@conn);
 397         $this->log("irspy_event",
 398                    "ZOOM_event(", scalar(@conn), " connections) = $i0");
 399         if ($i0 < 1) {
 400             my %messages = (
 401                             0 => "no events remain",
 402                             -1 => "ZOOM::event() argument not a reference",
 403                             -2 => "ZOOM::event() reference not an array",
 404                             -3 => "no connections remain",
 405                             -4 => "too many connections for ZOOM::event()",
 406                             );
 407             my $message = $messages{$i0} || "ZOOM::event() returned $i0";
 408             $this->log("irspy", $message);
 409             last;
 410         }
 411
 412         my $conn = $conn[$i0-1];
 413         my $ev = $conn->last_event();
 414         my $evstr = ZOOM::event_str($ev);
 415         $conn->log("irspy_event", "event $ev ($evstr)");
 416         goto NEXT_EVENT if $ev != ZOOM::Event::ZEND;
 417
 418         my $task = $conn->current_task();
 419         die "$conn has no current task for event $ev ($evstr)" if !$task;
 420
 421         my $res;
 422         eval { $conn->check() };
 423         if ($@ && ref $@ && $@->isa("ZOOM::Exception")) {
 424             my $sub = $task->{cb}->{exception};
 425             die $@ if !defined $sub;
 426             $res = &$sub($conn, $task, $task->udata(), $@);
 427         } elsif ($@) {
 428             die "Unexpected non-ZOOM exception: " . ref($@) . " ($@)";
 429         } else {
 430             my $sub = $task->{cb}->{$ev};
 431             if (!defined $sub) {
 432                 $conn->log("irspy_unhandled", "event $ev ($evstr)");
 433                 next;
 434             }
 435
 436             $res = &$sub($conn, $task, $task->udata(), $ev);
 437         }
 438
 439         if ($res == ZOOM::IRSpy::Status::OK) {
 440             # Nothing to do -- life continues
 441
 442         } elsif ($res == ZOOM::IRSpy::Status::TASK_DONE) {
 443             my $task = $conn->current_task();
 444             die "no task for TASK_DONE on $conn" if !$task;
 445             die "next task already defined for $conn" if $conn->next_task();
 446             $conn->log("irspy_task", "completed task $task");
 447             $conn->next_task($task->{next});
 448             $conn->current_task(0);
 449
 450         } elsif ($res == ZOOM::IRSpy::Status::TEST_GOOD ||
 451                  $res == ZOOM::IRSpy::Status::TEST_BAD) {
 452             my $x = ($res == ZOOM::IRSpy::Status::TEST_GOOD) ? "good" : "bad";
 453             $conn->log("irspy_task", "test ended during task $task ($x)");
 454             $conn->log("irspy_test", "test completed ($x)");
 455             $conn->current_task(0);
 456             $conn->next_task(0);
 457             if ($res == ZOOM::IRSpy::Status::TEST_BAD) {
 458                 my $address = $conn->option('current_test_address');
 459                 $conn->log("irspy", "top-level test failed!")
 460                     if $address eq "";
 461                 my $node = $this->{tree}->select($address);
 462                 my $skipcount = 0;
 463                 while (defined $node->next() &&
 464                        length($node->next()->address()) >= length($address)) {
 465                     $conn->log("irspy_debug", "skipping from '",
 466                                $node->address(), "' to '",
 467                                $node->next()->address(), "'");
 468                     $node = $node->next();
 469                     $skipcount++;
 470                 }
 471
 472                 $conn->option(current_test_address => $node->address());
 473                 $conn->log("irspy_test", "skipped $skipcount tests");
 474                 $nskipped += $skipcount;
 475             }
 476
 477         } elsif ($res == ZOOM::IRSpy::Status::TEST_SKIPPED) {
 478             $conn->log("irspy_test", "test skipped during task $task");
 479             $conn->current_task(0);
 480             $conn->next_task(0);
 481             $nskipped++;
 482
 483         } else {
 484             die "unknown callback return-value '$res'";
 485         }
 486     }
 487
 488     $this->log("irspy", "exiting main loop");
 489
 490     # Sanity checks: none of the following should ever happen
 491     my $finished = 1;
 492     $this->log("irspy", "performing end-of-run sanity-checks");
 493     foreach my $conn (@conn) {
 494         my $test = $conn->option("current_test_address");
 495         my $next = $this->_next_test($test);
 496         if (defined $next) {
 497             $this->log("irspy",
 498                        "$conn (in test '$test') has queued test '$next'");
 499             $finished = 0;
 500         }
 501         if (my $task = $conn->current_task()) {
 502             $this->log("irspy", "$conn still has an active task $task");
 503             $finished = 0;
 504         }
 505         if (my $task = $conn->next_task()) {
 506             $this->log("irspy", "$conn still has a queued task $task");
 507             $finished = 0;
 508         }
 509         if (!$conn->is_idle()) {
 510             $this->log("irspy",
 511                        "$conn still has ZOOM-C level tasks queued: see below");
 512             $finished = 0;
 513         }
 514         my $ev = $conn->peek_event();
 515         if ($ev != 0 && $ev != ZOOM::Event::ZEND) {
 516             my $evstr = ZOOM::event_str($ev);
 517             $this->log("irspy", "$conn has event $ev ($evstr) waiting");
 518             $finished = 0;
 519         }
 520         if (!$conn->option("rewrote_record")) {
 521             $this->log("irspy", "$conn did not rewrite its ZeeRex record");
 522             $finished = 0;
 523         }
 524     }
 525
 526     # This really shouldn't be necessary, and in practice it rarely
 527     # helps, but it's belt and braces.  (For now, we don't do this
 528     # hence the zero in the $nruns check).
 529     if (!$finished) {
 530         if (++$nruns < 0) {
 531             $this->log("irspy", "back into main loop, ${nruns}th time");
 532             goto ROUND_AND_ROUND_WE_GO;
 533         } else {
 534             $this->log("irspy", "bailing after $nruns main-loop runs");
 535         }
 536     }
 537
 538     # This shouldn't happen emit anything either:
 539     while ((my $i1 = ZOOM::event(\@conn)) > 0) {
 540         my $conn = $conn[$i1-1];
 541         my $ev = $conn->last_event();
 542         my $evstr = ZOOM::event_str($ev);
 543         $this->log("irspy",
 544                    "$conn still has ZOOM-C level task queued: $ev ($evstr)")
 545             if $ev != ZOOM::Event::ZEND;
 546     }
 547
 548     return $nskipped;
 549 }
 550
 551
 552 # Exactly equivalent to ZOOM::event() except that it is tolerant to
 553 # undefined values in the array being passed in.
 554 #
 555 sub __UNUSED_tolerant_ZOOM_event {
 556     my($connref) = @_;
 557
 558     my(@conn, @map);
 559     foreach my $i (0 .. @$connref-1) {
 560         my $conn = $connref->[$i];
 561         if (defined $conn) {
 562             push @conn, $conn;
 563             push @map, $i;
 564         }
 565     }
 566
 567     my $res = ZOOM::event(\@conn);
 568     return $res if $res <= 0;
 569     my $res2 = $map[$res-1] + 1;
 570     print STDERR "*** tolerant_ZOOM_event() returns $res->$res2\n";
 571     return $res2;
 572 }
 573
 574
 575 sub _gather_tests {
 576     my $this = shift();
 577     my($tname, @ancestors) = @_;
 578
 579     die("$0: test-hierarchy loop detected: " .
 580         join(" -> ", @ancestors, $tname))
 581         if grep { $_ eq $tname } @ancestors;
 582
 583     my $slashSeperatedTname = $tname;
 584     $slashSeperatedTname =~ s/::/\//g;
 585     my $fullName = "ZOOM/IRSpy/Test/$slashSeperatedTname.pm";
 586
 587     eval {
 588         require $fullName;
 589         $this->log("irspy", "successfully required '$fullName'");
 590     }; if ($@) {
 591         $this->log("irspy", "couldn't require '$fullName': $@");
 592         $this->log("warn", "can't load test '$tname': skipping",
 593                    $@ =~ /^Can.t locate/ ? () : " ($@)");
 594         return undef;
 595     }
 596
 597     $this->log("irspy", "adding test '$tname'");
 598     my @subnodes;
 599     foreach my $subtname ("ZOOM::IRSpy::Test::$tname"->subtests($this)) {
 600         my $subtest = $this->_gather_tests($subtname, @ancestors, $tname);
 601         push @subnodes, $subtest if defined $subtest;
 602     }
 603
 604     return new ZOOM::IRSpy::Node($tname, @subnodes);
 605 }
 606
 607
 608 # These next three should arguably be Node methods
 609 sub _next_test {
 610     my $this = shift();
 611     my($address, $omit_child) = @_;
 612
 613     # Try first child
 614     if (!$omit_child) {
 615         my $maybe = $address eq "" ? "0" : "$address:0";
 616         return $maybe if $this->{tree}->select($maybe);
 617     }
 618
 619     # The top-level node has no successor or parent
 620     return undef if $address eq "";
 621
 622     # Try next sibling child
 623     my @components = split /:/, $address;
 624     my $last = pop @components;
 625     my $maybe = join(":", @components, $last+1);
 626     return $maybe if $this->{tree}->select($maybe);
 627
 628     # This node is exhausted: try the parent's successor
 629     return $this->_next_test(join(":", @components), 1)
 630 }
 631
 632
 633 sub _last_sibling_test {
 634     my $this = shift();
 635     my($address) = @_;
 636
 637     return undef
 638         if !defined $this->_next_sibling_test($address);
 639
 640     my $nskipped = 0;
 641     while (1) {
 642         my $maybe = $this->_next_sibling_test($address);
 643         last if !defined $maybe;
 644         $nskipped++;
 645         $address = $maybe;
 646         $this->log("irspy", "skipping $nskipped tests to '$address'");
 647     }
 648
 649     return ($address, $nskipped);
 650 }
 651
 652
 653 sub _next_sibling_test {
 654     my $this = shift();
 655     my($address) = @_;
 656
 657     my @components = split /:/, $address;
 658     my $last = pop @components;
 659     my $maybe = join(":", @components, $last+1);
 660     return $maybe if $this->{tree}->select($maybe);
 661     return undef;
 662 }
 663
 664
 665 =head1 SEE ALSO
 666
 667 ZOOM::IRSpy::Record,
 668 ZOOM::IRSpy::Web,
 669 ZOOM::IRSpy::Test,
 670 ZOOM::IRSpy::Maintenance.
 671
 672 The ZOOM-Perl module,
 673 http://search.cpan.org/~mirk/Net-Z3950-ZOOM/
 674
 675 The Zebra Database,
 676 http://indexdata.com/zebra/
 677
 678 =head1 AUTHOR
 679
 680 Mike Taylor, E<lt>mike@indexdata.comE<gt>
 681
 682 =head1 COPYRIGHT AND LICENSE
 683
 684 Copyright (C) 2006 by Index Data ApS.
 685
 686 This library is free software; you can redistribute it and/or modify
 687 it under the same terms as Perl itself, either Perl version 5.8.7 or,
 688 at your option, any later version of Perl 5 you may have available.
 689
 690 =cut
 691
 692
 693 1;